XL 2013 Adapter un code VBA / Valeurs

[rem13]

Bonjour,

Comment adapter le code ci-dessous pour que ce qui va être collé, ça soit en Valeurs, que je n'ai pas les formules.

With Worksheets("feuille1")
Worksheets("feuille2").Range("A7:G580").Copy .Cells(.Rows.Count, "A").End(xlUp)(2)

Merci d'avance,

Cordialement.

 

[frangy]

Bonjour,

Worksheets("feuille2").Range("A7:G580").Copy
Worksheets("feuille1").Cells(Rows.Count, "A").End(xlUp)(2).PasteSpecial Paste:=xlPasteValues, Operation:=xlNone, _
        SkipBlanks:=False, Transpose:=False

Cordialement.

 

[Staple1600]

Bonsoir le fil,

Une autre syntaxe possible

Sub Valeurs_Seules()
Dim r As Range
Set r = Sheets(2).Range("A7:G580")
Sheets(1).Cells(Rows.Count, 1).End(3)(2).Resize(r.Rows.Count, r.Columns.Count).Value = r.Value
End Sub

NB: Adapter le nom des feuille selon besoins.

 

[Staple1600]

Re

Et pour le fun , la même que précédemment (mais en version paramétrée)

Sub test_1()
Application.ScreenUpdating = False
'ici on recopie en colonne A (par défaut)
CopieVS Feuil1, Feuil2, "A7:G15"
End Sub
Sub test_2()
'ici on recopie en colonne C -> dernier paramètre: 3
Application.ScreenUpdating = False
CopieVS Feuil1, Feuil2, "A7:G15", 3
End Sub
Private Sub CopieVS(f_A As Worksheet, f_B As Worksheet, rngAdr As String, Optional vCol As Long = 1)
Dim r As Range
Set r = f_B.Range(rngAdr)
f_A.Cells(Rows.Count, vCol).End(3)(2).Resize(r.Rows.Count, r.Columns.Count).Value = r.Value
End Sub