XL 2016 Boucle sur plusieurs plages pour les Trier

[KTM]

Bonsoir chers tous
Jai neuf plages de données de même dimension que je voudrais trier.
Jai élaboré un code pour les trier une à une mais je voudrais faire plus simple en utilisant une boucle.
Merci de me simplifier mon code.

Sub TRIER()
Dim PlageDeDonnees As Range
   With Sheets("Cascade")
        ds = 10
        Set PlageDeDonnees = .Range("K22").Resize(ds, 5)
        PlageDeDonnees.Sort key1:=.Range("O22"), order1:=xlAscending, Header:=xlNo
        
        Set PlageDeDonnees = .Range("K52").Resize(ds, 5)
        PlageDeDonnees.Sort key1:=.Range("O52"), order1:=xlAscending, Header:=xlNo
        
        Set PlageDeDonnees = .Range("K82").Resize(ds, 5)
        PlageDeDonnees.Sort key1:=.Range("O82"), order1:=xlAscending, Header:=xlNo
        
        Set PlageDeDonnees = .Range("K112").Resize(ds, 5)
        PlageDeDonnees.Sort key1:=.Range("O112"), order1:=xlAscending, Header:=xlNo

        Set PlageDeDonnees = .Range("K142").Resize(ds, 5)
        PlageDeDonnees.Sort key1:=.Range("O142"), order1:=xlAscending, Header:=xlNo
        
        Set PlageDeDonnees = .Range("K172").Resize(ds, 5)
        PlageDeDonnees.Sort key1:=.Range("O172"), order1:=xlAscending, Header:=xlNo

        Set PlageDeDonnees = .Range("K202").Resize(ds, 5)
        PlageDeDonnees.Sort key1:=.Range("O202"), order1:=xlAscending, Header:=xlNo
        
        Set PlageDeDonnees = .Range("K232").Resize(ds, 5)
        PlageDeDonnees.Sort key1:=.Range("O232"), order1:=xlAscending, Header:=xlNo
        
        Set PlageDeDonnees = .Range("K262").Resize(ds, 5)
        PlageDeDonnees.Sort key1:=.Range("O262"), order1:=xlAscending, Header:=xlNo
   End With
End Sub

 

[sylvanu]

Bonjour KTM,
Sans fichier test impossible de tester, alors un peu au pif :

Sub TRIER()
Dim PlageDeDonnees As Range, i%, ds%
   With Sheets("Cascade")
        ds = 10
        For i = 1 To 9
            Set PlageDeDonnees = .Cells(30 * i - 8, "K").Resize(ds, 5)
            PlageDeDonnees.Sort key1:=.Cells(30 * i - 8, "O"), order1:=xlAscending, Header:=xlNo
        Next i
    End With
End Sub

ou encore si vous voulez éviter cette équation 30x-8 :

Sub TRIER2()
Dim PlageDeDonnees As Range, i%, T
    T = Array(22, 52, 82, 112, 142, 172, 202, 232, 262)
   With Sheets("Cascade")
        ds = 10
        For i = 0 To 8
            Set PlageDeDonnees = .Cells(T(i), "K").Resize(ds, 5)
            PlageDeDonnees.Sort key1:=.Cells(T(i), "O"), order1:=xlAscending, Header:=xlNo
        Next i
    End With
End Sub

 

[KTM]

Bonjour KTM,
Sans fichier test impossible de tester, alors un peu au pif :

Sub TRIER()
Dim PlageDeDonnees As Range, i%, ds%
   With Sheets("Cascade")
        ds = 10
        For i = 1 To 9
            Set PlageDeDonnees = .Cells(30 * i - 8, "K").Resize(ds, 5)
            PlageDeDonnees.Sort key1:=.Cells(30 * i - 8, "O"), order1:=xlAscending, Header:=xlNo
        Next i
    End With
End Sub

ou encore si vous voulez éviter cette équation 30x-8 :

Sub TRIER2()
Dim PlageDeDonnees As Range, i%, T
    T = Array(22, 52, 82, 112, 142, 172, 202, 232, 262)
   With Sheets("Cascade")
        ds = 10
        For i = 0 To 8
            Set PlageDeDonnees = .Cells(T(i), "K").Resize(ds, 5)
            PlageDeDonnees.Sort key1:=.Cells(T(i), "O"), order1:=xlAscending, Header:=xlNo
        Next i
    End With
End Sub

Merci pour le coup de main......

 

[Nicolas JACQUIN]

Bonjour à tous,

ou encore si vous voulez éviter cette équation 30x-8 :

Je l'avais autrement aussi, dans le même contexte, à tester

Sub TRIER()
    Dim i As Long
    With Sheets("Cascade")
        For i = 22 To 262 Step 30
            .Range("K" & i).Resize(10, 5).Sort _
                .Range("O" & i), xlAscending, , , , , , xlNo
        Next i
    End With
End Sub

Nicolas