supprimer N/A apres recherchev

[alexclo]

Bonjour


j ai regarde les differents echanges sur le sujet et pense avoir trouve ma solution

=IF(VLOOKUP(A4,'[Supplier TO analysis template.xlsx]2015'!$A$5:$C$111,2,FALSE)="#N/A","0",VLOOKUP(A4,'[Supplier TO analysis template.xlsx]2015'!$A$5:$C$111,2,FALSE))

malgre cela les N/A restent

j ai egalemet essaye avec ESTNA/ISNA sans plus de success
if(isna(VLOOKUP(A4,'[Supplier TO analysis template.xlsx]2015'!$A$5:$C$111,2,FALSE),"",VLOOKUP(A4,'[Supplier TO analysis template.xlsx]2015'!$A$5:$C$111,2,FALSE)))
excel me dit que je mets trop darguments pour cette function.....

j ai donc fait une simulation beaucoup plus simple
=IF(F4="#N/A",1,0)
quand je mets in chiffre ou une lettre ca me met bien 0
si je mets #N/A, bingo, la reponse est #N/A....

bref je suis perdu dansd les meandres d excel

merci d avance pour vos lumieres

 

[Victor21]

Bonjour.

La lumière, c'est bien. Encore faut-il avoir quelque chose à éclairer. Où est donc le petit fichier Excel qui reproduit la difficulté ?

 

[eriiic]

Bonjour,

essaie avec :

=sierreur(ta_formule;0)

eric

 

[job75]

Bonjour alexclo, Patrick, eriiiic,

#N/A est une valeur d'erreur, utiliser "#N/A" qui est un texte ne vaut rien.

Et vous n'avez pas dû utiliser ISNA correctement.

Voici 4 formules, de la plus légère à la plus lourde :

=IFERROR(VLOOKUP(A4,'[Supplier TO analysis template.xlsx]2015'!$A$5:$C$111,2,FALSE),0)

=IF(COUNTIF('[Supplier TO analysis template.xlsx]2015'!$A$5:$A$111,A4),VLOOKUP(A4,'[Supplier TO analysis template.xlsx]2015'!$A$5:$C$111,2,FALSE),0)

=IF(ISNA(MATCH(A4,'[Supplier TO analysis template.xlsx]2015'!$A$5:$A$111,0)),0,VLOOKUP(A4,'[Supplier TO analysis template.xlsx]2015'!$A$5:$C$111,2,FALSE))

=IF(ISNA(VLOOKUP(A4,'[Supplier TO analysis template.xlsx]2015'!$A$5:$C$111,2,FALSE)),0,VLOOKUP(A4,'[Supplier TO analysis template.xlsx]2015'!$A$5:$C$111,2,FALSE))

On peut utiliser ISERROR à la place de ISNA si A4 peut être une valeur d'erreur.

La 1ère formule ne renvoie jamais de valeur d'erreur, alors que les 3 autres peuvent en renvoyer si la valeur trouvée en colonne B du fichier source est une valeur d'erreur.

A+

 

[alexclo]

merci beaucoup pour cet aide

je vais essayer l une ou l autre