Microsoft 365 Tester l'existence d'un filtre dans un tableau structuré

Sub testFiltre()
Dim monTab As ListObject
Set monTab = Feuil1.ListObjects("Tableau_Struct")

On Error Resume Next
    If monTab.AutoFilter.FilterMode Then
        monTab.Range.AutoFilter
    End If
    monTab.ShowAutoFilterDropDown = True
    If monTab.AutoFilter.FilterMode Then
        monTab.Range.AutoFilter
    Else
        monTab.AutoFilter.ShowAllData
    End If
End Sub

'-----------------------------------------------------------------------
'Return = True si il y a des colonnes filtrées dans un tableau structuré
'-----------------------------------------------------------------------
Function ExisteColonnesFiltréesTableauStructuré(Tbl As ListObject) As Boolean   
    'Init Return Value
    ExisteColonnesFiltréesTableauStructuré = False

    With Tbl
        'Il n'y a pas de filtres
        If .AutoFilter Is Nothing Then Exit Function
  
        'Aucune colonne n'est filtrée
        If .AutoFilter.FilterMode = False Then Exit Function
      
        'Set Return Value
        ExisteColonnesFiltréesTableauStructuré = True
    End With
End Function

'--------------------------------------------------
'Liste des colonnes filtrées d'un tableau structuré
'Return: False si aucun filtre sur colonne
'        Tableau des numéros de colonnes filtées
'--------------------------------------------------
Function TabColonnesFiltréesTableauStructuré(Tbl As ListObject) As Variant
    Dim TabColonnesFiltrées() As Integer
    Dim NbColonnesFiltrées As Integer
    Dim j As Integer

    'Init Return Value
    TabColonnesFiltréesTableauStructuré = False
  
    'Il n'y a pas de colonne filtrée dans le tableau structuré
    If Not ExisteColonnesFiltréesTableauStructuré(Tbl) Then Exit Function
  
    With Tbl
        For j = 1 To .ListColumns.Count
            'Filtre sur colonne j
            If .AutoFilter.Filters(j).On Then
                NbColonnesFiltrées = NbColonnesFiltrées + 1
                ReDim Preserve TabColonnesFiltrées(1 To NbColonnesFiltrées)
                TabColonnesFiltrées(NbColonnesFiltrées) = j
            End If
        Next j
    End With
  
    TabColonnesFiltréesTableauStructuré = TabColonnesFiltrées
End Function