Microsoft 365 ajouter une pièce jointe à mon mail

FCMLE44 · 18 Septembre 2020

Bonjour

Le code ci-dessous fonctionne trés bien pour envoyer un mail depuis Excel

VB:

Sub LeMail()

Dim LeMail As Variant

Set LeMail = CreateObject("Outlook.Application") 'Création d'un Objet Outlook

With LeMail.CreateItem(olMailItem) 'informe le programme que nous voulons envoyer un mail
    .Subject = "Votre demande de simulation d'indemnité de départ"
    .To = Range("C4")
    .Body = "Votre Indemnité de départ"
    .Display 'pour afficher le mail avant de l'envoyer sinon Send
End With

End Sub

Néanmoins, je souhaiterais qu'il puisse y rajouter des pièces jointes que j'irais chercher dans l'explorateur windows
Ces fichiers pourront être au format pdf et excel

Merci

FCMLE44 · 18 Septembre 2020

A force de recherche, j'ai trouvé et adapter ma macro
Cela fonctionne

sylvanu · 19 Septembre 2020

Bonjour FCMLE,
Mettez votre code qui marche. Ca servira pour de futurs lecteurs.

FCMLE44 · 21 Septembre 2020

Bonjour

Voici

VB:

'Il faut activer la référence "Microsoft Outlook Library" Avant de lancer cette macro,
' Dans l'éditeur VBA: Faire Menu / Tools / Reference / Cocher "Microsoft Outlook Library"
Sub ChoixMultiFichiers_EnvoiMail()
    Dim Fichiers As Variant
    Dim i As Integer
    Dim Ol As Outlook.Application
    Dim olMail As MailItem
 
    'Affiche la boîte dialogue "Ouvrir"
    '(C'est l'argument True qui autorise la multisélection)
    Fichiers = Application.GetOpenFilename("Tous les fichiers (*.*),*.*", , , , True)
 
   Set Ol = New Outlook.Application
   Set olMail = Ol.CreateItem(olMailItem)
 
    With olMail
        .To = Range("D4")
        .Subject = "Votre demande de calcul d'indemnité de départ "
        .HTMLBody = "<html><body>Bonjour,</body></html><br>" & "<html><body>Veuillez trouver ci-joint la simulation demandée</body></html><br>" & "<html><body>Nous vous en souhaitons bonne réception</body></html><br>" & "<html><body>Cordialement</body></html>" & .HTMLBody 'le corps du mail ..son contenu
 
        'Boucle sur le tableau pour récupérer le nom du ou des classeurs sélectionnées.
        '(IsArray(Fichiers) renvoie False si aucun fichier n'a été sélectionné).
        If IsArray(Fichiers) Then
            For i = 1 To UBound(Fichiers)
                .Attachments.Add Fichiers(i)
            Next
        End If
 
        .Display
    End With
 
End Sub

Il me reste juste à trouver pour que ma signature Outlook se mette par défaut

Si quelqu'un a eu une idée

Merci

sylvanu · 21 Septembre 2020

Bonjour,

Insérer signature Outlook à partir macro excel

Bonjour, le code ci-dessous me génère un mail qui s'affiche directement dans outlook. Tout fonctionne excepté la signature qui ne s'affiche pas, or elle est créée et paramétrée dans Outlook à la base. J'imagine que je dois insérer un bout de code pour la générer automatiquement avec le corps...

www.excel-downloads.com

Macro insertion signature Outlook avec Excel

J 'ai parcouru une multitudes de forums pour savoir comment insérer la signature créée dans Outlook par défaut à la macro suivante qui envoie un mail depuis...

forum.excel-pratique.com

Insertion de signature dans le courrier électronique Outlook à partir d'Excel VBA

J'essaie d'automatiser certains e-mails en utilisant VBA pour Excel. Tout va bien jusqu'à maintenant, sauf essayer de garder ma signature dans le courriel. Une fois que vous avez demandé à VBA de créer ...

stackoverrun.com

danbibi · 23 Septembre 2020

bonjour! j'aimerais savoir comment faire exactement la meme chose sauf que la liste de mails et dans un tableau excel d'une colonne avec pleins de mails de clients. j'ai copier cette VBA sur un bouton pour envoyer
Merci a tous !

FCMLE44 · 23 Septembre 2020

danbibi à dit:
bonjour! j'aimerais savoir comment faire exactement la meme chose sauf que la liste de mails et dans un tableau excel d'une colonne avec pleins de mails de clients. j'ai copier cette VBA sur un bouton pour envoyer
Merci a tous !

