Afficher une durée en jours et heure

hassan.zer · 12 Janvier 2010

Bonsoir, Re,

Je souhaiterai afficher une durée restante entre 2 dates sous le format 2 jours 8 heures, auriez-vous une solution ? Merci.

Et encore merci à ce forum !

jeanpierre · 12 Janvier 2010

Re : Afficher une durée en jours et heure

Bonsoir hassan.zer,

Essaie avec, en D4 :

=DATEDIF(B4;C4;"d")&" jours "&TEXTE(C4-B4;"hh")&" heures"
Bonne soirée.

Jean-Pierre

job75 · 12 Janvier 2010

Re : Afficher une durée en jours et heure

Bonsoir hassan.zer,

Pas certain d'avoir bien compris, mais peut-être cette formule :

Code:

=ENT(C4-B4)&" jours "&ENT(24*(C4-B4-ENT(C4-B4)))&" heures"

On pourrait faire assez facilement un traitement pour supprimer les "s" s'il y a 0 ou 1 jour ou heure, mais ça compliquerait la formule et ferait un peu besogneux.

Edit : bonsoir jeanpierre, pas rafraîchi.

Tu as raison, TEXTE(C4-B4;"hh")&" heures" c'est mieux...

A+

Goose · 12 Janvier 2010

Re : Afficher une durée en jours et heure

Bsr,

formule en D4 (en année, mois et jours): a adapter a ton cas

Code:

=SI(B4="";"";SI(ET(DATEDIF(B4;C4;"y")=0;DATEDIF(B4;C4;"ym")=0;DATEDIF(B4;C4;"md")=0);0;SI(DATEDIF(B4;C4;"y")<>0;DATEDIF(B4;C4;"y")&SI(DATEDIF(B4;C4;"y")>1;" ans";" an");"")&SI(ET(DATEDIF(B4;C4;"y")<>0;DATEDIF(B4;C4;"ym")<>0;DATEDIF(B4;C4;"md")=0);" et ";"")&SI(ET(DATEDIF(B4;C4;"y")<>0;DATEDIF(B4;C4;"ym")=0;DATEDIF(B4;C4;"md")<>0);" et ";"")&SI(ET(DATEDIF(B4;C4;"y")<>0;DATEDIF(B4;C4;"ym")<>0;DATEDIF(B4;C4;"md")<>0);", ";"")&SI(DATEDIF(B4;C4;"ym")<>0;DATEDIF(B4;C4;"ym")&" mois ";"")&SI(ET(DATEDIF(B4;C4;"ym")<>0;DATEDIF(B4;C4;"md")<>0);"et ";"")&SI(DATEDIF(B4;C4;"md")<>0;DATEDIF(B4;C4;"md")&SI(DATEDIF(B4;C4;"md")>1;" jours";" jour");"")))

ROGER2327 · 13 Janvier 2010

Re : Afficher une durée en jours et heure

Bonsoir à tous

Des variantes.

Code:

[B][COLOR="DarkSlateGray"]=SUPPRESPACE(SI(ENT(C4-B4);ENT(C4-B4)&" jour"&SI(ENT(C4-B4)>1;"s ";" ");"")&SI(MOD(C4-B4;1);TEXTE(MOD(C4-B4;1);SI(MOD(C4-B4;1)>1/24;"h"" heures ""mm";"h"" heure ""mm"));""))
=SUPPRESPACE(SI(ENT(C4-B4);ENT(C4-B4)&"j ";"")&SI(MOD(C4-B4;1);TEXTE(MOD(C4-B4;1);"h""h""mm");""))
=TEXTE(C4-B4;"j""j ""h""h""mm")
=TEXTE(C4-B4+1/48;"j""j ""h""h""")[/COLOR][/B]

au format Standard.

Code:

[COLOR="DarkSlateGray"][B]=C4-B4[/B][/COLOR]

au format j"j" h"h"mm.

Code:

[COLOR="DarkSlateGray"][B]=C4-B4+1/48[/B][/COLOR]

au format j"j" h"h".

ROGER2327
#2585

hassan.zer · 13 Janvier 2010

Re : Afficher une durée en jours et heure

Merci bien, jai trouvé ce qu'il me fallait dans vos solutions !!!! Merci encore !

Goose · 13 Janvier 2010

Re : Afficher une durée en jours et heure

Bjr à tous,
dis moi Roger, aurais tu une variante avec (année, mois et jours) ?
merci
@+

