Trop d'imbrication tue l'imbrication

[dudul54]

Bonsoir à tous.
Ceci est mon premier message sur le forum.
J'aurais besoin de vos lumières pour essayer de résoudre un problème concernant les imbrications.

J'ai voulu imposer afin de faciliter une RECHERCHEV, certains critères concernant des temps à faire pour un barème de notation en natation.

Seul souci, apparemment, j'atteins le quota maximum d'imbrication en enchainant une cascade de fonction SI.

Y aurait-il une meilleure solution restant accessible à un novice ?

Voilà ma formule en question :

=si(L3<25;"échec";si(L3<50;"25m";si(L3<75;"50m";si (L3<=100;100;si(L3<=110;110;si(L3<=120;120;si(L3<= 130;130;si(L3<=140;140;si(L3<=150;150;si(L3<=160;1 60;si(L3<=170;170;si(L3<=180;180;si(L3<=190;190;si (L3<=200;200;si(L3<=210;210;si(L3<=220;220;si(L3<= 230;230;si(L3<=240;240;si(L3<=250;250;si(L3<=260;2 60;si(L3<=270;270;si(L3>270;"100m+10"))))))))))))) )))))))))


Le but de la manœuvre étant de pouvoir déterminer la note automatiquement en fonction de la performance (qui serait bien évidemment standardisée) et le type de candidat.

Merci de votre aide et du temps que vous aurez bien voulu me prêter 🙂

 

[sioum]

Re : Trop d'imbrication tue l'imbrication

bonsoir

c'est quoi K3?

 

[dudul54]

Re : Trop d'imbrication tue l'imbrication

Mince, j'ai oublié de changer la formule après avoir modifié le fichier 🙁

Formule éditée ^^

K3 ==> L3


L3 étant la "performance" en mètre ou en secondes réalisée par une personne 🙂

 

[CISCO]

Re : Trop d'imbrication tue l'imbrication

Bonsoir

Je suppose que dans ta formule, c'est L3 qu'il faut écrire, et pas K3.

@ plus

 

[dudul54]

Re : Trop d'imbrication tue l'imbrication

Bonsoir Cisco, tout à fait, L3 et non K3 🙂

 

[JNP]

Re : Trop d'imbrication tue l'imbrication

Bonsoir le fil 🙂,
Le temps que je traduise ta formule de départ, y avait déjà du beau monde 😉...
Sricto senso, ta formule pourrait être traduite ainsi :

=SI(K3<100;CHOISIR(ENT(K3/25)+1;"échec";"25m";"50m";100);SI(K3>270;"100m+10";ARRONDI.SUP(K3;-1)))

ensuite, en ouvrant ton fichier, j'ai vu qu'il y avait des 100m +5, donc ça doit pas être exactement ça, mais y a de l'idée 🙄...
Bonne soirée 😎

 

[CISCO]

Re : Trop d'imbrication tue l'imbrication

Bonsoir à tous, bonsoir JNP

Essayes avec

SI(SUBSTITUE(L3;"m";"")*1<25;"échec";SI(SUBSTITUE(L3;"m";"")*1<50;"50m";SI(SUBSTITUE(L3;"m";"")*1<75;"50m";SI(SUBSTITUE(L3;"m";"")*1<=270;ARRONDI.SUP(L3/10;0)*10;"100m+10"))))

valable sur excel 2007

@ plus

 

[JNP]

Re : Trop d'imbrication tue l'imbrication

Re, salut Cisco 🙂,
J'ai du abuser de substances quelconques, car en voyant ta réponse, j'ai rien compris au film 🙁...
Bonne soirée, je vais me coucher, j'essayerai de comprendre un autre jour 🙄...

 

[dudul54]

Re : Trop d'imbrication tue l'imbrication

Merci à vous deux pour vos propositions 🙂

JNP, la tienne marche plutôt bien quand je l'utilise sur mes quelques 1000 lignes, sauf dans le cas, effectivement où l'on retrouve des formats alpha-numérique, à ce moment là, il ne me donne que du 100+10m mais c'est déjà une bonne piste 🙂.

En tout cas, merci beaucoup, même si je ne comprend pas du tout le principe de la fonction choisir qui m'a l'air ma foi, bien utile.

