Affichage automatique dans les 2 sens

[REDGS]

Bonjours le forum,

En mode vba, comment faire SI A2 ="G" AFFICHER AUTOMATIQUEMENT "P" DANS A1 ET VICE VERSA.
DE MEME POUR A4-A5, A7-A8 ETC (il y a une cellule vide toutes les 2 cellules)
Fichier joint.
Merci de votre aide.
cordialement
Redgs

 

[phlaurent55]

Re : Affichage automatique dans les 2 sens

Bonjour Redgs,

la question me semble imprécise
ton fichier en retour
il suffit de mettre les scores en colonne A & D
mais il faudrait penser à gérer les "match nuls"

à+
Philippe

 

[phlaurent55]

Re : Affichage automatique dans les 2 sens

Re,

pour gérer les égalités

à+
Philippe

 

[REDGS]

Re : Affichage automatique dans les 2 sens

Bonjours Philippe,

Il n'y a pas de match nul, effectivement je faisais en inscrivant les scores, mais ceux-ci sont sans importance car les gagnants vont dans un sens et les perdants dans un autre. Donc en inscrivant uniquement le "G" je simplifie l'enregistrement du résultat.
A+
Redgs

 

[Pierrot93]

Re : Affichage automatique dans les 2 sens

Bonjour Redgs, Philippe

une solution vba, procédure événementielle à placer dans le module de la feuille concernée => click droit sur l'onglet => visualiser le code et tu le colles :

Option Explicit
Dim b As Boolean
Private Sub Worksheet_Change(ByVal Target As Range)
If b Then Exit Sub
If Target.Count > 1 Then Exit Sub
If Target.Row > 17 Or (Target.Column <> 2 And Target.Column <> 5) Then Exit Sub
If Target.Row Mod 3 = 0 Then Exit Sub
If UCase(Target.Value) <> "G" And UCase(Target.Value) <> "P" Then Exit Sub
b = True
Target.Offset(IIf(Target.Row Mod 3 = 1, 1, -1), 0).Value = IIf(UCase(Target.Value) = "G", "P", "G")
b = False
End Sub

bonne fin d'après midi
@+

 

[Robert]

Re : Affichage automatique dans les 2 sens

bonjnour Redgs, bonjour le forum,

SI A2 ="G" AFFICHER AUTOMATIQUEMENT "P" DANS A1 ET VICE VERSA.

Mais que est le versa du vice ?
1 - SI A2 ="P" AFFICHER AUTOMATIQUEMENT "G" DANS A1 ?
2 - SI A1 ="P" AFFICHER AUTOMATIQUEMENT "G" DANS A2 ?
Dans la macro événementeielle Change ci-dessous j'ai opté pour la seconde possibilité :

Private test As Boolean 'déclare la variable test
Private Sub Worksheet_Change(ByVal Target As Range) 'au changement dans l'onglet
Dim plp As Range 'déclare la variable plp (PLage des P) qui borde la mer d'alors bien entendu...
Dim plg As Range 'déclare la variable plg (PLage des G)
If test = True Then Exit Sub 'si la variable test est vrai, sort de la procédure
If Target.Cells.Count > 1 Then Exit Sub 'si la sélection contient plus d'une seule cellule, sort de la procédure
'définit la variable plp
Set plp = Application.Union(Range("B1"), Range("B4"), Range("B7"), Range("B10"), Range("B13"), Range("B16"), _
    Range("E1"), Range("E4"), Range("E7"))
'définit la variable plg
Set plg = Application.Union(Range("B2"), Range("B5"), Range("B8"), Range("B11"), Range("B14"), Range("B17"), _
    Range("E2"), Range("E5"), Range("E8"))
'condition 1 : si le changement a lieu dans la plage des p
If Not Application.Intersect(Target, plp) Is Nothing Then
    'définit la variable test, écrit "G" ou rien dans la cellule en dessous
    test = True: Target.Offset(1, 0) = IIf(UCase(Target.Value) = "P", "G", "")
'condition 2 : si le changement a lieu dans la plage des g
ElseIf Not Application.Intersect(Target, plg) Is Nothing Then
    'définit la variable test, écrit "P" ou rien dans la cellule au dessus
    test = True: Target.Offset(-1, 0) = IIf(UCase(Target.Value) = "G", "P", "")
End If 'fin des condition
test = False 'réinitialise la variable test
End Sub

[Édition]
Bonjour Philippe, Pierrot, on s'est croisé...

 

[youky(BJ)]

Re : Affichage automatique dans les 2 sens

Bonjour à tous,
Je suis à la bourre mais comme j'avais fait et planté Excel je fais malgrès tout suivre le fichier
Bruno

 

[REDGS]

Re : Affichage automatique dans les 2 sens

Pierrot, c'est exactement ce que je recherchais.
Merci à vous deux d'avoir répondu à ma demande.
Cordialement
Redgs

Merci également à Robert et Youky.