Tester la présence d'une valeur dans une colonne

[natorp]

Bonsoir à toutes et tous

J'aimerais tester la présence d'une valeur saisie dans une colonne,
si elle est présente on stoppe
si elle est absente on continue et on l'ajoute à la colonne testée

voir fichier joint

merci de votre aide, cordialement
Gérard

PS, merci de mettre le code dans le message de réponse ou dans la feuille excel, demain je serais au boulot et le code est effacé par le filtre de mon entreprise

 

[Etienne2323]

Re : Tester la présence d'une valeur dans une colonne

Bonsoir Gérard,
voici une possibilité.

Sub Test()

Dim Valeur_Test As String
Dim DerniereLigne As Integer
Dim Lig

Valeur_Test = Cells(1, 3).Value 'La valeur qu'on souhaite tester

DerniereLigne = Cells(65536, 1).End(xlUp).Row 'On va aller trouver la dernière ligne de la colonne A

'On va voir si on trouve la valeur testée.
Set Lig = Range(Cells(1, 1), Cells(DerniereLigne, 1)).Find(Valeur_Test, LookIn:=xlValues, LookAt:=xlWhole)
If Not Lig Is Nothing Then
    Exit Sub 'Si on la trouve, alors on sort de la macro
Else
    Cells(DerniereLigne + 1, 1).Value = Valeur_Test 'Sinon, on l'ajoute à la liste.
End If


End Sub

Bonne soirée,

Étienne

 

[natorp]

Re : Tester la présence d'une valeur dans une colonne

Etienne,

l'idée serait plutôt de tester en direct la saisie

si le mot saisi existe dans la colonne A alors on reste sur C1 et l'utilisateur est obligé d'en saisir un autre, sinon on passe à C2 et le mot et ajouté à la fin de la liste en colonne A

cordialement, Gérard

 

[Etienne2323]

Re : Tester la présence d'une valeur dans une colonne

Bonsoir Gérard,
voici une version qui devrait remplir votre besoin, du moins, je l'espère.

Sub Test()

Dim Valeur_Test As String
Dim DerniereLigne As Integer
Dim Lig

Valeur_Test = Cells(Cells(65536, 1).End(xlUp).Row, 3).Value 'La valeur qu'on souhaite tester

DerniereLigne = Cells(65536, 1).End(xlUp).Row 'On va aller trouver la dernière ligne de la colonne A

'On va voir si on trouve la valeur testée.
Set Lig = Range(Cells(1, 1), Cells(DerniereLigne, 1)).Find(Valeur_Test, LookIn:=xlValues, LookAt:=xlWhole)
If Not Lig Is Nothing Then
    Cells(Cells(65536, 1).End(xlUp).Row, 3).Select
Else
    Cells(DerniereLigne + 1, 1).Value = Valeur_Test 'Sinon, on l'ajoute à la liste.
    Cells(Cells(65536, 1).End(xlUp).Row + 1, 3).Select
End If


End Sub

Cordialement,

Étienne

 

[mth]

Re : Tester la présence d'une valeur dans une colonne

Bonsoir natorp, Etienne 🙂

Au cas où, une autre approche, avec ce code (à placer dans le code de la feuille):

Private Sub Worksheet_Change(ByVal Target As Range)
    If Target.Address = "$C$1" Then
        If Application.WorksheetFunction.CountIf([A:A], UCase(Target.Value)) = 0 Then
            Cells(Cells(Rows.Count, 1).End(xlUp).Offset(1, 0).Row, 1) = Target.Value
        End If
    End If
End Sub

Bonne soirée 🙂

mth

 

[natorp]

Re : Tester la présence d'une valeur dans une colonne

Bjr Etienne et mth

l'idée de mth est le bonne piste, je souhaiterais juste pouvoir ajouter un msgbox :
si le texte saisi en C1 existe dans la colonne A alors on efface C1 et on oblige à en saisir un autre

Merci de votre aide, cordialement
Gérard

 

[natorp]

Re : Tester la présence d'une valeur dans une colonne

Re

en fait j'ai essayé avec ça :

Private Sub Worksheet_Change(ByVal Target As Range)
    If Target.Address = "$D$4" Then
        If Application.WorksheetFunction.CountIf([A:A], UCase(Target.Value)) <> 0 Then
        Target.Cells = ""
        Range("D4").Select
        MsgBox ("Déjà utilisé !")
        Exit Sub
        ElseIf Application.WorksheetFunction.CountIf([A:A], UCase(Target.Value)) = 0 Then
            Cells(Cells(Rows.Count, 1).End(xlUp).Offset(1, 0).Row, 1) = Target.Value
            Cells(Sheets("Feuil1").Range("b1000").End(xlUp).Row + 3, 7) = Target.Value
            Range("D4").Select
        End If
    End If
End Sub

mais je n'arrive pas à fermer la msgbox (je pense qu'elle teste les 65000 lignes de la colonne A), y a-t-il une autre solution ?

merci de votre aide, cordialement
Gérard

 

[Si...]

Re : Tester la présence d'une valeur dans une colonne

Salut

à tester

Private Sub Worksheet_Change(ByVal Target As Range)
  If Target.Address <> "$D$4" Or Target.Count > 1 Then Exit Sub
  If Target = "" Then Exit Sub 'pour éviter des appels successifs
  Dim Dli As Long
  Dli = Cells(Rows.Count, 1).End(xlUp).Row
  If Application.CountIf(Range("A1:A" & Dli), Target) > 0 Then
    MsgBox Target & " est déjà dans la liste", vbInformation, "pas accepté :"
    Target = ""
  Else
    Cells(Dli + 1, 1) = Target
    Cells(Sheets("Feuil2").Range("B1000").End(xlUp).Row + 3, 7) = Target
    '----- OU, pour écrire en Feuil2
    'With Sheets("Feuil2")
    '  .Cells(.Range("B1000").End(xlUp).Row + 3, 7) = Target
    'End With
  End If
  Target.Select
End Sub

 

[natorp]

Re : Tester la présence d'une valeur dans une colonne

Bjr Si...

Super, ça marche impecc' merci beaucoup, bonne journée

Gérard