XL 2013 Boucle sur plusieurs feuilles sauf 1

[Regueiro]

Bonsoir le Forum et Bonne Année à Tous.
Voici mon code qui marche pour boucler sur une feuille
Mais j'aimerais boucler sur toutes les feuilles sauf 1 (Feuil4) = ACCUEIL

Option Explicit
Public Derlig As Long, DerCol As Long
Public Cell As Range
Sub Transfert()
Dim Dico As Object
Dim F As Worksheet
Set F = Worksheets("eric")
MsgBox F.Name
Set Dico = CreateObject("Scripting.Dictionary")

    Derlig = F.Cells(Rows.Count, 3).End(xlUp).Row
    MsgBox Derlig
        For Each Cell In F.Range("C7", F.Cells(Derlig, 3))
            If Cell <> "" Then Dico(Cell.Value) = ""
        Next Cell

With Sheets("ACCUEIL")
[I4].Resize(Dico.Count) = Application.Transpose(Dico.keys)

End With

End Sub

Pour info je dois rajouter plusieurs feuilles avec des noms diééfrents
MErci de votre Aide

 

[Roland_M]

Re : Boucle sur plusieurs feuilles sauf 1

bonjour,

essayer comme ceci !?

Option Explicit
Public Derlig As Long, DerCol As Long, Cell As Range
Sub Transfert()
Dim Dico As Object, F As Worksheet
Set Dico = CreateObject("Scripting.Dictionary")
For Each F In Worksheets
    If LCase(F.Name) <> "accueil" Then 'excepté celle-ci !
        Derlig = F.Cells(Rows.Count, 3).End(xlUp).Row
        For Each Cell In F.Range("C7", F.Cells(Derlig, 3))
            If Cell <> "" Then Dico(Cell.Value) = ""
        Next
    End If
Next
If Dico.Count > 0 Then
   With Sheets("ACCUEIL"): .[I4].Resize(Dico.Count) = Application.Transpose(Dico.keys): End With
End If
Set F = Nothing: Set Dico = Nothing
End Sub

 

[Regueiro]

Re : Boucle sur plusieurs feuilles sauf 1

Bonsoir Le FORUM
Roland_M
Merci pour ton AIDE.
Code Parfait
A+