Adresse d une cellule suivant 3 criteres

Tibo

XLDnaute Barbatruc

• 29 Mars 2008

• #2

Re : Adresse d une cellule suivant 3 criteres

Bonjour,

Une solution avec une formule matricielle, mais avec une concaténation :

Code:

=INDEX(BASE!C2:E6;EQUIV(B6&B7;BASE!A2:A6&BASE!B2:B6;0);
EQUIV(B8;BASE!C1:E1;0))

Formule à valider par CTRL + MAJ + ENTREE

Une autre sans concaténation et sans validation matricielle :

Code:

=INDEX(BASE!C2:E6;SOMMEPROD((BASE!A2:A6=B6)*(BASE!B2:B6=B7)*
LIGNE(BASE!A2:A6))-1;EQUIV(B8;BASE!C1:E1;0))

Je te laisse tester

@+

 

Vote positif 0 Vote négatif

M

Monique

Nous a quitté

Repose en paix

• 29 Mars 2008

• #3

Re : Adresse d une cellule suivant 3 criteres

Bonjour,

Ou bien
=SOMMEPROD((BASE!A2:A6=B6)*(BASE!B2:B6=B7)*(BASE!C1:E1=B8);BASE!C2:E6)

ou bien
=SOMMEPROD((BASE!A2:A6&BASE!B2:B6=B6&B7)*(BASE!C1:E1=B8);BASE!C2:E6)

 

Vote positif 0 Vote négatif

R

ri2

XLDnaute Nouveau

• 29 Mars 2008

• #4

Re : Adresse d une cellule suivant 3 criteres

Merci, la 2eme solution me convient car je ne veux pas avoir a modifier ma base.
Par contre, j'etais plutot parti sur les fonctions indirect adresse pour avoir a eviter justement la fonction sommeprod qui est "gourmande" sur une grosse base de donnes.
En te remerciant
@+

 

Vote positif 0 Vote négatif

R

ri2

XLDnaute Nouveau

• 29 Mars 2008

• #5

Re : Adresse d une cellule suivant 3 criteres

Oups, pas vu l'arrivée de Monique. Merci à toi également. Maitrisant mal la fonction Index, je pense que je vais retenir ta solution
Cordialement

 

Vote positif 0 Vote négatif

G

GIBI

XLDnaute Impliqué

• 29 Mars 2008

• #6

Re : Adresse d une cellule suivant 3 criteres

bonjour,

dans votre exemple il faut mettre dans la cellule résultat (exemple en D7)

=INDEX(BASE!C2:H20;EQUIV(B7;DECALER(BASE!B2:B20;EQUIV(B6;BASE!A2:A20;0)-1;0;NB.SI(BASE!A2:A20;B6);1);0);EQUIV(B8;BASE!C1:H1;0))

rechercher le 1ier N) de ligne du véhicule EQUIV(B6;BASE!A2:A20;0)
Redefinir la plage du model avec DECALER
Rechercher le n° de ligne du model dans la plage "décaler"
Etc..


Et voila!

Maintenant un peu de reflexion

GIBI


PS Méthode plus génarale car la donnée final peut être alphanumérique, mais il faut que les deux premiers critères soit en séquence

 

Dernière édition: 29 Mars 2008

Vote positif 0 Vote négatif

R

ri2

XLDnaute Nouveau

• 29 Mars 2008

• #7

Re : Adresse d une cellule suivant 3 criteres

Merci GIBI, je cherchais ce genre de formule ( ma base de données est conséquente ), reste plus qu'a essayer de comprendre un peu mieux !!
Bon WE à vous

 

Vote positif 0 Vote négatif