ROGER2327 · 13 Janvier 2010

Re : Afficher une durée en jours et heure

Re...

Goose à dit:
Bjr à tous,
dis moi Roger, aurais tu une variante avec (année, mois et jours) ?
merci
@+

Non.

Bonne soirée,
ROGER2327
#2589

job75 · 13 Janvier 2010

Re : Afficher une durée en jours et heure

Bonsoir le fil,

Goose à dit:
dis moi Roger, aurais tu une variante avec (année, mois et jours)

Cette formule en C2 du fichier joint :

Code:

=DATEDIF(A2;B2;"y")&" ans "&DATEDIF(A2;B2;"m")-12*DATEDIF(A2;B2;"y")&" mois "&DATEDIF(DATE(ANNEE(B2);MOIS(B2)-(JOUR(A2)>JOUR(B2));JOUR(A2));B2;"d")&" jours"

Goose, on vouvoie Roger

A+

ROGER2327 · 14 Janvier 2010

Re : Afficher une durée en jours et heure

Bonsoir job75

job75 à dit:
(...)
Goose, on vouvoie Roger
(...)

C'est vous qui le dites... En réalité, il n'y a pas de règle stricte en la matière : chacun étant libre de sa conception de la bienséance, ROGER2327 voussoie Goose et job75 parce qu'il lui plait d'en user ainsi, tandis que job75 et Goose tutoient ROGER2327 parce qu'ils en ont envie.
Et c'est ainsi que tout va pour le mieux dans le meilleur des mondes.

Bonne nuit.
ROGER2327
#2592

Goose · 14 Janvier 2010

Re : Afficher une durée en jours et heure

merci job
@+

archi · 14 Janvier 2010

Re : Afficher une durée en jours et heure

Bonjour à tous,
en s'appuyant sur la formule de JOB75, y a t'il une façon de simplifier la formule ci-dessous avec les arguments de formule de Roger ?
merci d'avance
bye

=SI(E16="";"";SI(ET(DATEDIF(E16;AUJOURDHUI();"y")=0;DATEDIF(E16;AUJOURDHUI();"ym")=0;DATEDIF(E16;AUJOURDHUI();"md")=0);0;SI(DATEDIF(E16;AUJOURDHUI();"y")<>0;DATEDIF(E16;AUJOURDHUI();"y")&SI(DATEDIF(E16;AUJOURDHUI();"y")>1;" ans";" an");"")&SI(ET(DATEDIF(E16;AUJOURDHUI();"y")<>0;DATEDIF(E16;AUJOURDHUI();"ym")<>0;DATEDIF(E16;AUJOURDHUI();"md")=0);" et ";"")&SI(ET(DATEDIF(E16;AUJOURDHUI();"y")<>0;DATEDIF(E16;AUJOURDHUI();"ym")=0;DATEDIF(E16;AUJOURDHUI();"md")<>0);" et ";"")&SI(ET(DATEDIF(E16;AUJOURDHUI();"y")<>0;DATEDIF(E16;AUJOURDHUI();"ym")<>0;DATEDIF(E16;AUJOURDHUI();"md")<>0);", ";"")&SI(DATEDIF(E16;AUJOURDHUI();"ym")<>0;DATEDIF(E16;AUJOURDHUI();"ym")&" mois ";"")&SI(ET(DATEDIF(E16;AUJOURDHUI();"ym")<>0;DATEDIF(E16;AUJOURDHUI();"md")<>0);"et ";"")&SI(DATEDIF(E16;AUJOURDHUI();"md")<>0;DATEDIF(E16;AUJOURDHUI();"md")&SI(DATEDIF(E16;AUJOURDHUI();"md")>1;" jours";" jour");"")))

Afficher une durée en jours et heure

hassan.zer

XLDnaute Occasionnel

Pièces jointes

jeanpierre

Nous a quitté

job75

XLDnaute Barbatruc

Goose

XLDnaute Occasionnel

ROGER2327

XLDnaute Barbatruc

Pièces jointes

hassan.zer

XLDnaute Occasionnel

Goose

XLDnaute Occasionnel

ROGER2327

XLDnaute Barbatruc

job75

XLDnaute Barbatruc

Pièces jointes

ROGER2327

XLDnaute Barbatruc

Goose

XLDnaute Occasionnel

archi

XLDnaute Impliqué

Discussions similaires