XL 2019 Supprimer des cellules en fonction d'une cellule de la ligne

[chris4785478547]

Bonjour tout le monde,
J'ai essayé de trouver cette solution sur ce forum et d'autres, même si certains sujets se rapprochent de mon problème, je n'arrive pas à adapter...
Il s'agit d'effacer les 8 premières colonnes de chaque ligne comprenant (en 1ere colonne) une date= "01/01/1900"
Ma macro est celle ci:

Sub Macro2()
'
' Macro2 Macro
'

Dim i, j

For i = 7 To 65535
If CDate(Cells(i, 1).Value) = "01/01/1900" Then
For j = 1 To 8
Cells(i, j).ClearContents
Next j
Next i

'

End Sub

Elle me renvoie une erreur de compilation : NEXT SANS FOR (sur le next i)
J'ai certainement une erreur de syntaxe mais je ne vois pas laquelle
Merci par avance.

 

[sylvanu]

Bonjour Chris,
Prenez l'habitude d'indenter:

Sub Macro2()
Dim i, j
For i = 7 To 65535
    If CDate(Cells(i, 1).Value) = "01/01/1900" Then
        For j = 1 To 8
            Cells(i, j).ClearContents
        Next j
    End If
Next i
End Sub

Il manquait un End If, et il y avait un End With en trop. 😛

En plus vous pouvez réduire la boucle en allant seulement jusqu'à le dernière cellule occupée avec :

For i = 7 To Range("A65500").End(xlUp).Row

 

[chris4785478547]

Bonjour Chris,
Prenez l'habitude d'indenter:

Sub Macro2()
Dim i, j
For i = 7 To 65535
    If CDate(Cells(i, 1).Value) = "00/01/1900" Then
        For j = 1 To 8
            Cells(i, j).ClearContents
        Next j
    End If
Next i
End Sub

Il manquait un End If, et il y avait un End With en trop. 😛

En plus vous pouvez réduire la boucle en allant seulement jusqu'à le dernière cellule occupée avec :

For i = 7 To Range("A65500").End(xlUp).Row

Merci Sylvanu pour cette réponse.
Je venais de voir que j'avais omis d'enlever le End with mais le End if m'échappait toujours. Merci.
Pourtant, de mon côté j'ai une erreur:

"Erreur d'exécution 13: Incompatibilié de type"

Sub Macro2()
'
' Macro2 Macro
'

Dim i, j

    For i = 7 To 65535
        If CDate(Cells(i, 1).Value) = "00/01/1900" Then
            For j = 1 To 8
                Cells(i, j).ClearContents
            Next j
        End If
    Next i
End Sub

Si vous avez une idée...
Bien sûr, dès que ça fonctionnera, je raccourcirai mon code avec la proposition.
Merci

 

[Staple1600]

Bonjour le fil

Fonctionne chez moi
(avec ce petit biais 😉)

Sub Macro3()
Const X = #12/31/1899#
Dim i, j
For i = 7 To 65535
    If Cells(i, 1).Value = X Then
        For j = 1 To 8
            Cells(i, j).ClearContents
        Next j
    End If
Next i
End Sub

 

[eriiic]

Bonjour à tous,

ou bien, le 01/01/1900 étant 1 :

    Dim i As Long
    For i = 7 To Cells(Rows.Count, 1).End(xlUp).Row
        If Cells(i, 1).Value = 1 Then
            Cells(i, 1).Resize(, 8).ClearContents
        End If
    Next i

eric

 

[Staple1600]

Bonsoir eriiic

Y a pas photo entre un banal 1 et ce si particulier 31 😉

 

[eriiic]

Certes oui 😉
Mais je n'ai pas compris pourquoi vous prenez le 00/01/1900 (ou 31/12/1899) alors qu'il parle d'un 1 et non d'un 0 (?)
Quoiqu'il en soit, inutile de s'encombrer d'un CDate()

 

[Staple1600]

Re

Moi c'est à cause de

Sub Test()
[A1] = "01/01/1900"
MsgBox [A1].Value
End Sub

Ce qui m'a permis de re-découvrir rétro-news 😉
Donc rien que pour cela, merci à chris pour sa question 😉

NB: Si jamais il y avait des vrais 1 au milieu des 01/01/1900
Avec le X, c'est plus sexy, non ? 😉

 

[eriiic]

Ah oui, c'est vrai que vba ne démarre pas les dates le même jour.
Tout les 1 sont vrais non ?

 

[mapomme]

Bonjour à tous 🙂,

Pour le fun :

Sub Macro1()
Dim x
   Application.ScreenUpdating = False
   For Each x In Range(Range("a7"), Cells(Rows.Count, 1).End(xlUp)).Cells
      If IsDate(x) Then If x = 1 Then x.Resize(, 8).ClearContents
   Next x
End Sub

 

[Staple1600]

Re

je voulais dire si il y a des 1 qui ne correspondent pas à 01/01/1900 mais à des 1 fait à la main, sans pesticides 😉
Et les données associées à ces vrais 1 ne doivent pas être effacés.
Avec mon code, seuls les 01/01/1900 sont traitées 😉

EDITION: Pan sur le nez
Au coin, Staple, j'ai dit une cronerie
Désolé.

 

[mapomme]

Bonjour @Staple1600 🙂

mais à des 1 fait à la main, sans pesticides 😉
Et les données associées à ces vrais 1 ne doivent pas être effacés.

N'est ce pas ce que fait mon code ?

 

[Staple1600]

Bonsoir mapomme

Je ne sais pas ce que fait ton code.
Mais je sais que je t'ai pas vu passé dans le fil.

C'est normal!

Je suis au coin.
(cf mon précédent message)

 

[mapomme]

Je ne sais pas ce que fait ton code.
Mais je sais que je t'ai pas vu passé dans le fil.

Faux arrêter le chouchen. C'est pas bon pour toi à ton âge 😛

 

[Staple1600]

Faux arrêter le chouchen. C'est pas bon pour toi à ton âge 😛

C'est pas faux qu'il faut mais faux est qu'il faux arrêter.

OK, je retourne au coin 😉