Application.Match pour rechercher une valeur quelconque

[job75]

Bonjour à tous et à toutes,

Cette solution vient d'un fil de C@thy mais j'ouvre cette discussion pour facilement la retrouver :

Sub Rechercher()
Dim x As Variant, i As Variant
x = InputBox("Entrez la valeur texte, nombre, date, heure :", "Rechercher")
i = Replace(x, ".", Mid(1.1, 2, 1)) 'séparateur décimal de l'ordi
If IsNumeric(i) Then x = CDbl(i) Else If IsDate(x) Then x = CDbl(CDate(x))
i = Application.Match(x, [B:B], 0)
If IsNumeric(i) Then Cells(i, 2).Select 'valeur trouvée
End Sub

Quand je dis "valeur quelconque" cela exclut les valeurs logiques et les valeurs d'erreur.

Fichier joint.

A+

 

[job75]

Re : Application.Match pour rechercher une valeur quelconque

Re,

Pour le 1.1 voici l'explication :

https://www.excel-downloads.com/threads/rechercher-une-date-precise-dans-une-liste.184566/

A+

 

[job75]

Re : Application.Match pour rechercher une valeur quelconque

Re,

Si l'on veut rechercher les valeurs logiques ou d'erreur il faut compléter par la méthode Find :

Sub Rechercher()
Dim x As Variant, i As Variant, c As Range
x = InputBox("Entrez la valeur texte, nombre, date, heure :", "Rechercher")
i = Replace(x, ".", Mid(1.1, 2, 1)) 'séparateur décimal de l'ordi
If IsNumeric(i) Then x = CDbl(i) Else If IsDate(x) Then x = CDbl(CDate(x))
i = Application.Match(x, [B:B], 0)
If IsNumeric(i) Then
  Cells(i, 2).Select
Else 'valeurs logiques TRUE-FALSE ou valeurs d'erreur
  Set c = [B:B].Find(x, , xlValues, xlWhole)
  If Not c Is Nothing Then c.Select
End If
End Sub

Pour les valeurs logiques entrer dans l'InputBox leur équivalent en anglais.

Fichier (3).

A+

 

[R@chid]

Re : Application.Match pour rechercher une valeur quelconque

Bonjour @ tous,
Salut Job75 🙂,

Cette solution vient d'un fil de C@thy mais j'ouvre cette discussion pour facilement la retrouver :

On peut se faciliter la vie avec des dossiers sur XLD.
Regarde la pièce jointe 911060
@ + +

 

[job75]

Re : Application.Match pour rechercher une valeur quelconque

Bonjour le forum,

Merci R@chid, mais tout le monde n'est pas aussi méthodique.

Ici une recherche par ligne ou par colonne sur toute la feuille :

Private Sub CommandButton1_Click()
Dim x As Variant, i As Variant, r As Range
x = TextBox1
i = Replace(x, ".", Mid(1.1, 2, 1)) 'séparateur décimal de l'ordi
If IsNumeric(i) Then x = CDbl(i) Else If IsDate(x) Then x = CDbl(CDate(x))
With ActiveSheet.UsedRange
  For Each r In IIf(OptionButton1, .Rows, .Columns)
    i = Application.Match(x, r, 0)
    If IsNumeric(i) Then r.Cells(i).Select: Exit Sub
  Next
  'valeurs logiques et valeurs d'erreur
  If UCase(x) = "VRAI" Then x = "TRUE"
  If UCase(x) = "FAUX" Then x = "FALSE"
  Set r = .Find(x, , xlValues, xlWhole, IIf(OptionButton1, xlByRows, xlByColumns))
  If r Is Nothing Then MsgBox "Valeur introuvable": Exit Sub
  r.Select
End With
End Sub

Fichier (4).

A+