Ajustement de la hauteur d'une ligne avec cellules fusionners...

[CyberNeo99]

Bonjour à tous,

Je sais que ce sujet a été traité mais je pars une nouvelle discussion car je me demande si cela serait possible de créer un code VB, faire une macro mais de façon un peu général pour contourner ce problème... ???

En fait de créer une macro qui permet d'ajuster autmatiquement la hauteur de lignes avec des cellules fusionners selon une plage déterminer. Il suffirait de paramétrer la plage, définir la plage pour qu'il puisse faire les cellules une par une dans la plage donner et ajuster automatiquement la hauteur de chaque cellule ??? 🙄

Merci à l'avance

Neo 😉

 

[Cousinhub]

Re : Ajustement de la hauteur d'une ligne avec cellules fusionners...

Bonsoir,

Regarde le code suivant, la plage est à adapter...

(code de Jim Rech adapté)

Sub Regler_Hauteur_Cells_Fusionnees()
Dim HauteurInitialeLigne As Single, LargeurFusion As Single
Dim Cellule As Range, Cel As Range
Dim LargeurCellule As Single, NouvelleHauteur As Single
For Each Cel In Range("A1:A" & [A65000].End(xlUp).Row) 'A adapter
    If Cel.MergeCells Then
        LargeurFusion = 0
        With Cel.MergeArea
            .WrapText = True
            If .Rows.Count = 1 Then
                Application.ScreenUpdating = False
                HauteurInitialeLigne = .RowHeight
                LargeurCellule = Cel.ColumnWidth
                For Each Cellule In Cel.MergeArea
                    LargeurFusion = Cellule.ColumnWidth + LargeurFusion
                Next
                .MergeCells = False
                .Cells(1).ColumnWidth = LargeurFusion
                .EntireRow.AutoFit
                NouvelleHauteur = .RowHeight
                .Cells(1).ColumnWidth = LargeurCellule
                .MergeCells = True
                .RowHeight = IIf(HauteurInitialeLigne > NouvelleHauteur, HauteurInitialeLigne, NouvelleHauteur)
            End If
        End With
    End If
Next Cel
End Sub

Bonne soirée

 

[CyberNeo99]

Re : Ajustement de la hauteur d'une ligne avec cellules fusionners...

Bonjour,

Gros Merci pour une réponse aussi rapide et surtout pour le code.

Je vais essayé ça...

Merci encore

Neo 😀

 

[CyberNeo99]

Re : Ajustement de la hauteur d'une ligne avec cellules fusionners...

Bonjour,

Désolé pour avoir pris autant de temps à essayer le code mais j'étais quelque peu déborder par d'autres Pb.

J'ai essayé le code mais malheureusement il ajuste la colonne et plus large que le contenue des cellules fusionner. Ce que j'aimerais serait de garder la largeur original de la colonne mais qu'il ajuste la hauteur de la ligne selon le contenue des cellules fusionner..... Mes cellules fusionner sont toujours dans la même colonne. L'idée reste la même que le code soit fait selon une plage donnée, une colonne comme dans le code ci-haut mais que la largeur de la colonne ne soit pas affecter et que la hauteur s'ajuste automatiquement au contenue....

Merci à l'avance

Neo 😉