Aide avec l'objet dictionnary

[arthurho]

Bonjour,

Je souhaite utiliser l'objet dictionnary pour enlever les doublons dans une liste.

Cette liste est présente dans l'onglet "Feuil2", et j'execute le script sur "Feuil1"

Je souhaite obtenir le resultat sur une range différente de la range que je parcours.

J'ai réalisé le script suivant :

Sub test()
    
Dim DicoVersion As Object, VersionRange As Range, item As Variant, VersionNb As Long

Set DicoVersion = CreateObject("Scripting.Dictionary")
    Application.ScreenUpdating = False
VersionNb = 20
        With Sheets("Feuil2").Select
        'Récupération du nom de la version pour chaque item'
            Selection.Range("AI1:A" & Range("AI65536").End(xlUp).Row + 1).ClearContents
                MsgBox "test"
                '.Range("AI1:A" & Range("AI65536").End(xlUp).Row + 1).ClearContents
                'boucle cellules colonne A
                
                For Each VersionRange In Range("A2:A" & Range("A65536").End(xlUp).Row)
                               
                    If Not DicoVersion.Exists(VersionRange.Value) Then DicoVersion.Add VersionRange.Value, VersionRange.Value
        
                Next VersionRange
                For Each item In DicoVersion.items
                    Selection.Range("AI" & VersionNb) = item
                    VersionNb = VersionNb + 1
                Next
                'tri ascendant'
                    Range("AI20:AI" & Range("AI65536").End(xlUp).Row).Sort Key1:=Range("AI20"), Header:=xlGuess
                End With
                Set DicoVersion = Nothing
                Application.ScreenUpdating = True
                
End Sub

Malheureusement, mes item sont vides.

Avez vous une solution ?

Merci

Cdt,

Arthur HO.

 

[flyonets44]

Re : Aide avec l'objet dictionnary

Bonjour
en retour ton fichier avec une macro
Cordialement
Flyonets

 

[pierrejean]

Re : Aide avec l'objet dictionnary

bonjour arturho

une macro pour ce que tu souhaites

Sub essai()
Set dico = CreateObject("scripting.dictionary")
For n = 2 To Sheets("Feuil2").Range("A65536").End(xlUp).Row
 x = Sheets("Feuil2").Range("A" & n)
 dico(x) = x
Next n
Range("AI1").Resize(dico.Count) = Application.Transpose(dico.keys)
End Sub

Edit : Salut Flyonets

 

[flyonets44]

Re : Aide avec l'objet dictionnary

Salut pierrejeanjean
tes contributions m'ont souvent dépanné
un grand merci à toi
Cordialement
Flyonets

 

[arthurho]

Re : Aide avec l'objet dictionnary

Merci à vous deux, la reactivité de ce forum est incroyable .

Bonne journée

 

[BOISGONTIER]

Re : Aide avec l'objet dictionnary

Bonjour,

+rapide

Set mondico = CreateObject("Scripting.Dictionary")
a = Range("a2", [a65000].End(xlUp)).Value    ' lecture dand tableau + rapide
For Each c In a
  mondico(c) =""
Next c
[c2].Resize(mondico.Count, 1) = Application.Transpose(mondico.keys)

Objet dictionary

JB

 

[pierrejean]

Re : Aide avec l'objet dictionnary

Re

Merci JB

 

[laurent950]

Re : Aide avec l'objet dictionnary

Bonsoir, Boisgontier, Pierrejean , Flyonets44, Le fil, Le forum.

J'ai une question par rapport a "Boigontier" est votre code pour comprendre quelque choses :

- a = Range("a2", [a65000].End(xlUp)).Value ' ici a c'est la plage de A2:A (a la dernière cellule non vide de la colonne A)

a = correspond a toutes les valeurs de cette plage.

Quelle différence entre :

a = toute les valeurs de la plage

Ou

dim a() as variant
a = toutes les valeurs de la plage

C'est à dire que "a" est une variable qui contient des données dans les deux cas (j'aurais aimé savoir si "a" avait était déclarer comme un tableau, votre code aurais fonctionner :

Différemment ?
Ou
Ce n’est pas possible ?
Ou
C'est les mêmes choses car est forcément un tableau de type variant ? (dans les 2 cas)
Ou
Il y a une autre astuce ?

Merci à vous est vos réponses, Mr Boigontier ou Mr Pierrejean

Laurent

 

[BOISGONTIER]

Re : Aide avec l'objet dictionnary

Bonsoir,

Le tableau a() peut être déclaré ou non. Il est du type variant et à 2 dimensions (1 To n,1 To 1)

Sub essai()
  'Dim a() As Variant
  Set mondico = CreateObject("Scripting.Dictionary")
  a = Range("a2", [a65000].End(xlUp)).Value    ' lecture dans tableau + rapide
  For Each c In a
    mondico(c) = ""
  Next c
  [c2].Resize(mondico.Count, 1) = Application.Transpose(mondico.keys)
  MsgBox TypeName(a)
  MsgBox UBound(a, 1)
  MsgBox UBound(a, 2)
End Sub

JB

 

[laurent950]

Re : Aide avec l'objet dictionnary

Bonsoir, Mr Boisgontier

Je vous remercie pour votre réponse qui me permet de comprendre un peux plus chaque jour.

Laurent