test avec foction SI sur des heures

[Soina06]

Bonsoir a tous,
je chercher le moyen de realiser un test, sur une cellule B6 au forma [hh]mm
il va y avoir 3 possibilité de reponses
1- B6 < 70:00=0
2- B6 compris entre 70:00 et 77:00 =0.5
3- B6 > 77:00=1
j'ai utilisé cette formule, mais cela ne marche pas

=SI(B6<"70:00";0;SI(B6>="70:00";0,5;SI(B6>"77:00";1)))
Je vous remerci de votre aide
amicalement

 

[Monique]

Bonjour,

Les heures entre guillemets doivent être rendues numériques,
par *1 ou /1 ou +0 ou -0
=SI(B6<"70:"*1;0;SI(ET(B6>="70:"*1;B6<="77:"*1);0,5;SI(B6>"77:"*1;1)))
La dernière condition n'a pas besoin d'être écrite (c'est "sinon") :
=SI(B6<"70:"*1;0;SI(ET(B6>="70:"*1;B6<="77:"*1);0,5;1))

Sinon, pour Excel, 1 = 1 jour, 1 / 24 = 1 heure.
Au choix :
=SI(B6<70/24;0;SI(ET(B6>=70/24;B6<=77/24);0,5;SI(B6>77/24;1)))

La dernière condition n'a pas besoin d'être écrite :
=SI(B6<70/24;0;SI(ET(B6>=70/24;B6<=77/24);0,5;1))

Ou bien,
=(B6>=70/24)*(B6<=77/24)*0,5+(B6>77/24)
qui équivaut à VRAI * VRAI * 0,5 + FAUX
ou FAUX * FAUX * 0,5 + VRAI
ou FAUX * FAUX * 0,5 + FAUX
(faux = 0 et vrai = 1)

 

[Jean-Marie]

Bonsoir

=SI(B6<TEMPSVAL("70:00");0;SI(B6>=TEMPSVAL("77:00:00");1;0,5))
ou
=SI(B6<"70:00"+0;0;SI(B6>="77:00"+0;1;0,5))
ou
=SI(B6<70/24;0;SI(B6>=77/24;1;0,5))

"70:00"+0 converti le temps "chaîne" en temps "série.
1 est égal à 1 jour, 1/24 est égal à 1 heure.


@+Jean-Marie

 

[Soina06]

Merci Monique et Jean Marie, je vien sde finaliser mon tableau avec vos conseils
C'est super