Astuce - Lister les références utilisées dans un projet

  • Initiateur de la discussion Initiateur de la discussion RoyalP
  • Date de début Date de début

Boostez vos compétences Excel avec notre communauté !

Rejoignez Excel Downloads, le rendez-vous des passionnés où l'entraide fait la force. Apprenez, échangez, progressez – et tout ça gratuitement ! 👉 Inscrivez-vous maintenant !

RoyalP

XLDnaute Occasionnel
Ce code n'est pas de moi mais je le trouve vraiment trés pratique. L'auteur se reconnaitra surement et je l'en remercie par avance.

Code:
'-------------------------------------------------
'-                                               -
'- Lister les references utilisés dans un projet -
'-                                               -
'-------------------------------------------------
Sub Lister_LesGuids_Références()
Dim X As Integer, Sh As Worksheet
Dim NbRef As Integer, A As Integer
Set Sh = Worksheets.Add(After:=Sheets(Sheets.Count))
On Error Resume Next
With Sh
    .Name = "GUIDS"
    .Cells(1, 1) = "Nom de la bibliothèque"
    'Son appellation dans la fenêtre Reférences
    .Cells(1, 2) = "Description"
    .Cells(1, 3) = "Guid"
    .Cells(1, 4) = "Major"
    .Cells(1, 5) = "Minor"
    .Cells(1, 6) = "Chemin complet"
    With .Range("A1:F1")
        .Font.Bold = True
        .Font.Size = 12
    End With
    With Sh.Parent.VBProject.References
        NbRef = .Count
        X = 2
        For A = 1 To NbRef
            Sh.Cells(X, 1) = .Item(A).Name
            Sh.Cells(X, 2) = .Item(A).Description
            Sh.Cells(X, 3) = .Item(A).GUID
            Sh.Cells(X, 4) = .Item(A).major
            Sh.Cells(X, 5) = .Item(A).minor
            Sh.Cells(X, 6) = .Item(A).fullpath
            X = X + 1
        Next
    End With
    .Range("A1").CurrentRegion.EntireColumn.AutoFit
End With
End Sub
'------------------------------------------

À partir de l'information, on peut charger les bibliothèques désirées
de cette manière :

Dans le ThisWorkbook, tu crées ce type de procédure :

Exemple : Pour charger la bibliothèque :
Library MSForms -> Nom de la bibliothèque (formulaire)
C:\Windows\system32\FM20.DLL -> Chemin et fichier source
Microsoft Forms 2.0 Object Library -> Appellation descriptive.

Code:
'----------------------------------------------
Private Sub Workbook_Open()
 
On Error Resume Next
ThisWorkbook.VBProject.References.AddFromGuid _
GUID:="{0D452EE1-E08F-101A-852E-02608C4D0BB4}", major:=2, minor:=0
 
End Sub
'----------------------------------------------

Ca m'a super bien servi pour savoir quelles librairies manquées.
 
- Navigue sans publicité
- Accède à Cléa, notre assistante IA experte Excel... et pas que...
- Profite de fonctionnalités exclusives
Ton soutien permet à Excel Downloads de rester 100% gratuit et de continuer à rassembler les passionnés d'Excel.
Je deviens Supporter XLD

Discussions similaires

Retour