valeur brute en heure et minute en conservant les chiffres

[5859lannes]

Bonsoir à tous,

Je butte depuis quelques jours sur un problème.
Voilà, j'obtiens lors d'extraction des données brutes numériques au format texte (bloc note)
J'ouvre le bloc note sous excel, et j'obtiens les données suivantes par exemple : 730 format standard pour 07:30 que j'aimerai au format heures et minutes.
Comment faire ?????
De plus, l'extraction me donne deux bornes une basse : exemple 740 et une haute exemple 830, qu'il faut que soustrait pour obtenir le delai entre les deux bornes : ici 50 minutes et non 90.
Si quelqu'un peu m'aider je serai heureux.
Merci d'avance.

Didier.

Pièce jointe : exemple de tableau extrait.

 

[Fred0o]

Re : valeur brute en heure et minute en conservant les chiffres

Bonsoir 5859lannes,

Formule à mettre en D2 et à tirer vers le bas :

=TEMPS(GAUCHE(C2;NBCAR(C2)-2);DROITE(C2;2);0)-TEMPS(GAUCHE(B2;NBCAR(B2)-2);DROITE(B2;2);0)

A+

 

[Staple1600]

Re : valeur brute en heure et minute en conservant les chiffres

Bonsoir à tous

Essayes cette formule en D2
(Format: hh:mm) puis recopie vers le bas

=SI(NBCAR(B2)=3;TEMPS(GAUCHE(B2);DROITE(B2;2);0);TEMPS(GAUCHE(B2;2);DROITE(B2;2);0))

Adaptes la formule pour la colonne C (et mettre cette formule adaptée en colonne E)

=SI(NBCAR(C2)=3;TEMPS(GAUCHE(C2);DROITE(C2;2);0);TEMPS(GAUCHE(C2;2);DROITE(C2;2);0))

EDITION: Houps désolé, FredOo bing collision (Bonsoir)

 

[Modeste geedee]

Re : valeur brute en heure et minute en conservant les chiffres

Bonsour®
en D2 :
=TEXTE(C2;"00"":""00")-TEXTE(B2;"00"":""00")
format de cellule : hh:mm

😎
dans le cas ou on voudrait chaque valeur séparée
=1*TEXTE(B2;"00\:00")
=1*TEXTE(C2;"00\:00")
format de cellule : hh:mm
"By Design" il faut un opérateur mathématique pour numériser le format texte

🙄
dans le 1er exemple c'est l'opérateur "-" qui rempli cette fonction...

 

[gosselien]

Re : valeur brute en heure et minute en conservant les chiffres

génial Modeste 🙂