XL 2010 affichage image dans cellule

Thalie à dit:

Y a personne qui peut m'aider 😉

Cliquez pour agrandir...

job75 à dit:

Bonjour,

Le plus simple est d'introduire chaque image dans le commentaire de la cellule en colonne C .

Voyez le fichier (zippé) joint avec ce code :

VB:

Sub Images()
Dim coef#, chemin$, i&, fichier$, o As Object
coef = 2 'coefficient d'agrandissement des images, à adapter
chemin = ThisWorkbook.Path & "\"
Application.ScreenUpdating = False
With [Tableau1]
    .Columns(3).ClearComments
    For i = 1 To .Rows.Count
        fichier = Dir(chemin & .Cells(i, 1) & ".jpg")
        If fichier <> "" Then
            Set o = ActiveSheet.Pictures.Insert(chemin & fichier) 'image temporaire
            o.ShapeRange.LockAspectRatio = msoTrue 'verrouille les proportions
            o.Width = o.Width * coef 'agrandissement
            With .Cells(i, 3).AddComment("").Shape 'crée le commentaire
                .Width = o.Width
                .Height = o.Height
                .Fill.UserPicture chemin & fichier
            End With
            o.Delete 'supprime l'image temporaire
        End If
    Next
End With
End Sub

L'image s'affiche au survol de la cellule par la souris.

A+

Cliquez pour agrandir...