Une fonction (VBA) qui repère s'il y a un ou des doublons

=SIGNE(SOMME((Plage<>"")*EXACT(Plage;TRANSPOSE(Plage)))-NBVAL(Plage))

Function Doublons(plage As Range) As Byte
Dim a$
a = plage.Address
Doublons = Sgn(Evaluate("SUM((" & a & "<>"""")*EXACT(" & a & ",TRANSPOSE(" & a & ")))-COUNTA(" & a & ")"))
End Function

Sub test()
Dim t() As Boolean
ReDim t(2000, 2000) 't(5000, 5000)
ThisWorkbook.Names.Add "tab", t
End Sub

Function Roger3(Plage As Range, Optional Casse As Boolean) As Boolean
'Nécessite l'ajout de la bibliothèque Microsoft Scripting Runtime au projet.
'Ignore les cellules vides.
Dim i&, v(), Dic As New Dictionary
    Dic.CompareMode = -Not Casse
    v = Plage.Value
    On Error GoTo E
    For i = 1 To UBound(v)
        If Not IsEmpty(v(i, 1)) Then Dic.Add CStr(v(i, 1)), True
    Next i
Exit Function
E:  Roger3 = True
End Function

Function RogerV3(Plage As Range, Optional Casse As Boolean) As Boolean
'Nécessite l'ajout de la bibliothèque Microsoft Scripting Runtime au projet.
'N'ignore pas les cellules vides.
Dim i&, v(), Dic As New Dictionary
    Dic.CompareMode = -Not Casse
    v = Plage.Value
    On Error GoTo E
    For i = 1 To UBound(v)
        Dic.Add CStr(v(i, 1)), True
    Next i
Exit Function
E:  RogerV3 = True
End Function

Function DoublonsJOB(plage As Range, Optional Casse As Boolean) As Byte
Dim t, ub&, x, i&, j&
t = plage 'matrice, plus rapide
ub = UBound(t)
For i = 1 To ub - 1
  x = t(i, 1)
  If x <> "" Then
    For j = i + 1 To ub
      If StrComp(t(j, 1), x, -Not Casse) = 0 Then DoublonsJOB = True: Exit Function
    Next
  End If
Next
End Function

Option Compare Binary

Option Compare Text

Function Doublons(Plage As Range, Optional CelVides As Boolean, Optional Casse As Boolean) As Boolean
'Vérifie s'il y a ou pas un ou des doublons (avec certaines conditions) dans une plage de cellules
'- Plage : plage de cellules où l'on recherche des doublons
'- CelVides : CelVides = False (ou omis) --> ignore les cellules vides
'             CelVides = True --> n'ignore pas les cellules vides
'- Casse : Casse = False (ou omis) --> ignore la casse : 2 items en majuscule ou minuscule seront considérés comme identiques (ex : a = A)
'          Casse = True --> n'ignore pas la casse : 2 items en majuscule ou minuscule seront considérés comme différents (ex : a <> A)
'ROGER2327
    Dim i&, v(), Dic As Object
    Set Dic = CreateObject("Scripting.Dictionary")
    Dic.CompareMode = -Not Casse
    v = Plage.Value
    On Error GoTo E
    For i = 1 To UBound(v)
        If CelVides = True Then
            Dic.Add CStr(v(i, 1)), True
        Else
            If Not IsEmpty(v(i, 1)) Then Dic.Add CStr(v(i, 1)), True
        End If
    Next i
    Exit Function
E:  Doublons = True
End Function