Bonjour
Voici le code que j'avais trouvé et qui a été amélioré par une personne qui m'a gentiment aidé.
Je l'ai adapté à mon fichier

VB:

Sub ChoixMultiFichiers_EnvoiMail_ValidSTC()
    Dim Fichiers As Variant
    Dim i As Integer
    Dim Ol As Outlook.Application
    Dim olMail As MailItem
    Dim SigString As String
    Dim Signature As String

    'Affiche la boîte dialogue "Ouvrir"
    '(C'est l'argument True qui autorise la multisélection)
    Fichiers = Application.GetOpenFilename("Tous les fichiers (*.*),*.*", , , , True)

   Set Ol = New Outlook.Application
   Set olMail = Ol.CreateItem(olMailItem)

'Change only Mysig.htm to the name of your signature
SigString = Environ("appdata") & "\Microsoft\Signatures\travail.htm"

If Dir(SigString) <> "" Then
    Signature = GetBoiler(SigString)
Else
    Signature = ""
End If

    With olMail
        .To = Range("AA1")
        .CC = Range("AB1")
        .Subject = "Solde de Tout compte " & Range("B9") & " à valider"
        .HTMLBody = "<html><body>Bonjour,</body></html><br>" & _
            "<html><body>Ci-joint dossier Solde de Tout Compte pour validation</body></html><br>" & _
            "<html><body>Est-il possible de m'informer de sa validation pour envoi courrier au salarié ?</body></html><br>" & _
            "<html><body>Bonne réception</body></html><br>" & "<html><body>Cordialement</body></html>" & _
             "<br>" & Signature & .HTMLBody             'le corps du mail ..son contenu

        'Boucle sur le tableau pour récupérer le nom du ou des classeurs sélectionnées.
        '(IsArray(Fichiers) renvoie False si aucun fichier n'a été sélectionné).
        If IsArray(Fichiers) Then
            For i = 1 To UBound(Fichiers)
                .Attachments.Add Fichiers(i)
            Next
        End If

        .Display
    End With
End Sub

Function GetBoiler(ByVal sFile As String) As String
'Dick Kusleika
    Dim fso As Object
    Dim ts As Object
    Set fso = CreateObject("Scripting.FileSystemObject")
    Set ts = fso.GetFile(sFile).OpenAsTextStream(1, -2)
    GetBoiler = ts.readall
    ts.Close
End Function

Dans cette partie, je vais chercher le mail principal ainsi que la personne en copie dans deux cellules différentes

Code:

With olMail
        .To = Range("AA1")
        .CC = Range("AB1")

A toi de l'adapter à ton tour

danbibi · 23 Septembre 2020

Par exemple, si la colonne de mail est dans la colonne A, je dois mettre:
With olMail
.To = Range("A1")
.CC = Range("A1")
??
desole je n'est pas beaucoup de connaissance en VBA
merci a toi

FCMLE44 · 23 Septembre 2020

danbibi à dit:
Par exemple, si la colonne de mail est dans la colonne A, je dois mettre:
With olMail
.To = Range("A1")
.CC = Range("A1")
??
desole je n'est pas beaucoup de connaissance en VBA
merci a toi

Oui attention en .CC c'est la personne en copie donc ce n'est peut être pas la même

danbibi · 23 Septembre 2020

la personne en copie? c'est quoi exactement ? c'est un champs obligatoire ?

FCMLE44 · 23 Septembre 2020

non, si tu ne veux pas mettre de personne en copie de ton mail, tu supprimes cette ligne

VB:

.CC = Range("A1")

danbibi · 23 Septembre 2020

de plus je tombe sur cette erreur

FCMLE44 · 23 Septembre 2020

Quand tu lances la macro ?

danbibi · 23 Septembre 2020

FCMLE44 · 23 Septembre 2020

Sous quel format sont tes adresses mails ?

Microsoft 365 ajouter une pièce jointe à mon mail

XLDnaute Impliqué

XLDnaute Impliqué

XLDnaute Barbatruc

XLDnaute Impliqué

XLDnaute Barbatruc

XLDnaute Junior

XLDnaute Impliqué

XLDnaute Junior

XLDnaute Impliqué

XLDnaute Junior

XLDnaute Impliqué

XLDnaute Junior

XLDnaute Impliqué

XLDnaute Junior

XLDnaute Impliqué

Discussions similaires

Partager cette page

Statistiques des forums