accélèrer un code qui masque les lignes vides

[pascal21]

Private Sub Workbook_Open()
With Worksheets("tableau de bord")
   Dim J As Long   'code pour masquer les lignes
Dim Plage As Range
Set Plage = Range("a3", Range("a200"))
For J = Plage.Cells.Count To 1 Step -1
    If Plage.Cells(J).Value = "" Then
       Plage.Cells(J).EntireRow.Hidden = True
   End If
Next
End With

bonsoir le forum
ma question est simple et contenue dans le titre
est-il possible d'accélèrer ce code qui prend environ 30 sec
ou existe-il une autre solution pour masquer les lignes dont la colonne A est vide
merci

 

[Guest]

Re : accélèrer un code qui masque les lignes vides

Bonsoir,

Cela devrait te faire gagner du temps.

Private Sub Workbook_Open()
    Dim oldCalculation As XlCalculation
    oldCalculation = Application.Calculation
    On Error GoTo FinMasquage
    With Worksheets("tableau de bord")
        Dim J As Long   'code pour masquer les lignes
        Dim Plage As Range
        Dim plgRes As Range   'Plage d'union de toutes les lignes à masquer
        Set Plage = Range("a3", Range("a200"))
        Application.Calculation = xlCalculationManual
        Application.EnableEvents = False
        Application.ScreenUpdating = False
        For J = Plage.Cells.Count To 1 Step -1
            If Plage.Cells(J).Value = "" Then
                If plgRes Is Nothing Then
                    Set plgRes = Plage.Cells(J)
                Else
                    Set plgRes = Union(plgRes, Plage.Cells(J))
                End If
            End If
        Next
        'Masquage de toutes les lignes trouvée
        If Not plgRes Is Nothing Then plgRes.EntireRow.Hidden = True
    End With
FinMasquage:
        Application.Calculation = oldCalculation
        Application.EnableEvents = False
        Application.ScreenUpdating = False
End Sub

A+

 

[pascal21]

Re : accélèrer un code qui masque les lignes vides

bonsoir merci je vais essayer entre-temps j'avais trouvé un autre code un poil plus rapide que le 1er
je te dis ce qui en est

 

[pascal21]

Re : accélèrer un code qui masque les lignes vides

re
c'est parfait, le code à une réponse quasi instantannée
merci bonne soirée