Microsoft 365 VBA : changer l'ordre des feuilles dans l'impression en pdf

VBA_dev_Anne_Marie

VBA_dev_Anne_Marie

XLDnaute Occasionnel
Bonjour,

Je souhaite changer l'ordre des feuilles et afficher la feuille "1 - Bordereau" en première position dans mon classeur Excel. Quand je fais cela, la Page_1 est imprimé en deuxième position, alors que dans mon code c'est : "Page_1", "1 - Bordereau":

Est-ce que vous connaissez une astuce pour garder l'ordre : "Page_1", "1 - Bordereau", "Page_5", "Page_6", "Page_7", "Page_8", "Page_9", "Page_10", "Page_11", "Page_12" lors de l'impression ?

Merci pour votre aide !

Mon code est :
VB: 
Sub Fichier_pdf()
    Dim sRep As String
    Dim sFilename As String
    Dim LHeure As String
    Dim LaDate As String
    Dim Nom As String

   LHeure = Format(Time, "HMS")
   LaDate = Format(Date, "dd" & "." & "mm" & "." & "yyyy")
   Nom = "Création du bordereau le"
   With ActiveSheet.PageSetup
    .LeftFooter = ""
   .CenterFooter = ""
   .RightFooter = ""
    End With

    Sheets(Array("Page_1", "1 - Bordereau", "Page_5", "Page_6", "Page_7", "Page_8", "Page_9", "Page_10", "Page_11", "Page_12")).Select
    sRep = ThisWorkbook.Path
    sFilename = Nom & " " & LaDate & " " & LHeure & ".pdf"
    

    ActiveSheet.ExportAsFixedFormat _
            Type:=xlTypePDF, _
            Filename:=sRep & "\" & sFilename, _
            Quality:=xlQualityStandard, _
            IncludeDocProperties:=True, _
            IgnorePrintAreas:=False, _
            OpenAfterPublish:=True
    Sheets("1 - Bordereau").Select
' Message de confirmation
MsgBox "Création du fichier PDF a été effectuée", Title:="Mon document"

End Sub

Merci pour votre aide !
 
Trier par date Trier par votes
C

Compte Supprimé 979

Guest
Re,

Il faut faire une petite routine de déplacement des feuilles 😉 que voici
VB: 
Sub Fichier_pdf()
  Dim sRep As String
  Dim sFilename As String
  Dim LHeure As String
  Dim LaDate As String
  Dim Nom As String
  Dim Ind As Integer, NomAvant(10) As String, NomTrié() As String

  LHeure = Format(Time, "HMS")
  LaDate = Format(Date, "dd" & "." & "mm" & "." & "yyyy")
  Nom = "Création du bordereau le"
  With ActiveSheet.PageSetup
    .LeftFooter = ""
    .CenterFooter = ""
    .RightFooter = ""
  End With
  ' Tableau des feuilles du classeur
  For Ind = 1 To Sheets.Count
    NomAvant(Ind) = Sheets(Ind).Name
  Next Ind
  ' Ordre souhaité des feuilles pour l'impression
  NomTrié = Split("Page_1,1 - Bordereau,Page_5,Page_6,Page_7,Page_8,Page_9,Page_10,Page_11,Page_12", ",")
  ' Déplacer les feuilles dans le bon ordre
  On Error Resume Next
  For Ind = 0 To Sheets.Count - 1
    Sheets(NomTrié(Ind)).Move Before:=Sheets(Ind + 1)
  Next Ind
  On Error GoTo 0
  ' Sélectionner les feuilles triées
  Sheets(NomTrié).Select
  '
  sRep = ThisWorkbook.Path
  sFilename = Nom & " " & LaDate & " " & LHeure & ".pdf"
  ' Imprimer les feuilles sélectionnées
  ActiveSheet.ExportAsFixedFormat _
    Type:=xlTypePDF, _
    Filename:=sRep & "\" & sFilename, _
    Quality:=xlQualityStandard, _
    IncludeDocProperties:=True, _
    IgnorePrintAreas:=False, _
    OpenAfterPublish:=True
  ' Remettre les onglets dans l'ordre initial (si nécessaire)
  On Error Resume Next
  For Ind = 1 To Sheets.Count
    Sheets(NomAvant(Ind)).Move Before:=Sheets(Ind)
  Next Ind
  On Error GoTo 0
 
  Sheets("1 - Bordereau").Select
  ' Message de confirmation
  MsgBox "Création du fichier PDF a été effectuée", Title:="Mon document"
End Sub

@+
 

Pièces jointes

  • MarieParis_Impression Onglets Ordonnés.xlsm
    39.6 KB · Affichages: 7
