Affectation d'une macro aux touches PgDOwn et PgUp

[Chri8Ed]

Bonjour

Je souhaiterais affecter une macro aux touches PgDOwn et PgUp

En fait quand j'appuie sur la touche PdDown
Au lieux de faire ce que cette touche fait normalement
Je souhaiterais qu'elle lance ma macro Page_Down ().

Mais je veux aussi que cela ne concerne qu'une feuille de mon classeur et pas les autres.

J'ai bien penser à l'application OnKey, mais sans succès

Merci d'avance pour votre aide
A+

 

[PMO2]

Re : Affectation d'une macro aux touches PgDOwn et PgUp

Bonjour,

Peut être comme ce qui suit

1) copiez le code suivant dans la fenêtre de code de ThisWorkbook

Private Sub Workbook_Activate()
If ActiveSheet.Name = MA_FEUILLE Then Call OnKey_On
End Sub

Private Sub Workbook_Deactivate()
Call OnKey_Off
End Sub

Private Sub Workbook_SheetActivate(ByVal Sh As Object)
If Sh.Name = MA_FEUILLE Then
  Call OnKey_On
Else
  Call OnKey_Off
End If
End Sub

2) Copiez le suivant dans un module Standard en ayant pris soin d'adapter la constante MA_FEUILLE du nom de la feuille concernée

'### Constante à adapter ###
Public Const MA_FEUILLE As String = "test"
'###########################

Sub OnKey_On()
With Application
  .OnKey "{PGDN}", "PageDown"
  .OnKey "{PGUP}", "PageUp"
End With
End Sub

Sub OnKey_Off()
With Application
  .OnKey "{PGDN}"
  .OnKey "{PGUP}"
End With
End Sub

Sub PageDown()
MsgBox "page down"
End Sub

Sub PageUp()
MsgBox "page up"
End Sub

 

[Chri8Ed]

Re : Affectation d'une macro aux touches PgDOwn et PgUp

Bonjour PM02

Je découvre ta macro que maintenant, suite à un déplacement pour mon travail

J'avais trouvé une solution par moi-même, qui fonctionnait ma fois très bien
Mais je trouve que ta macro est mieux écrite
et certainement plus sûre
Je viens donc de l'adopter et je te remercie pour ce développement

A+