Transfert 11 contrôles vers Listbox

cathodique · 19 Mars 2018

Bonsoir🙂,

La listbox n'accepte pas plus de 10 colonnes, or je voudrais transférer 9 textbox et 2 combobox (pour simplifier car dans mon fichier original, j'ai 2 boutons d'option dans une frame).

Pour 10 contrôles c'est bon, le 11ème le code plante. Besoin de votre aide merci.

VB:

Private Sub CommandButton1_Click()

   Me.ListBox1.AddItem Me.TextBox1
   n = Me.ListBox1.ListCount - 1
   Me.ListBox1.List(n, 1) = Me.ComboBox1
   Me.ListBox1.List(n, 2) = Me.TextBox2
   Me.ListBox1.List(n, 3) = Me.ComboBox2
   Me.ListBox1.List(n, 4) = Me.TextBox3
   Me.ListBox1.List(n, 5) = Me.TextBox4
   Me.ListBox1.List(n, 6) = Me.TextBox5
   Me.ListBox1.List(n, 7) = Me.TextBox6
   Me.ListBox1.List(n, 8) = Me.TextBox7
   Me.ListBox1.List(n, 9) = Me.TextBox8
'   Me.ListBox1.List(n, 10) = Me.TextBox9 '*** plante ici
         For i = 1 To 9: Me("textbox" & i) = "": Next i
         For i = 1 To 2: Me("combobox" & i) = "": Next i

   Me.TextBox1.SetFocus
End Sub

Bonne soirée.😉

BOISGONTIER · 19 Mars 2018

Bonsoir,

Il faut passer par un Array et ensuite utiliser .List ou .Column

http://boisgontierjacques.free.fr/pages_site/formulaireListes2colonnes.htm#12col

JB

cathodique · 19 Mars 2018

Bonsoir Boisgontier😉,

C'est vraiment une agréable surprise. Je voulais te remercier pour tes efforts.

Ton site fait parti de mes favoris. Avant d'ouvrir une discussion, j'effectue des recherches sur le forum, consulte ton site et bien souvent j'utilise google.

J'ai bien consulté l'exemple de ton lien. Il traite l'extraction à partir d'une feuille de calcul.

Pour mon cas, je voudrais alimenter au fur et à mesure la listbox.

c'est à dire renseigner les différents contrôles, après clic transfert vers listbox et vidage des contrôles pour la ligne suivante.

Et, là j'avoue être incapable de le faire ou plutôt je ne vois pas comment adapter ton exemple.

Merci beaucoup.

Bonne soirée

BOISGONTIER · 19 Mars 2018

Cf PJ

Code:

Private Sub CommandButton1_Click()
    Dim Tbl()
    If Me.ListBox1.ListCount > 0 Then
      TblE = Me.ListBox1.List
      n = Me.ListBox1.ListCount + 1
      ReDim Tbl(1 To n, 1 To 11)
      For i = LBound(TblE) To UBound(TblE)
        For j = LBound(TblE, 2) To UBound(TblE, 2)
          Tbl(i + 1, j + 1) = TblE(i, j)
        Next j
      Next i
     Else
       n = 1
       ReDim Tbl(1 To n, 1 To 11)
     End If
     Tbl(n, 1) = Me.TextBox1
     Tbl(n, 2) = Me.ComboBox1
     Tbl(n, 3) = Me.TextBox2
     Tbl(n, 4) = Me.ComboBox2
     Tbl(n, 5) = Me.TextBox3
     Tbl(n, 6) = Me.TextBox4
     Tbl(n, 7) = Me.TextBox5
     Tbl(n, 8) = Me.TextBox6
     Tbl(n, 9) = Me.TextBox7
     Tbl(n, 10) = Me.TextBox8
     Tbl(n, 11) = Me.TextBox9
     Me.ListBox1.List = Tbl
     For i = 1 To 9: Me("textbox" & i) = "": Next i
     For i = 1 To 2: Me("combobox" & i) = "": Next i
     Me.TextBox1.SetFocus
End Sub

JB

cathodique · 20 Mars 2018

Bonjour😉,

ça ne peut pas être plus parfait que ça. C'est parfait, toute ma gratitude.

J'avoue que je n'aurai jamais trouvé. Toute ma gratitude.

De Else à End Sub, j'ai compris. C'est du début jusqu'à Else que je n'ai pas bien compris. Peut-être en utilisant F8.

Merci beaucoup pour tout. J'ai beaucoup appris de ton site.

Bonne journée.

Transfert 11 contrôles vers Listbox

cathodique

XLDnaute Barbatruc

Pièces jointes

BOISGONTIER

XLDnaute Barbatruc

cathodique

XLDnaute Barbatruc

BOISGONTIER

XLDnaute Barbatruc

Pièces jointes

cathodique

XLDnaute Barbatruc

Discussions similaires

Transfert 11 contrôles vers Listbox

cathodique

XLDnaute Barbatruc

Pièces jointes

BOISGONTIER

XLDnaute Barbatruc

cathodique

XLDnaute Barbatruc

BOISGONTIER

XLDnaute Barbatruc

Pièces jointes

cathodique

XLDnaute Barbatruc

Discussions similaires

Privacy & Transparency

Privacy & Transparency