Vote positif 0 Vote négatif
VBA_dev_Anne_Marie

VBA_dev_Anne_Marie

XLDnaute Occasionnel
BrunoM45 à dit:
Re,

Il faut faire une petite routine de déplacement des feuilles 😉 que voici
VB: 
Sub Fichier_pdf()
  Dim sRep As String
  Dim sFilename As String
  Dim LHeure As String
  Dim LaDate As String
  Dim Nom As String
  Dim Ind As Integer, NomAvant(10) As String, NomTrié() As String

  LHeure = Format(Time, "HMS")
  LaDate = Format(Date, "dd" & "." & "mm" & "." & "yyyy")
  Nom = "Création du bordereau le"
  With ActiveSheet.PageSetup
    .LeftFooter = ""
    .CenterFooter = ""
    .RightFooter = ""
  End With
  ' Tableau des feuilles du classeur
  For Ind = 1 To Sheets.Count
    NomAvant(Ind) = Sheets(Ind).Name
  Next Ind
  ' Ordre souhaité des feuilles pour l'impression
  NomTrié = Split("Page_1,1 - Bordereau,Page_5,Page_6,Page_7,Page_8,Page_9,Page_10,Page_11,Page_12", ",")
  ' Déplacer les feuilles dans le bon ordre
  On Error Resume Next
  For Ind = 0 To Sheets.Count - 1
    Sheets(NomTrié(Ind)).Move Before:=Sheets(Ind + 1)
  Next Ind
  On Error GoTo 0
  ' Sélectionner les feuilles triées
  Sheets(NomTrié).Select
  '
  sRep = ThisWorkbook.Path
  sFilename = Nom & " " & LaDate & " " & LHeure & ".pdf"
  ' Imprimer les feuilles sélectionnées
  ActiveSheet.ExportAsFixedFormat _
    Type:=xlTypePDF, _
    Filename:=sRep & "\" & sFilename, _
    Quality:=xlQualityStandard, _
    IncludeDocProperties:=True, _
    IgnorePrintAreas:=False, _
    OpenAfterPublish:=True
  ' Remettre les onglets dans l'ordre initial (si nécessaire)
  On Error Resume Next
  For Ind = 1 To Sheets.Count
    Sheets(NomAvant(Ind)).Move Before:=Sheets(Ind)
  Next Ind
  On Error GoTo 0
 
  Sheets("1 - Bordereau").Select
  ' Message de confirmation
  MsgBox "Création du fichier PDF a été effectuée", Title:="Mon document"
End Sub

@+
Cliquez pour agrandir...
Merci, j'ai changé mon code de cette façon ,ça marche aussi :
 
Vote positif 0 Vote négatif
VBA_dev_Anne_Marie

VBA_dev_Anne_Marie

XLDnaute Occasionnel
VB: 
Sub Fichier_pdf()
    Dim sRep As String
    Dim sFilename As String
    Dim LHeure As String
    Dim LaDate As String
    Dim Nom As String

   LHeure = Format(Time, "HMS")
   LaDate = Format(Date, "dd" & "." & "mm" & "." & "yyyy")
   Nom = "Création du bordereau le"
   With ActiveSheet.PageSetup
    .LeftFooter = ""
   .CenterFooter = ""
   .RightFooter = ""
    End With
   
    Sheets("1 - Bordereau").Select
    Sheets("1 - Bordereau").Move Before:=Sheets(3)
   
    Sheets(Array("Page_1", "1 - Bordereau", "Page_5", "Page_6", "Page_7", "Page_8", "Page_9", "Page_10", "Page_11", "Page_12")).Select
    sRep = ThisWorkbook.Path
    sFilename = Nom & " " & LaDate & " " & LHeure & ".pdf"
   
 
    ActiveSheet.ExportAsFixedFormat _
            Type:=xlTypePDF, _
            Filename:=sRep & "\" & sFilename, _
            Quality:=xlQualityStandard, _
            IncludeDocProperties:=True, _
            IgnorePrintAreas:=False, _
            OpenAfterPublish:=True
           
    Sheets("1 - Bordereau").Select
    Sheets("1 - Bordereau").Move Before:=Sheets(1)

' Message de confirmation
MsgBox "Création du fichier PDF a été effectuée", Title:="Mon document"

End Sub
kiki29 à dit:
Salut, tjs à titre de curiosité : PDFCreator Modifier l'ordre dans la queue d'impression puis fusionner le tout en un seul PDF

