XL 2016 Autre curiosité ComboBox

[Dudu2]

Bonjour,

J'aimerais que le ComboBox.DropDown s'exécute automatiquement à chaque fois qu'on entre dans une ComboBox.
J'ai donc codé:

Private Sub UserForm_Initialize()
    Me.ComboBox1.List = [A1:A3].Value
    Me.ComboBox2.List = [B1:B3].Value
    Me.ComboBox3.List = [C1:C3].Value
    Me.ComboBox1.SetFocus
End Sub

Private Sub ComboBox1_Enter()
    [I2].Value = "ComboBox1_Enter"
    Me.ComboBox1.DropDown
End Sub

Private Sub ComboBox2_Enter()
    [I2].Value = "ComboBox2_Enter"
    Me.ComboBox2.DropDown
End Sub

Private Sub ComboBox3_Enter()
    [I2].Value = "ComboBox3_Enter"
    Me.ComboBox3.DropDown
End Sub

Hélas ! Quand on utilise Tabulation pour passer à la ComboBox suivante, le ComboBox.DropDown ne s'exécute qu'une fois sur 2. Et pourquoi donc ?

 

[patricktoulon]

😛 😛 😛 😛 😛 😛
bon j'aime mieux ça 🤪

 

[patricktoulon]

dis moi tu serais pas en train de te faire une biblio de code events spéciaux toi ?

 

[Dudu2]

Ce qui est sûr c'est que je garde ces acquis pour mon usage perso quand je développe des trucs pour les gens.
Ces 2 curiosités des ComboBoxes qui nous ont occupés une partie de l'après-midi, franchement j'aurais jamais pensé tomber dessus. Et maintenant que je sais comment les identifier / contourner, je vais pas me priver 😉.

Et je suis content d'avoir eu le support des experts qui se sont impliqués. Merci à eux !

 

[patricktoulon]

oui il y en a quelques uns comme ça qui sont intéressants les plus dur sont sur feuille
tiens un autre en deux temps
1er tab dropdown et le 2d sélectionne la suivante

Private Sub UserForm_Initialize()
    Me.ComboBox1.List = [A1:A3].Value
    Me.ComboBox2.List = [B1:B3].Value
    Me.ComboBox3.List = [C1:C3].Value
End Sub
Private Sub ComboBox1_KeyDown(ByVal KeyCode As MSForms.ReturnInteger, ByVal Shift As Integer)
    key_tabpress ComboBox1, KeyCode
End Sub

Private Sub ComboBox2_KeyDown(ByVal KeyCode As MSForms.ReturnInteger, ByVal Shift As Integer)
    key_tabpress ComboBox2, KeyCode
End Sub

Private Sub ComboBox3_KeyDown(ByVal KeyCode As MSForms.ReturnInteger, ByVal Shift As Integer)
    key_tabpress ComboBox3, KeyCode
End Sub

Private Sub key_tabpress(combo As MSForms.ComboBox, ByVal KeyCode As MSForms.ReturnInteger)
    With combo
        If KeyCode = 9 And Val(.Tag) = 0 Then .Tag = 1: KeyCode = 0: .DropDown Else .Tag = 0
    End With
End Sub

 

[Dudu2]

C'est original 🤔
Je le vois plus comme une démo d'une utilisation de la propriété .Tag dont je ne soupçonnais pas l'existence et qui peut avoir son utilité.

 

[patricktoulon]

re
le tag c'est surtout pratique pour memeriser un flag respectif a chaque combobox
on peut faire avec une variable tableau

Dim flag&(1 To 3)
Private Sub UserForm_Initialize()
    Me.ComboBox1.List = [A1:A3].Value
    Me.ComboBox2.List = [B1:B3].Value
    Me.ComboBox3.List = [C1:C3].Value
End Sub
Private Sub ComboBox1_KeyDown(ByVal KeyCode As MSForms.ReturnInteger, ByVal Shift As Integer)
    key_tabpress ComboBox1, KeyCode, flag(1)
End Sub

Private Sub ComboBox2_KeyDown(ByVal KeyCode As MSForms.ReturnInteger, ByVal Shift As Integer)
    key_tabpress ComboBox2, KeyCode, flag(2)
End Sub

Private Sub ComboBox3_KeyDown(ByVal KeyCode As MSForms.ReturnInteger, ByVal Shift As Integer)
    key_tabpress ComboBox3, KeyCode, flag(3)
End Sub

Private Sub key_tabpress(combo As MSForms.ComboBox, ByVal KeyCode As MSForms.ReturnInteger, flag&)
    With combo
        If KeyCode = 9 And Val(flag) = 0 Then flag = 1: KeyCode = 0: .DropDown Else flag = 0
    End With
End Sub