Trouver une valeur minimale supérieure à 0 parmi des cellules non adjacentes

[benjinain]

Bonjour à tous,

Voilà mon problème :
Je souhaite reporter la valeur minimale parmi plusieurs cellules situées sur une même ligne mais pas adjacentes entre elles. Dans l'exemple joint, je souhaite trouver la valeur minimale parmi les cellules D4, F4 et H4 (ou D5, F5 et H5).
Le contenu de ces cellules étant donné par une formule, il affiche 0 lorsqu'il manque une des informations de cette formule.
J'ai donc tenté avec la formule matricielle suivante : =MIN(SI(D4;F4;H4)>0;(D4;F4;H4);"")
Ça ne marche malheureusement pas et j'obtiens une erreur #VALEUR.

Quelqu'un aurait-il une solution à me proposer (de préférence sans VBA)?

Merci d'avance!

 

[CISCO]

Re : Trouver une valeur minimale supérieure à 0 parmi des cellules non adjacentes

Bonjour

MIN(SI(C4:H4>0;C4:H4;""))

en matriciel donne le bon résultat (Si tu ne veux pas tester C4, fais avec D4:H4).

Lorsque tu écris

MIN(SI(D4;F4;H4)>0;(D4;F4;H4);"")

Excel comprend SI D4>=0, tester F4 >0, sinon, tester H4>0. Prendre aussi D4, F4, H4 et "". Puis finalement prendre le MIN de tout cela (soit VRAI, D4, F4, H4 et "", soit FAUX, D4, F4, H4 et "").

 

[benjinain]

Re : Trouver une valeur minimale supérieure à 0 parmi des cellules non adjacentes

Bonjour CISCO et merci de ta réponse.

Je rappelle cependant que je ne veux pas prendre en compte toutes les cellules de la ligne. Ta proposition intègre le contenu des cellules E4 et G4, ce que je ne souhaite pas.

 

[CISCO]

Re : Trouver une valeur minimale supérieure à 0 parmi des cellules non adjacentes

Re

Dans ce cas, essaye avec

MIN(SI((C4:H4>0)*(DROITE(C$2:H$2;1)="A");C4:H4;""))

toujours en matriciel

@ plus

 

[CISCO]

Re : Trouver une valeur minimale supérieure à 0 parmi des cellules non adjacentes

Re

Ou encore

MIN(SI((C4:H4>0)*(EST.PAIR(COLONNE(C4:H4)));C4:H4;""))

toujours en matriciel

@ plus

 

[job75]

Re : Trouver une valeur minimale supérieure à 0 parmi des cellules non adjacentes

Bonjour benjinain, CISCO,

Formule en I4 :

=MIN(SI((D4:H4>0)*(MOD(COLONNE(D4:H4);2)=0);D4:H4))

ou plus générale, si l'on déplace le tableau :

=MIN(SI((D4:H4>0)*(MOD(COLONNE(D4:H4);2)=MOD(COLONNE(D4);2));D4:H4))

Ce sont des formules matricielles à valider par Ctrl+Maj+Entrée.

Fichier joint.

Edit : pardon, pas vu les posts #4 et #5...

A+

 

[benjinain]

Re : Trouver une valeur minimale supérieure à 0 parmi des cellules non adjacentes

Re,

Ca marche super, merci beaucoup! Rapide et efficace!