XL 2016 Actualiser la ComboBox après saisie dans TextBox

job75 à dit:

Bonjour Yoyo01000, Bernard,

Voyez le fichier joint et le code de l'UserForm :

VB:

Private Sub CommandButton2_Click() 'Ajouter le poste
If TextBox1 = "" Then Exit Sub
Dim lig As Variant
With Sheets("listes")
    lig = Application.Match(TextBox1, .Columns(1), 0)
    If IsNumeric(lig) Then MsgBox "'" & TextBox1 & "' existe déjà...": Exit Sub 'évite les doublons
    lig = .Columns(1).Find("", , xlValues).Row
    .Cells(lig, 1) = TextBox1
    TextBox1 = ""
    UserForm_Initialize
    ComboBox1.DropDown 'facultatif, déroule la liste
End With
End Sub

Private Sub CommandButton1_Click() 'Supprimer le poste
If ComboBox1.ListIndex = -1 Then Exit Sub
Sheets("listes").Rows(ComboBox1.ListIndex + 2).Delete
ComboBox1 = ""
UserForm_Initialize
End Sub

Private Sub UserForm_Initialize()
Dim h&
With Sheets("listes")
    h = .Columns(1).Find("", , xlValues).Row - 2
    If h < 1 Then ComboBox1.Clear: Exit Sub
    ComboBox1.List = .Cells(2, 1).Resize(h, 2).Value '2 colonnes pour avoir au moins 2 éléments
End With
End Sub

A+

Cliquez pour agrandir...

Dranreb à dit:

Bonjour.
Mon code :

VB:

Option Explicit
Private RngPostes As Range, LCou As Long, ExInduite As Boolean
Private Sub UserForm_Initialize()
   Set RngPostes = Feuil8.[Poste_d_appel]
   Set RngPostes = RngPostes.Resize(RngPostes(1000, 1).End(xlUp).Row - RngPostes.Row + 1)
   ComboBox1.List = RngPostes.Value
   End Sub
Private Sub TextBox1_Change(): If ExInduite Then Exit Sub
   ComboBox1.Text = TextBox1.Text
   End Sub
Private Sub ComboBox1_Change(): If ExInduite Then Exit Sub
   ExInduite = True: TextBox1.Text = ComboBox1.Text: ExInduite = False
   If ComboBox1.MatchFound Then LCou = ComboBox1.ListIndex + 1 Else LCou = 0
   CommandButton1.Enabled = LCou > 0
   CommandButton2.Enabled = ComboBox1.Text <> "" And LCou = 0
   End Sub
Private Sub CommandButton2_Click()
   LCou = RngPostes.Rows.Count + 1
   Set RngPostes = RngPostes.Resize(LCou)
   RngPostes(LCou, 1).Value = ComboBox1.Text
   ThisWorkbook.Names.Add "Poste_d_appel", RngPostes
   ComboBox1.List = RngPostes.Value
   ComboBox1.Text = ""
   End Sub
Private Sub CommandButton1_Click()
   If RngPostes.Rows.Count <= 2 Then
      MsgBox "Il doit rester au moins 2 postes dans la liste", vbCritical, CommandButton2.Caption
      Exit Sub: End If
   RngPostes(LCou, 1).Delete xlShiftUp
   ComboBox1.List = RngPostes.Value
   ComboBox1.Text = ""
   End Sub

Je n'ai pas trop compris à quoi servait votre TextBox1 alors j'ai simplement veillé à ce qu'il y ait toujours la même chose que dans la ComboBox1, laquelle aurait suffit. J'ai supposé qu'il ne devait pas y avoir de doublon dans la liste.

Attention, ce code peut introduire des #REF! dans la colonne B. C'est normal, vous n'avez rien expliqué à son sujet.

Un "Complément Excel (*.xlam)" est un fichier non visible dont ce sont essentiellement des macros de son projet VBA qui sont destinées à être utilisées. S'il est autre que "VBAProject", le nom de son projet peut être coché dans les références de celui d'un classeur utilisateur.
Je propose souvent un CBxLCtlA.xlsm muni d'une procédure d'installation automatique en CBxLCtlA.xlam sur le dossier des compléments Excel et dont le projet VBA s'appelle "CLsCAs". Il contient principalement des définitions d'objets ComboBoxLiées et ControlsAssociés, bien adaptés à la mise à jour d'un tableau (de préférence régi par Excel) dont chaque ligne est identifiée par une combinaison de valeurs dans une ou plusieurs colonnes.

Cliquez pour agrandir...

Dranreb à dit:

Alors je joins le précurseur de celui dont je parlais. Il est pourvu d'une feuille d'aide détaillée.

Cliquez pour agrandir...