À l'aide: copie de cell

[hestiahv]

Bonjour à tous.

J’ai une urgence incroyable qui dépasse mes capacités. J’espère que quelqu’un pourra m’aider

Le fichier A&E&C contient deux feuilles :
Load List
Et
Feuille 3

Le fichier Provenance contient une feuille :
Feuille1

J’ai déjà un code, gracieuseté des membres de votre forum,
Ce dernier à pour but que lorsqu’un numéro est entré entre (A15 :A500) dans Load List
Et que ce dernier ce retrouve dans Feuille 3, bien l’information sélectionné sera copié.

Le tout fonctionne à merveille.

Malheureusement, lorsque je fait un copier collé provenant d’un autre fichier seul la description du premier numéro apparait pour tout les numéro…..

Pour faire un test et comprendre le fonctionnement, copier un numéro de la feuille 3 dans la feuille Load list ( Cell A15 : A500)

Fait un à un : Copié A5 vers Load list, puis Copié A6 ainsi de suite fonctionne mais lors que fait en plage…..

Maintenant procédez de la même méthode mais en copiant la plage (A5 :A9) de Provenance vers Load list. L’information ne s’étend pas

Merci beaucoup
D'avance

 

[Gorfael]

Re : À l'aide: copie de cell

Salut hestiahv et le forum
Et tu veux un café en plus ? Pas envie de faire les manips, mais si tu mets ta macro WorkSheet_Change, je veux bien tenter de la corriger
A+

 

[lavaltt]

Re : À l'aide: copie de cell

Bonsoir le forum, le fil,

Je ne suis pas sur d'avoir bien compris votre message.

Pour la macro je croyait quelle était attaché à mon fichier:
Private Sub Worksheet_Change(ByVal Target As Range)
Dim Feuille As Worksheet, Résultat As Range
Set Target = Intersect(Target, Range("a15:a600"))
If Target Is Nothing Then Exit Sub
For Each Feuille In ThisWorkbook.Worksheets
If Feuille.Name <> "Load List" Then
Set Résultat = Feuille.Columns(1).Find(What:=Target.Value, LookAt:=xlWhole)
If Not Résultat Is Nothing Then
Target.Offset(0, 1) = Résultat.Offset(0, 1)
Target.Offset(0, 14) = Résultat.Offset(0, 2)
Target.Offset(0, 13) = Résultat.Offset(0, 4)
Target.Offset(0, 16) = Résultat.Offset(0, 3)
Exit Sub
End If
End If
Next
End Sub

Pour ce qui est du café, je tolère mal les activant mais merci pour l'offre

 

[hestiahv]

Re : À l'aide: copie de cell

Merci Laval,

Je n'avais pas remarqué que tu étais en ligne. Faut règler ce probleme.
Si non on ne peu pas envoyer le fichier....

Appelle moi dès que tu vois que tout est réglé. Je ferai de même

 

[mtlhv]

Re : À l'aide: copie de cell

Bonjour le Fil, les participants,

Hestia,

As-tu essayé de modifier ton en tête de macro?
Je crois déja avoir vu ce genre de problème.

Je fais des recherches et je te reviens.

Mtl

 

[Gorfael]

Re : À l'aide: copie de cell

Salut lavaltt et le forum
Quelques remarques :
- Utilise les balises de code (#), ça rend sa lecture plus facile
- Ne jamais utiliser des noms de variables qu'Excel peut lui-même utiliser
- On ne force pas une variable système (comme target) : comme son nom l'indique, Excel la met à jour.
- Une variable target peut ne correspondre qu'à une seule et unique cellule (comme dans Worksheet_BeforeDoubleClick ou Worksheet_BeforeRightClick), mais elle peut aussi correspondre à plusieurs cellules.
Un essais :

Private Sub Worksheet_Change(ByVal Target As Range)
Dim Feuille As Worksheet, Résultat As Range, Cel As Range, Plage As Range
Set Plage = Intersect(Target, Range("a15:a600"))
If Plage Is Nothing Then Exit Sub
For Each Cel In Plage
    For Each Feuille In ThisWorkbook.Worksheets
        If Feuille.Name <> "Load List" Then
            Set Résultat = Feuille.Columns(1).Find(What:=Cel, LookAt:=xlWhole)
            If Not Résultat Is Nothing Then
                Cel.Offset(0, 1) = Résultat.Offset(0, 1)
                Cel.Offset(0, 14) = Résultat.Offset(0, 2)
                Cel.Offset(0, 13) = Résultat.Offset(0, 4)
                Cel.Offset(0, 16) = Résultat.Offset(0, 3)
                Exit For
            End If
        End If
    Next Feuille
Next Cel
End Sub

Comme target peut contenir plusieurs cellules, dont certaines n'appartenant pas à la zone qui nous interesse, il fait les extraire => c'est le but de la variable Plage. Ensuite on fait une boucle qui va parcourir chacune des cellules de Plage, au travers du code fournis. Mais si on trouve le résultat souhaité, avant d'avoir parcouru toutes les cellules de Plage, on ne peut pas sortir de la macro, seulement de la boucle concernée => c'est le but du remplacement de "Exit Sub" par "Exit For", qui fait sortir de la boucle Feuille, et donc on passe à la Cel suivante.
A+

 

[hestiahv]

Re : À l'aide: copie de cell

Bonjour à tous,

Lavaltt, Gorfael

Gros Merci !!!!

Le tout fonctionne à merveille.....

Hestis....

Impressionné

Merci