Userform & SOMMEPROD => pb de date

[lo]

Userform & SOMMEPROD => pb de date

Bonjour ! ! !


2 petites questions avant le we, l’une relevant un fait étrange et surprenant (tout du moins pour moi ) et l’autre une question somme toute très bête…

Surprenant donc… Au 1er juillet 04 mon userform m’a renvoyé dans ma cellule 07/01/04 au lieu de 01/07/04 alors que le précédent mois fonctionnait parfaitement !
J’ai donc dû changer :
Format(Now, "DD/MM/YYYY")
Pour :
Format(Now, "MM/DD/YYYY")

Quelqu’un serait il pourquoi ?


Et pour finir une petite question relative à ce même userform et cette même date.
J’ai mis en place un tableau de statistique avec des formules du type SOMMEPROD.
Le hic c’est qu’une formule : =SOMMEPROD((Saisie!$A$7:$A$500=C$6)*(Saisie!$R$7:$R$500=1)*(Saisie!$J$7:$J$500))
Ne fonctionne pas alors que la même formule avec "" fonctionne :
=SOMMEPROD((Saisie!$A$7:$A$500="01/07/2004")*(Saisie!$R$7:$R$500=1)*(Saisie!$J$7:$J$500))

Sachant qu’en Saisie!$A$7:$A$500 j’ai une valeur du type jj/mm/aaaa et qu’en C$6 j’ai une valeur du même type…


Bon we ;-)

 

[Monique]

Re: Userform & SOMMEPROD => pb de date

Bonjour,

Deuxième partie de ta question, seulement.
Si C6 contient la formule =AUJOURDHUI(), ça devrait fonctionner.
Si tu as tapé en C6 =MAINTENANT(), ça ne marche qu'une fois par jour, à 00:00
Le 2 juillet 2004, la formule =AUJOURDHUI() ----> n° de série 38170
tandis que =MAINTENANT() ----> 38170 pile à 00:00 pile seulement
38170,25 à 06:00
38170,50 à 12:00
Etc

 

[lo]

Re: Userform & SOMMEPROD => pb de date

Bonjour Monique,


Hum... je pense qu'il n'y a pas mieux qu'un petit exemple pour s'expliquer. Je joins à ce post un .xls qui t'aidera à mieux comprendre le pb évoqué en 2).

Merci pour la formule =MAINTENANT que je ne connaissais pas ;-)

 

[Monique]

Re: Userform & SOMMEPROD => pb de date

Re,

En colonne A de la feuille "Saisie",
les dates sont du texte !
Si on enlève l'alignement horizontal centré,
tes dates s'alignent à gauche, comme du texte
Si tu mets le curseur dans une cellule et que tu valides, ça s'aligne à droite : c'est devenu une valeur numérique.
Un autre essai :
en D7, tu tapes 17/06/2004
En E7, tu tapes =A7=D7 --> Réponse : "FAUX"
Tu valides A7 et le FAUX devient VRAI
Tu peux aussi taper =ESTTEXTE(A7)

 

[Monique]

Re: Userform & SOMMEPROD => pb de date

Re,

Tu peux laisser les dates en texte dans la feuille de saisie,
en modifiant les SommeProd de la feuille de stat.
En F6 :
=SOMMEPROD((1*(Saisie!$A$7:$A$500)=$C6)*(Saisie!$R$7:$R$500=1)*(Saisie!$J$7:$J$500))
En G6 :
=SOMMEPROD((1*(Saisie!$A$7:$A$500)=$C6)*(Saisie!$R$7:$R$500=1)*(Saisie!$N$7:$N$500))
Etc

De cette manière, aussi
=SOMMEPROD((1*(Saisie!$A$7:$A$500)=$C6)*(Saisie!$R$7:$R$500=1);Saisie!$J$7:$J$500)
=SOMMEPROD((1*(Saisie!$A$7:$A$500)=$C6)*(Saisie!$R$7:$R$500=1);Saisie!$N$7:$N$500)

 

[lo]

Re: Userform & SOMMEPROD => pb de date

Monique,

Merci.
J'ai mis en place les formules du type =SOMMEPROD((1*(Saisie!$A$7:$A$500)=$C6)*(Saisie!$R$7:$R$500=1)*(Saisie!$J$7:$J$500)) et tt semble fonctionner. Par contre peux tu me dire pourquoi il aura fallu rajouter 1*()= ?

Bon week-end

 

[Monique]

Re: Userform & SOMMEPROD => pb de date

Re

Le *1 rend numérique le contenu de la cellule
C'est l'équivalent de CNUM() en plus court
=CNUM(A2)
=1*A2
=0+A2
=A2-0
=A2/1

 

[loic]

Re: Userform & SOMMEPROD => pb de date

Hello Monique,

Je viens tt juste de récuperer mon poste avec mon accès à Internet.
Merci pour tes explications !