Sommeprod et pb de plages nommées

[Franziskaner]

Bonjour à tous les participants !

Je cerne le problème de plus en plus près mais voilà, je bute sur un problème ayant apparemment trait à certaines de mes plages nommées.

Mes sommeprod faisant recours aux plages nommées Cat, Personnel et Heures fonctionnent, celles impliquant Bat et Etage produisent un N/A...

Quel puits de science pour me secourir ???

Merci d'avance,

Franziskaner

 

[Dranreb]

Re : Sommeprod et pb de plages nommées

Bonjour.
Il n'y a pas deux noms où on compte la même chose. Comment voulez vous que vos plages aient le même nombre de lignes ?
Cordialement.

 

[JCGL]

Re : Sommeprod et pb de plages nommées

Bonjour à tous,

Tu as des cellules vides dans la liste "Bat".
Pour SOMMEPROD() les plages doivent être de longueur strictement identiques.

A + à tous

Édition : Salut Bernard, salut Kjin

 

[kjin]

Re : Sommeprod et pb de plages nommées

Bonjour,
Sommeprod n'accepte que des plages contenant le même nb de lignes, donc dans la définition des noms il faut indiquer le nb de valeurs d'une colonne de référence, A par exemple
Pour Cat par exemple

=DECALER(Feuil1!$B$5;;;NBVAL($A:$A)-3))

ou

=DECALER(Feuil1!$B$5;;;NBVAL(Bat))

idem pour les autres plages
A+
kjin

 

[Monique]

Re : Sommeprod et pb de plages nommées

Bonjour à tous,

Pour faire la somme des heures (ou une autre somme en général), il vaut mieux :
=SOMMEPROD((Cat=AE13)*(Bat=AF13);Heures)

; à la place de *Heures au cas où il y aurait, dans la plage à sommer, du texte ou une formule renvoyant ““

S’il n’y a qu’ un critère :
=SOMMEPROD((Cat=B96)*1;Heures)

=SOMMEPROD(--(Cat=B96)*1;Heures)

 

[Misange]

Re : Sommeprod et pb de plages nommées

Bonjour
Comme signalé par tous (que je salue), il faut que toutes tes colonnes aient la même taille.
Tu peux très bien faire des somme prod avec des cellules vides dans ton tableau. Il suffit pour ça de définir tes noms en faisant référence au nombre d'items contenus dans la plus longue des colonnes, ici la colonne A
Bat =DECALER(Feuil1!$A$5;;;NBVAL(Feuil1!$A:$A)-3)
Cat =DECALER(Feuil1!$B$5;;;NBVAL(Feuil1!$A:$A)-3)
Heures =DECALER(Feuil1!$G$5;;;NBVAL(Feuil1!$A:$A)-3)
Personnel =DECALER(Feuil1!$F$5;;;NBVAL(Feuil1!$A:$A)-3)

vu comme ça tes formules fonctionnent toutes seules.

 

[Franziskaner]

Re : Sommeprod et pb de plages nommées

...et j'ai encore compris (appris) quelque chose !!!

Merci beaucoup à vous tous zélés membres de ce précieux forum !!

 

[hoerwind]

Re : Sommeprod et pb de plages nommées

Bonjour, salut les autres,

Sur base des formules de Misange, en nommant la partie répétitive des formules :
nbre : =NBVAL(Feuil1!$A:$A)-3
les formules sont plus courtes, avec moins de risques d'erreur :
Bat : =DECALER(Feuil1!$A$5;;;nbre)
Cat : =DECALER(Feuil1!$B$5;;;nbre)
Heures : =DECALER(Feuil1!$G$5;;;nbre)
Personnel : =DECALER(Feuil1!$F$5;;;nbre)

 

[Misange]

Re : Sommeprod et pb de plages nommées

Bonjour, salut les autres,

Sur base des formules de Misange, en nommant la partie répétitive des formules :
nbre : =NBVAL(Feuil1!$A:$A)-3
les formules sont plus courtes, avec moins de risques d'erreur :
Bat : =DECALER(Feuil1!$A$5;;;nbre)
Cat : =DECALER(Feuil1!$B$5;;;nbre)
Heures : =DECALER(Feuil1!$G$5;;;nbre)
Personnel : =DECALER(Feuil1!$F$5;;;nbre)

futé !

argh "futé !" ça fait moins de 10 caractères , on n'a pas le droit d'être laconique ici !

 

[hoerwind]

Re : Sommeprod et pb de plages nommées

Salut Misange,

J'apprécie que tu apprécies !

Et que penses-tu de nommer aussi la cellule Feuil1!$A$5, par exemple dep (pour départ) ?

Bat : =DECALER(dep;;;nbre)
Cat : =DECALER(dep;;1;nbre)
Heures : =DECALER(dep;;6;nbre)
Personnel : =DECALER(dep;;5;nbre)

Uniquement pour le fun !

 

[Misange]

Re : Sommeprod et pb de plages nommées

Ah oui c'est pratique aussi.
En fait maintenant quand j'utilise décaler je ne pars plus jamais d'une cellule qui risque d'être délétée. En pratique je pars toujours de la cellule contenant l'entête de la colonne et je décale de 1 vers le bas. Avec ta soluce ça ferait
=decaler (dep;1;6;nbre) par exemple

 

[hoerwind]

Re : Sommeprod et pb de plages nommées

Re,

Conseil judicieux, enregistré, on est jamais assez prudent !
Dommage qu'on ne puisse décaler à partir de la ligne 0 et de la colonne @ (lol).
Je l'applique dès mon prochain DECALER.