Cisco, ta technique me pose deux soucis, au boulot, tout le monde n'utilise que du excel 2003 grand max, du coup, je ne peux l'utiliser, de plus, sur ma version, le souci des palliers n'est pas pris en compte correctement, mais merci énormément d'avoir essayé de chercher 😱

 

[ROGER2327]

Re : Trop d'imbrication tue l'imbrication

Bonsoir à tous

Je tente le coup sans aucune conviction en voyant le barème Aisance aquatique : deux lignes pour 100m correspondant à deux notes différentes, même chose pour 100m+5, W31:W40 vide.

SGDG ni de moi-même :

=INDEX($X$21:$X$41;SI(ESTNUM(L3);EQUIV(MIN(L3;DECALER($Q$31;;EQUIV(J3;$R$21:$W$21;)));DECALER($Q$21:$Q$41;;EQUIV(J3;$R$21:$W$21;0));-1);EQUIV(L3;DECALER($Q$21:$Q$41;;EQUIV(J3;$R$21:$W$21;));)))

en L3, à recopier vers le bas.​

ROGER2327
#4947

Mardi 17 Gueules 138 (Le Bétrou, SQ)
23 Pluviôse An CCXIX
2011-W06-5T23:06:25Z

 

[dudul54]

Re : Trop d'imbrication tue l'imbrication

Bonsoir Roger,

J'vais tenter d'appliquer ta formule avec les bons barèmes cette fois, je n'ai pas pris le temps de les vérifier effectivement.

Voilà le bon fichier si tu veux bien te prêter au jeu avec la nouvelle mouture, je tente ma chance de mon coté avec ta formule. Voir si on obtient bien tous les deux la même chose 🙂

Merci d'avance ^^.

 

[dudul54]

Re : Trop d'imbrication tue l'imbrication

Merci Roger, vous venez de répondre à une question que je me posais, ou plutôt, vous avez résolus un souci que je voulais attaquer un peu plus tard, mais ca me retire déjà une bonne épine du pied ^^.

Merci beaucoup 🙂

 

[CISCO]

Re : Trop d'imbrication tue l'imbrication

Bonjour

Je ne sais quand a été rajouté la fonction ARRONDI.SUP sur Excel. Par conséquent, je ne puis te dire quelles versions d'Excel acceptent ou n'acceptent pas ma formule. Si besoin est, on peut trouver une relation mathématique faisant le même travail (ENT(L3/10)*10+SI(MOD(L3;10)>0;10;0)).

Cf. en pièce jointe ce que j'obtiens chez moi, enregistré sous excel 2003...

J'ai utilisé

SUBSTITUE(L3;"m";"")*1

pour contourner le problème des cellules alphanumérique, le m étant effacé, et le *1 permettant de transformer du texte en nombre.

et

ARRONDI.SUP(L4/10;0)*10

pour afficher, par exemple 100 avec 100, mais 110 avec 101, 102....juqu'à 109.

La formule, avec une vingtaine de SI
=si(L3<25;"échec";si(L3<50;"25m";si(L3<75;"50m";si (L3<=100;100;si(L3<=110;110;si(L3<=120;120;si(L3<= 130;130;si(L3<=140;140;si(L3<=150;150;si(L3<=160;1 60;si(L3<=170;170;si(L3<=180;180;si(L3<=190;190;si (L3<=200;200;si(L3<=210;210;si(L3<=220;220;si(L3<= 230;230;si(L3<=240;240;si(L3<=250;250;si(L3<=260;2 60;si(L3<=270;270;si(L3>270;"100m+10"))))))))))))) )))))))))

devient donc un truc du style, avec seulement 4 SI
=si(SUBSTITUE(L3;"m";"")*1<25;"échec";
si(SUBSTITUE(L3;"m";"")*1<50;"25m";
si(SUBSTITUE(L3;"m";"")*1<75;"50m";
si (SUBSTITUE(L3;"m";"")*1<=270;ARRONDI.SUP(L3/10;0)*10
;"100m+10"))))))
(tous les cas 100 à 270 sont remplacés par une seule fonction ARRONDI.SUP)


@ plus

 

[dudul54]

Re : Trop d'imbrication tue l'imbrication

Bonjour Cisco !

Et surtout MERCI.

J'ai tout simplement coller ta formule et POUF, c'est magique, tout est transformé sans aucun message d'erreur.

Encore merci 🙂