aide sur trie

[nrdz83]

Bonjour à tous et mes meilleurs voeux.

Voila j'ai une Base de données dans excel et en colonne A des numéros incrémentés ainsi 001 / 2012; 002 / 2012 et ainsi de suuite jusqu'a par exemple 254 / 2012.

Vu la nouvelle année je veux incrémenter mes numéros ainsi 001 / 2013; 002 / 2013 et ainsi de suite.

A la fin de la saisie dans ma feuille excel j'appel ce code afin de trier les données:

Range("A3:L5500").Select
  ActiveWorkbook.Worksheets("BD_Confection").Sort.SortFields.Clear
  ActiveWorkbook.Worksheets("BD_Confection").Sort.SortFields.Add Key:=Range( _
                                                                      "A3:A5500"), SortOn:=xlSortOnValues, Order:=xlAscending, DataOption:= _
                                                                 xlSortNormal
  With ActiveWorkbook.Worksheets("BD_Confection").Sort
    .SetRange Range("A3:L5500")
    .Header = xlGuess
    .MatchCase = False
    .Orientation = xlTopToBottom
    .SortMethod = xlPinYin
    .Apply
  End With
  ActiveWindow.ScrollColumn = 5
  ActiveWindow.ScrollColumn = 4
  ActiveWindow.ScrollColumn = 3
  ActiveWindow.ScrollColumn = 2
  Range("B3").Select

Il se trouve que mes numéros ce range ainsi
001 / 2012
001 / 2013
002 / 2013
002 / 2012
003 / 2012

Comment faire pour que mon trie se fasse d'abord par ... / 2012 puis ... / 2013 ?

Faut-il mettre le format des cellules en format texte?



Par avance merci pour vos lumières

 

[job75]

Re : aide sur trie

Bonsoir,

Une méthode classique :

- insérer une colonne auxiliaire B

- séparer les 2 nombres : en colonne A la partie gauche, en colonne B la partie droite (année)

- trier sur la colonne B puis sur la colonne A

- re-concaténer en colonne A les 2 nombres

- supprimer la colonne B.

Il nous faudrait le fichier pour faire tout ça...

A+

 

[nrdz83]

Re : aide sur trie

re bonsoir à tous

merci job75 mais rajouter une colonne ça va m'obliger à tout refaire mon programme.

Merci tout de même pour tes conseils, je vais bidouiller mon code au lieu de le mettre de A3;L5500 je vais mettre A254:L5500 (début de saisie en 2013)

C'est de la bidouille mais j'aurais à le faire qu'une fois par an lol.

Merci encore

amitiés

 

[job75]

Re : aide sur trie

Bonjour nrdz83,

La colonne B auxiliaire serait supprimée en fin de procédure, j'espère que vous l'avez compris.

Cela dit on peut s'en passer moyennant 2 boucles :

Sub Trier()
Dim tablo, i As Long, s
tablo = Range("A2", [A65536].End(xlUp))
If Application.CountA(tablo) = 1 Then Exit Sub
For i = 1 To UBound(tablo)
  s = Split(Replace(tablo(i, 1), " ", ""), "/")
  If UBound(s) = 1 Then tablo(i, 1) = s(1) & "/" & s(0)
Next
[A2].Resize(i - 1) = tablo
[A2:B2].Resize(i - 1).Sort [A2], Header:=xlNo 'tri
tablo = Range("A2", [A65536].End(xlUp))
For i = 1 To UBound(tablo)
  s = Split(tablo(i, 1), "/")
  If UBound(s) = 1 Then tablo(i, 1) = s(1) & " / " & s(0)
Next
[A2].Resize(i - 1) = tablo
End Sub

Fichier joint.

A+

 

[nrdz83]

Re : aide sur trie

Bonsoir job 75 je te remercie super je vais l'adapter a mon programme.

C'est vraiment super .

Amitiés