Aide pour VBA

[MASSJIPE]

Bonjour
je cherche un code pour copier des cellules d'une feuille et coller sur autre feuille à la ligne
le classeur est fait avec 2 feuilles vierge et suivi
La feuille vierge reste comme le nom l'indique après que la macro à fait son job
Copier dans cette feuille (vierge)
Cellule F3 F4 F7 R7 F8 G13
Coller dans la feuille suivi (case jaune) à la ligne car d'autre blocage peut être crée

Après la macro fait ceci
Sub Créationfeuilblocage()
ThisWorkbook.ActiveSheet.Copy
ActiveSheet.Name = Range("F3")
ChDir "C:\Users\jean-paul\Desktop"
ActiveWorkbook.SaveAs Filename:="C:\Users\jean-paul\Desktop\" & ActiveSheet.Name & ".xls", _
FileFormat:=xlExcel8, Password:="", WriteResPassword:="", _
ReadOnlyRecommended:=False, CreateBackup:=False
End Sub
Merci

 

[Staple1600]

Re : Aide pour VBA

Bonjour à tous

MASSJIPE: EDITION: ajout macro pour recopie
Code VBA:
Sub Copie_De_VIERGE_vers_SUIVI()
'Déclarations variables
Dim adrCellACopier, adrCellDestination, dl&, i As Byte
'Arrays avec adresses des cellules concernées
adrCellACopier = Array("F3", "F4", "F7", "R7", "F8", "G13")
adrCellDestination = Array("A", "D", "E", "F", "G", "H")
'recopie des valeurs (seules sans le format) , choisies de la feuille vierge vers la feuille suivi
With Sheets("suivi")
dl = .Range("A65536").End(xlUp).Row + 1
For i = LBound(adrCellACopier) To UBound(adrCellACopier)
.Range(CStr(adrCellDestination(i)) & dl).Value = Sheets("vierge").Range(adrCellACopier(i)).Value
Next i
End With
End Sub

Essaies ton code ainsi modifié (pour ce qui est de la création d'une feuille)
Code vba:
Sub CréationfeuilblocageII()
Dim NomNouvelleFeuille$, Chemin$, NomFichier$
NomNouvelleFeuille = ActiveSheet.Range("F3").Text
ThisWorkbook.ActiveSheet.Copy
ActiveSheet.Name = NomNouvelleFeuille
Chemin = "C:\Users\jean-paul\Desktop\"
NomFichier = Chemin & ActiveSheet.Name & ".xls"
ActiveWorkbook.SaveAs NomFichier
End Sub

 

[MASSJIPE]

Re : Aide pour VBA

Bonjour
Et si je veux associer les deux codes ensemble comment on fait
merci

 

[Staple1600]

Re : Aide pour VBA

Re

Comme cela par exemple 😉
Code VBA:
Sub Traitement()
Application.ScreenUpdating=False
Copie_De_VIERGE_vers_SUIVI
CréationfeuilblocageII
Application.ScreenUpdating=True
End sub

 

[MASSJIPE]

Re : Aide pour VBA

Bonsoir
Par contre j'ai un message à l'ouverture de la feuille créée
Merci

 

[Staple1600]

Re : Aide pour VBA

Bonsoir à tous

MASSJIPE
Quelle est ta version d'Excel? EXCEL 2003 ?
A tout hasard, essaies avec les modifs ci-dessous
Code vba:
Sub Traitement()
Application.ScreenUpdating = False
Copie_De_VIERGE_vers_SUIVI
CreationFeuilBlocageIII
Application.ScreenUpdating = True
End Sub
Code VBA:
Private Sub Copie_De_VIERGE_vers_SUIVI()
'Déclarations variables
Dim adrCellACopier, adrCellDestination, dl&, i As Byte
'Arrays avec adresses des cellules concernées
adrCellACopier = Array("F3", "F4", "F7", "R7", "F8", "G13")
adrCellDestination = Array("A", "D", "E", "F", "G", "H")
'recopie des valeurs (seules sans le format) , choisies de la feuille vierge vers la feuille suivi
With Sheets("suivi")
dl = .Range("A65536").End(xlUp).Row + 1
For i = LBound(adrCellACopier) To UBound(adrCellACopier)
.Range(CStr(adrCellDestination(i)) & dl).Value = Sheets("vierge").Range(adrCellACopier(i)).Value
Next i
End With
End Sub
Code VBA:
Private Sub CreationFeuilBlocageIII()
Dim NomNouvelleFeuille$, Chemin$, NomFichier$
NomNouvelleFeuille = ActiveSheet.Range("F3").Text
ThisWorkbook.ActiveSheet.Copy
ActiveSheet.Name = NomNouvelleFeuille
Chemin = "C:\Users\jean-paul\Desktop\"
NomFichier = Chemin & ActiveSheet.Name & ".xlsm"
ActiveWorkbook.SaveAs Filename:=NomFichier, FileFormat:=52
End Sub

 

[MASSJIPE]

Re : Aide pour VBA

Bonjour
merci beaucoup du coup de main