Aide sur code VBA appliquer valeur si champ vide.

James007

XLDnaute Barbatruc

• 13 Décembre 2010

• #2

Re : Aide sur code VBA appliquer valeur si champ vide.

Bonjour 🙂

A priori

Code:

Sub SetScope()
With Sheets(1)
Lrow = .Cells(Rows.Count, "A").End(xlUp).Row ''''''' en remplacant B par A ...''''''
For Each c In .Range(Cells(2, 2), Cells(Lrow, 2)) 'indiquer la colonne
If IsEmpty(c.Value) Then c.Value = "yes"
Next c
End With
End Sub

A +
🙂

 

Dernière édition: 13 Décembre 2010

Vote positif 0 Vote négatif

Gorfael

XLDnaute Barbatruc

• 13 Décembre 2010

• #3

Re : Aide sur code VBA appliquer valeur si champ vide.

Salut Soleil11 et le forum
J'ai eu du mal à comprendre (si c'est ça) : Tu veux que ta macro renseigne toutes les cellules de B suivant la plage de A.
Déjà, utilise les balises de code (# en mode avancé)

Comme t'a déjà répondu James007, il ne faut pas baser ton calcul de plage sur B, qui peut être totalement vide, mais sur A. Comme il a déjà répondu, d'autres versions :

Code:

Sub SetScope()
Dim Cel As Range
With Sheets(1)
    For Each Cel In .Range(.Cells(2, "B"), .Cells(Rows.Count, "A").End(xlUp).Offset(0, 1))
        If IsEmpty(Cel) Then Cel = "yes"
    Next Cel
End With
End Sub

Sub SetScope_1()
With Sheets(1)
    .Range(.Cells(2, "B"), .Cells(Rows.Count, "A").End(xlUp).Offset(0, 1)).SpecialCells(xlCellTypeBlanks) = "yes"
End With
End Sub

Les deux font la même chose.
A+

 

Vote positif 0 Vote négatif

S

Soleil11

XLDnaute Occasionnel

• 15 Décembre 2010

• #4

Re : Aide sur code VBA appliquer valeur si champ vide.

Bonjour le forum,

Le code ci-dessus fonctionne parfaitement mais existe-t-il un code plus rapide mon tableau fait 40'000 lignes et je le trouve un peu lent.

Merci pour votre aide à nouveau.

Soleil11

 

Vote positif 0 Vote négatif

Gorfael

XLDnaute Barbatruc

• 15 Décembre 2010

• #5

Re : Aide sur code VBA appliquer valeur si champ vide.

Salut Soleil11
Tu as testé SetScope_1 ? Pas sûr qu'on puisse faire plus rapide.
A+

 

Vote positif 0 Vote négatif

S

Soleil11

XLDnaute Occasionnel

• 15 Décembre 2010

• #6

Re : Aide sur code VBA appliquer valeur si champ vide.

Rebonjour,

Désolé vous avez raison la SetScope1 est vraiement plus rapide.

Merci à tout le forum pour votre précieuse aide.

Soleil11

 

Vote positif 0 Vote négatif

ROGER2327

XLDnaute Barbatruc

• 15 Décembre 2010

• #7

Re : Aide sur code VBA appliquer valeur si champ vide.

Bonsoir à tous

Salut Soleil11
Tu as testé SetScope_1 ? Pas sûr qu'on puisse faire plus rapide.
A+

Cliquez pour agrandir...

Je crois que si :

Code:

Sub toto()
Dim i&, oDat, oPlg As Object
  With Sheets(1)
    Set oPlg = Range(.Cells(1, 1), .Cells(.Rows.Count, 1).End(xlUp).Offset(0, 1))
    If Not oPlg Is Nothing Then
      oDat = oPlg.Value
      For i = 2 To UBound(oDat, 1)
        If Not IsEmpty(oDat(i, 1)) And IsEmpty(oDat(i, 2)) Then oDat(i, 2) = "yes"
      Next
    End If
    oPlg.Value = oDat
  End With
End Sub

​

ROGER2327
#4756

Dimanche 15 Sable 138 (Khurmookum du Dr Faustroll, SS)
25 Frimaire An CCXIX
2010-W50-3T16:55:42Z

 

Dernière édition: 15 Décembre 2010

Vote positif 0 Vote négatif