VBA Tri de certains onglets

[FAUB]

Bonjour le forum,

J'ai un fichier (ci-joint) avec plusieurs onglets que je veux trier, et d'autres qui ne doivent pas être triés.

J'ai essayé cette macro, mais elle ne fonctionne pas:


Sub trier()

For Each f In ActiveWorkbook.Sheets
s = f.Name
If s <> "1" And s <> "2" And s <> "3" Then
Range("A5", Selection.End(xlDown)).Select
Selection.Sort Key1:=Range("A5"), Order1:=xlAscending, nHeader:=xlGuess, _
OrderCustom:=1, MatchCase:=False, Orientation:=xlTopToBottom, _
DataOption1:=xlSortNormal
End If
Next

End Sub


Pourriez-vous me dire ce que je dois modifier pour que cela fonctionne ?

Merci d'avance!

FAUB

 

[mromain]

Re : VBA Tri de certains onglets

re,

à tester:

Sub trier()

For Each f In ActiveWorkbook.Sheets
    s = f.Name
    If s <> "1" And s <> "2" And s <> "3" Then
    f.Range(f.Range("A5"), f.Range("A5").End(xlDown)).Sort Key1:=f.Range("A5"), _
            Order1:=xlAscending, Header:=xlGuess, OrderCustom:=1, MatchCase:=False, _
            Orientation:=xlTopToBottom, DataOption1:=xlSortNormal
    End If
Next
       
End Sub

a+

 

[FAUB]

Re : VBA Tri de certains onglets

Ca marche nickel.
Merci beaucoup !

Bonne journée !

 

[PMO2]

Re : VBA Tri de certains onglets

Bonjour,

Essayez avec votre code modifié ci-dessous

Sub trier_pmo()
Dim f As Worksheet
Dim s As String
Dim R As Range
For Each f In ActiveWorkbook.Sheets
  s = f.Name
  If s <> "1" And s <> "2" And s <> "3" Then
    f.Activate
    Set R = f.Range("A5:A" & f.[a65536].End(xlUp).Row & "")
    R.Sort Key1:=f.[a5], Order1:=xlAscending, Header:=xlGuess, _
      OrderCustom:=1, MatchCase:=False, Orientation:=xlTopToBottom, _
      DataOption1:=xlSortNormal
  End If
Next f
End Sub

Cordialement.

PMO
Patrick Morange