Mot de passe changeant

[WDAndCo]

Bonjour le Forum

Comment mettre un mot de passe journalier ?

Du genre « 20052014 » pour aujourd’hui et « 19052014 » pour hier.
Ou « 140 » pour aujourd’hui et « 139 » pour hier; qui sont les X jours depuis le premier janvier.

Private Sub Workbook_Open()
“??????????????????????“ Then ActiveWorkbook.Close False
End Sub

D’avance merci.
Dominique

 

[job75]

Re : Mot de passe changeant

Bonjour WDAndCo,

Private Sub Workbook_Open()
Dim i&
For i = Date To 1 Step -1 'recherche du mot de passe précédent
  On Error Resume Next
  Me.Unprotect Format(i, "ddmmyyyy")
  If Err = 0 Then Exit For
Next
Me.Protect Format(Date, "ddmmyyyy") 'nouveau mot de passe
Me.Save 'enregistrement
Me.Protect 'demande du mot de passe
If Err Then If Workbooks.Count = 1 Then Application.Quit Else Me.Close
Me.Protect Format(Date, "ddmmyyyy") 'remet la protection
Me.Save
End Sub

Bah si l'on ne connaît pas le mot de passe il suffit de ne pas activer les macros

A+

 

[WDAndCo]

Re : Mot de passe changeant

Bonjour job75 et re le Forum

job75 merci, mais, je me suis de nouveau mal exprimé !
Le « Mot de passe » ne protégé pas le classeur, il doit juste permettre ou pas l’ouverture du classeur.

Du genre :

Demande d’ouverture
-> Si la saisie = date du jour actuel
-> Ouverture Else pas d’ouverture.

Ou

Ouverture
-> Si la saisie <> date du jour actuel
-> Fermeture

J’espère avoir été plus clair

Dominique

 

[job75]

Re : Mot de passe changeant

Re,

Avec le numéro du jour :

Private Sub Workbook_Open()
Dim jour%, i%
jour = Date - CDate("1/1") + 1 'numéro du jour
For i = jour To 1 Step -1 'recherche du mot de passe précédent
  On Error Resume Next
  Me.Unprotect CStr(i)
  If Err = 0 Then GoTo 1
Next
For i = 366 To 1 Step -1 'si année précédente
  On Error Resume Next
  Me.Unprotect CStr(i)
  If Err = 0 Then Exit For
Next
1 Me.Protect CStr(jour) 'nouveau mot de passe
Me.Save 'enregistrement
Me.Protect 'demande du mot de passe
If Err Then If Workbooks.Count = 1 Then Application.Quit Else Me.Close
Me.Protect CStr(jour) 'remet la protection
Me.Save
End Sub

Aujourd'hui 21/05/2014 le mot de passe est donc 141.

A+

 

[job75]

Re : Mot de passe changeant

Re,

Je protégeais le classeur parce que j'aime bien la boîte de dialogue

Avec une InputBox c'est nettement moins joli :

'l'une ou l'autre de ces macros :

Private Sub Workbook_Open()
Dim mdp$
mdp = Format(Date, "ddmmyyyy") 'date du jour
If InputBox("Mot de passe :") <> mdp Then _
  If Workbooks.Count = 1 Then Application.Quit Else Me.Close
End Sub

Private Sub Workbook_Open()
Dim mdp$
mdp = Date - CDate("1/1") + 1 'numéro du jour
If InputBox("Mot de passe :") <> mdp Then _
  If Workbooks.Count = 1 Then Application.Quit Else Me.Close
End Sub

Sinon fabriquez-vous un bel UserForm...

A+

 

[job75]

Re : Mot de passe changeant

Re,

S'il y a des formules volatiles ou des liaisons utiliser Me.Saved = True :

'l'une ou l'autre de ces macros :

Private Sub Workbook_Open()
Dim mdp$
mdp = Format(Date, "ddmmyyyy") 'date du jour
Me.Saved = True
If InputBox("Mot de passe :") <> mdp Then _
  If Workbooks.Count = 1 Then Application.Quit Else Me.Close
End Sub

Private Sub Workbook_Open()
Dim mdp$
mdp = Date - CDate("1/1") + 1 'numéro du jour
Me.Saved = True
If InputBox("Mot de passe :") <> mdp Then _
  If Workbooks.Count = 1 Then Application.Quit Else Me.Close
End Sub

A+

 

[WDAndCo]

Re : Mot de passe changeant

Merci beaucoup job75 pile poils
Hé ! Oui nous sommes bien le 141eme jour de l'année, je n’avais pas tourné la page de l'éphéméride.