Microsoft 365 annuler clic gauche si double clic ou clic droit

[Usine à gaz]

Bonjour le Forum,
Bonne fin de dimanche 🙂

Il y a un déjà longtemps, j'avais posté cette question sans avoir trouvé de solution.
Nous en étions arrivé, si je me souviens bien, à ce que ce bon sang de clic gauche, si double clic ou clic droit, s'exécute toujours en premier. Et pas moyen de ne pas exécuter "Private Sub Worksheet_SelectionChange(ByVal R As Range)" et le code qui va avec.

Le temps passant, nos ténors étant toujours en évolution en répondant à nos demandes toujours plus folles dingues (et ils ont de koi faire lol), je me permets de reposer la question.

Est-il possible de neutraliser le clic gauche ou de faire en sorte que le double clic ou clic droit s'exécutent en premier ? Sans grand espoir mais sait-on jamais avec nos magiciens.

Comme dirait un illustre inconnu : j'ai le non, je cherche le oui
En cas, je joins un petit fichier test.
Je vous remercie vivement,
Amicalement,
lionel,

 

[Bernard_XLD]

Salut Usine à gaz, le forum

Il sert à quoi ton sendkeys esc ?

Bien cordialement

 

[Usine à gaz]

Bonsoir Yeahou,
Merci d'être là 🙂
"Il sert à quoi ton sendkeys esc ?"
Il annule l'action du double clic ou clic droit pour sortir de la cellule,
lionel 🙂

 

[Bernard_XLD]

re,

ok, autre question
le clic gauche doit il être actif sur certaines cellules ou hors de certaines cellules et lesquelles ?

Bien cordialement, @+

 

[Usine à gaz]

Oui, il doit être actif sur toutes les cellules de la feuille, sauf si double clic ou clic droit sur cellule 🙂

 

[Usine à gaz]

Re-Bonsoir,

Il semble qu'il y ait une solution ici :

[Résolu] VBA Clic Gauche automatique par KevinTchy - page 1 - OpenClassrooms

openclassrooms.com

Mais j'ai pas compris 😡

 

[Bernard_XLD]

Re,

je t'ai fait au plus simple, tout est à placer dans le module de feuille

Cordialement, @+
[édition : code modifié en post #12]

 

[Bernard_XLD]

re,

il faut quand même que le sélection change s'exécute après doubleclic ou clic droit ? car je l'ai laissé !

Cordialement, @+

 

[Usine à gaz]

Re-Bonsoir Yeahou,

Un grand merci pour ce que tu as fait. Certainement un sacré casse-tête 🙂
"il faut quand même que le sélection change s'exécute après doubleclic ou clic droit ?"
Non, c'est justement ce que je voudrais éviter.
🙂

 

[Bernard_XLD]

Re,

Certainement un sacré casse-tête

Ben non ! 🤔, j'ai vu bien pire.

Non, c'est justement ce que je voudrais éviter.

Voila le code modifié, pas de selectionchange si doubleclic ou clic droit

Bien cordialement, @+
[édition : code modifié en post #12]

 

[Usine à gaz]

Super Merci. je vais regarder 🙂

 

[Bernard_XLD]

re,

nouvelle version qui règle un petit bug quand on faisait doubleclic ou clic droit sur la cellule déjà active, la sélection suivante était désactivée, réglé avec ce code modifié.

Bien cordialement, @+

Option Explicit
Dim Mem_Target As Range, Bloque_Selection As Boolean
Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
If Not Mem_Target Is Nothing Then Bloque_Selection = True
If Not Application.Intersect(Target, Range("a1:z10000")) Is Nothing Then
    Cancel = True
    MsgBox "C'est un double clic sur la cellule " & Target.Address, vbOKOnly + vbInformation
End If
End Sub
Private Sub Worksheet_BeforeRightClick(ByVal Target As Range, Cancel As Boolean)
If Not Mem_Target Is Nothing Then Bloque_Selection = True
If Not Application.Intersect(Target, Range("a1:z10000")) Is Nothing Then
    Cancel = True
    If Target.Count = 1 Then
        MsgBox "C'est un clic droit sur la cellule " & Target.Address, vbOKOnly + vbInformation
    Else
        MsgBox "C'est un clic droit sur les cellules " & Target.Address, vbOKOnly + vbInformation
    End If
End If
End Sub
Private Sub Worksheet_SelectionChange(ByVal Target As Range)
Set Mem_Target = Target
Application.OnTime Now() + TimeValue("00:00:01"), "'" & ThisWorkbook.Name & "'!" & ThisWorkbook.Worksheets(ActiveSheet.Name).CodeName & ".Differe_Worksheet_SelectionChange"
End Sub
Private Sub Differe_Worksheet_SelectionChange()
DoEvents
If Bloque_Selection Then Bloque_Selection = False: Set Mem_Target = Nothing: Exit Sub
If Mem_Target.Count = 1 Then
    MsgBox "Worksheet_SelectionChange, je m'exécute sur la cellule " & Mem_Target.Address
Else
    MsgBox "Worksheet_SelectionChange, je m'exécute sur les cellules " & Mem_Target.Address
End If
Set Mem_Target = Nothing
End Sub

 

[Usine à gaz]

Merci pour ce code modifié 🙂

 

[Usine à gaz]

Bonjour Yeahou, le Forum,
Je vous souhaite une belle journée 🙂

Encore merci à toi, ton code fonctionne bien.
lionel 🙂

 

[Bernard_XLD]

Bonjour lionel, le forum

tu n'as pas mis le bon post en solution, c'est le 12, pas le 13 !

Bonne journée !
Bien amicalement, @+
Bernard