Afficher Colonne masquées avec Workbook

[Gonteur]

Bonjour,

Je cherche à réinitialiser une feuille Excel à son ouverture

J'ai réussi à supprimer les filtres
Private Sub Workbook_Open()
With ThisWorkbook.Worksheets("Ma Feuille")
If .FilterMode Then .ShowAllData
End With
End Sub

Mais je n'y arrive pas pour les colonnes et/ou lignes masquées

Merci de l'intérêt que vous y porterez

 

[youky(BJ)]

Bonjour Gonteur,

Private Sub Workbook_Open()
With ThisWorkbook.Worksheets("Ma Feuille")
If .FilterMode Then .ShowAllData
.rows("1:" & .UsedRange.row).hidden=false
.columns("1:" & .UsedRange.column).hidden=false
End With
End Sub

ceci doit faire l'affaire
Bruno

 

[Gonteur]

Merci Bruno, ton aide est apprécié

Avec ce code,
Les filtres s'enlèves mais les colonnes reste cachées + erreur d'exécution "1004"

 

[Gonteur]

Bonjour,

Voici la solution fonctionnel

Private Sub Workbook_Open()
With ThisWorkbook.Worksheets("Ma Feuille")
If .FilterMode Then .ShowAllData
Columns("A:ZZ").Select
Selection.EntireColumn.Hidden = False
End With
End Sub

Merci de votre aide

 

[youky(BJ)]

Eviter les select
Columns("A:ZZ").Hidden=false
cela suffit

Sans fichier on fait à l'aveuglette comme j'ai pas testé j'ai mis des nombres au lieu des chiffres.
Bruno

 

[Gonteur]

Merci Bruno

Private Sub Workbook_Open()
With ThisWorkbook.Worksheets("Ma Feuille")
If .FilterMode Then .ShowAllData
Columns("A:ZZ").Hidden = False
End With
End Sub

 

[Si...]

Bon_soir

Voici la solution fonctionnelle ???

L'as-tu essayée avec une autre feuille que "Ma feuille" sélectionnée à l'ouverture (comme à la sauvegarde) ?

Ce serait mieux avec le point

.Columns("A:ZZ").Select

Mieux encore, pour éviter d'oublier des colonnes ,

.Cells.Columns.Hidden = 0

Et pour simplifier davantage commencer par

Sheets("Ma Feuille ").Select

(les points de référence n'étant plus nécessaires )

 

[Gonteur]

Merci Si...

Effectivement, ne fonctionne pas si on ouvre pas sur "Ma Feuille" . Comment appliquer la règle sur tout le classeur?

code fonctionnel pour "Ma Feuille"

Private Sub Workbook_Open()
With ThisWorkbook.Worksheets("Billets 17-18")
If .FilterMode Then .ShowAllData
Sheets("Billets 17-18").Select
.Cells.Columns.Hidden = 0
.Cells.Rows.Hidden = 0

End With
End Sub

 

[Si...]

Re

essaie :

Private Sub Workbook_Open()
  Dim Sh As Worksheet
  For Each Sh In Sheets
      If Sh.FilterMode Then Sh.ShowAllData
      Sh.Cells.Rows.Hidden = 0:  Sh.Cells.Columns.Hidden = 0
  Next
End Sub

 

[Gonteur]

Merci Si...

Génère l'erreur

Erreur d'exécution '1004':
Impossible de définir la propriété Hidden de la classe Range

 

[youky(BJ)]

Bonjour,
C'est parce qu'une ou plusieurs pages sont protégées.
Bruno

Private Sub Workbook_Open()
  Dim Sh As Worksheet
  For Each Sh In Sheets
    Sh.Unprotect
      If Sh.FilterMode Then Sh.ShowAllData
      Sh.Cells.Rows.Hidden = 0:  Sh.Cells.Columns.Hidden = 0
  Next
End Sub

 

[Gonteur]

Merci Si...
Effectivement, le problème provient de certaines feuilles qui sont protégés 😳 et tel quel c'est fonctionnel.

Le problème maintenant est que le code modifie toutes les feuilles, pas ce que je recherche, comment soustraire les feuilles protégé de la vérification du code? Et ce en maintenant que si je ferme le classeur sur une feuille protégée, le code s'applique, à l'ouverture à toutes les feuilles non protégées.

 

[Gonteur]

Merci beaucoup Si... de ton aide

Voici le code adapté qui correspond exactement à mes besoins

Private Sub Workbook_Open()
Dim Sh As Worksheet
For Each Sh In Sheets
If Not Sh.ProtectContents Then
If Sh.FilterMode Then Sh.ShowAllData
Sh.Cells.Rows.Hidden = 0: Sh.Cells.Columns.Hidden = 0
End If
Next
End Sub

Au plaisir!

 

[Si...]

Bon_jour

C'est Bruno 😉qui t'a parlé de feuilles protégées donc tu peux aussi le remercier pour l'idée 😎.

Je n'ai pas répondu avant car je ne savais pas ce que tu voulais exactement (traiter des onglets protégés - avec peut-être des conditions différentes - ou au contraire les autres !)

Tu as su quand même t'en sortir. C'est bien.

 

[Gonteur]

Effectivement merci Bruno
Votre aide à tous les deux a été très apprécié
Au plaisir!