3x GRANDE.VALEUR d'une plage ayant des valeurs à rechercher

[Fogel]

Bonjour,

Petite question complexe.

J'ai le tableau suivant

A1 50
A2 35
A3 15
B1 30
B2 25
B3 10
C1 25
C2 10
C3 5

Par la suite, j'ai une ligne comportant :

A1 A2 B2 A1 C2


La fonction que je recherche doit trouver la valeur de chacun des champs de la ligne ci-haut, puis additionner les trois plus grande valeurs de ceux-ci.

J'ai trouvé la fonction suivante si les A1 étaient déjà converties en chiffre mais je n'arrive pas à faire la recherche {=SOMME(GRANDE.VALEUR(B16:E16;{1;2;3}))}

Pouvez-vous m'aider?

Merci à l'avance!

Mario Lavigne

 

[Tibo]

Re : 3x GRANDE.VALEUR d'une plage ayant des valeurs à rechercher

Bonsoir,

Peux-tu nous joindre un extrait de ton fichier accompagné de quelques explications.

Là, je n'ai pas tout compris

A te (re)lire

@+

 

[Fogel]

Re : 3x GRANDE.VALEUR d'une plage ayant des valeurs à rechercher

Voilà.

La matrice est A5:B13.

Dans la colonne "Total", je veux la somme des trois plus grandes valeurs (GRANDE.VALEUR) de chacune des lignes.

Donc, en ordre, convertir B16 en 50, convertir, B17 en 35, etc. Et additionner les trois plus grandes valeurs.


Est-ce plus clair?

Merci!

 

[Tibo]

Re : 3x GRANDE.VALEUR d'une plage ayant des valeurs à rechercher

re,

Essaye avec cette formule matricielle en G16 :

=SOMME(GRANDE.VALEUR(SI($B16:$F16=$A$5:$A$13;$B$5:$B$13);{1;2;3}))

Matricielle à valider par CTRL + MAJ + ENTREE

à recopier vers le bas

Je te laisse tester

@+

 

[Fogel]

Re : 3x GRANDE.VALEUR d'une plage ayant des valeurs à rechercher

Bonjour Tibo,

Ca fonctionne à merveille.

J'ai cependant réalisé un petit problème. Il se peut que, sur certaines lignes, il n'y ait qu'un ou deux item. Donc, la fonction plante parce que Grande.Valeur ne trouve pas trois items.

Y a-t'il quelque chose qu'on puisse faire?

Merci!

 

[bcharef]

Re : 3x GRANDE.VALEUR d'une plage ayant des valeurs à rechercher

Bonsoir Fogel,
Salut Tibo;
Bonsoir à toutes et à tous.

Si, j'ai bien compris.

Un essai en G16 avec une formule matricielle; puis, tirez vers le bas

=SI(NBVAL($B16:$F16)<3;SOMME(SI($B16:$F16=$A$5:$A$13;$B$5:$B$13));SOMME(GRANDE.VALEUR(SI($B16:$F16=$A$5:$A$13;$B$5:$B$13);{1;2;3})))

A valider par CTRL + MAJ + ENTREE


A vous lire et bon courage.

Cordialement.

BCharef

 

[Fogel]

Re : 3x GRANDE.VALEUR d'une plage ayant des valeurs à rechercher

Bonjour BCharef,

Ca fonctionne très bien!

Vous êtes trop fort! 🙂

Merci!

 

[Chris401]

Re : 3x GRANDE.VALEUR d'une plage ayant des valeurs à rechercher

Bonsoir

Également, en modifiant légèrement la formule de Tibo :

=SOMME(GRANDE.VALEUR(SI($B16:$F16<>$A$5:$A$13;0;$B$5:$B$13);{1;2;3}))

Matricielle

Cordialement