Il faudrait que tu t'intéresses au CodeName : cela te permet de déplacer les onglets, de modidier ces noms d'onglet sans avoir à retoucher au code VBA.
Cliquez pour agrandir...
Merci ! Je regarde.
 
Vote positif 0 Vote négatif
patricktoulon

patricktoulon

XLDnaute Barbatruc
bonsoir
il y a un moyen simple sans modifier le fichier initial
c'est simplement de copier les feuilles dans un new classeur dans l'ordre que l'on souhaite
et de sauver ce nouveau classeur en pdf puis le fermer sans sauver
et basta ;)
exemple
pour info j'utilise les codename des feuilles
VB: 
Sub sauvelesfeuillesenpdf()
    Dim mes_Feuilles, I&, Chemin$
    Application.ScreenUpdating = False
    mes_Feuilles = Array(Feuil1, Feuil6, Feuil10, Feuil4, Feuil2)
    mes_Feuilles(0).Copy    ' a pour effet de créer un new classeur et de copier la feuille

    Set newclasseur = ActiveWorkbook    ' on variabilise le nouveau classeur
    'on boucle a partir de la 2d feuille puisque la premiere est la feuille(0) dans l'array
    For I = 1 To UBound(mes_Feuilles)
        'on les copie dans l'ordre de l'array "mes_feuilles"et toujour en dernier
        mes_Feuilles(I).Copy After:=newclasseur.Sheets(newclasseur.Sheets.Count)
    Next

    'voila tu a un nouveau classeur avec les feuilles concernées dans l'ordre que tu a voulu
    'maintenant on determine le chemin  du nouveau fichier
    Chemin = Environ("userprofile") & "\DeskTop\totolafritte.pdf"
    'et on le sauve avec ce chemin en pdf
    ActiveWorkbook.ExportAsFixedFormat Type:=xlTypePDF, Filename:= _
                                       Chemin, Quality:=xlQualityStandard, _
                                       IncludeDocProperties:=True, IgnorePrintAreas:=False, OpenAfterPublish:= _
                                       False
    'on en a plus besoinsde ce new classeur alors on le ferme !!!! sans le sauver !!!!!
    Application.DisplayAlerts = False
    ActiveWorkbook.Close
End Sub
terminé;)
 
Vote positif 0 Vote négatif

Discussions similaires

G
  • Question
XL 2016 Extraire des données d'un pdf et les copier dans excel
2
Réponses
17
Affichages
820
gali2
G
VBA_dev_Anne_Marie
  • Question
Microsoft 365 L'enregistrement en .pdf avec la fenêtre Enregistrer Sous
Réponses
4
Affichages
2 K
VBA_dev_Anne_Marie
VBA_dev_Anne_Marie
P
  • Question
XL 2019 Changer nom d'export en VBA
Réponses
3
Affichages
483
job75
job75
VBA_dev_Anne_Marie
  • Question
Microsoft 365 Comment désélectionner les cellules Excel
Réponses
3
Affichages
839
VBA_dev_Anne_Marie
VBA_dev_Anne_Marie
Nico2978
  • Résolu(e)
XL 2019 Aide pour un module d'archivage de feuille en pdf dans répertoire
Réponses
5
Affichages
536
Nico2978
Nico2978
F
  • Question
XL 2016 copier des fichiers dans des sous dossiers a partir de case a cocher sous excel
2
Réponses
17
Affichages
1 K
Felipe54
F
J
  • Question
XL 2019 Donner le nom de deux cellules a un onglet avec VBA
Réponses
1
Affichages
788
Jacky67
Jacky67
VBA_dev_Anne_Marie
  • Question
Microsoft 365 Imprimer en PDF sans note de bas page
Réponses
4
Affichages
1 K
VBA_dev_Anne_Marie
VBA_dev_Anne_Marie
S
  • Question
XL 2019 Enregistrer plusieurs feuilles excel en un fichier PDF dans un dossier portant le nom d'une cellule
Réponses
4
Affichages
2 K
Phil69970
Phil69970
E
  • Résolu(e)
Microsoft 365 Problème d'organisation des colonnes dans une ListBox en VBA Excel
Réponses
2
Affichages
797
eCHO
E

Membres actuellement en ligne

3 membres et 41 invités.

Partager cette page

Tutos vidéos

Power Query : Ajouter des requêtes (Excel et Power BI)
Créez votre première fonction LAMBDA dans Excel en 3 étapes!
LAMBDA, l’arme secrète de Microsoft pour Excel !
Office Insider - Découvrez les nouveautés Excel avant tout le monde

Statistiques des forums

Discussions
315 098
Messages
2 116 189
Membres
112 679
dernier inscrit
Yupanki