Suppresion feuille excel d'un autre classeur

[YaGo]

Bonsoir à tous,

Je compte réalisé une suppression de feuille dans un tableau esclave via mon tableau maitre mais malgré plusieurs essaie lorsque j'arrive à la 4ème feuille quelque soit sont nom ou ce qu'elle contient, j'obtiens le message d'erreur "L'indice n'appartient pas à la sélection" (idem pour un fichier avec moins de 4 feuille, la dernière bloque)

L'erreur apparait sur cette ligne: If Worksheets(i).Name <> "Table" Then

Sub UpdateDocument(Text As String)
Application.ScreenUpdating = False
Dim WorkbookMaster As Workbook, WorkbookSlave As String
Dim Document, DocumentTable
Dim i As Integer

Set WorkbookMaster = ActiveWorkbook
WorkbookSlave = Dir(ActiveWorkbook.Path & "\ " & Text)
Set Document = Workbooks.Open(ActiveWorkbook.Path & "\" & WorkbookSlave)
Set DocumentTable = Document.Sheets("Table")

Application.DisplayAlerts = False
For i = 1 To Worksheets.Count
If Worksheets(i).Name <> "Table" Then
Worksheets(i).Delete
End If
Next
Application.DisplayAlerts = True

Workbooks(WorkbookSlave).Close
Application.DisplayAlerts = False
Application.ScreenUpdating = True
End Sub

Bonne soirée,

YaGo

 

[Victor21]

Re : Suppresion feuille excel d'un autre classeur

Bonjour, YaGo.

Je n'y connais pas grand'chose en VBA, mais votre code ne chercherait-il pas la feuille Table dans le WorkbookMaster ?

A moins qu'il ne vous faille utiliser

 For I = Sheets.Count To 1 Step -1

PS : je n'ai pas cherché à tester sur les extraits de fichiers que vous avez omis de joindre.

 

[camarchepas]

Re : Suppresion feuille excel d'un autre classeur

Bonjour Yago , Victor

Bon , y'a des fois ou l'on se complique , a se demander si payé à la pige ...

Voici pour le demandé en enlevant toutes les fleuritures :

Sub UpdateDocument(Text As String)

Dim WorkbookSlave As String
Dim Onglet As Worksheet

Application.ScreenUpdating = False
 WorkbookSlave = Dir(ThisWorkbook.Path & "\ " & Text)
 Workbooks.Open (ActiveWorkbook.Path & "\" & WorkbookSlave)
  Application.DisplayAlerts = False
  For Each Onglet In Workbooks(WorkbookSlave).Worksheets
   If Onglet.Name <> "Table" Then Onglet.Delete
  Next
  Application.DisplayAlerts = True
 Workbooks(WorkbookSlave).Close
Application.ScreenUpdating = True
End Sub

 

[job75]

Re : Suppresion feuille excel d'un autre classeur

Bonjour à tous,

Quitte à simplifier :

Sub UpdateDocument(Text As String)
Dim w As Worksheet
Application.ScreenUpdating = False
Application.DisplayAlerts = False
With Workbooks.Open(ActiveWorkbook.Path & "\" & Text)
  For Each w In .Worksheets
    If w.Name <> "Table" Then w.Delete
  Next
  .Close True 'fermeture avec enregistrement
End With
End Sub

A+

 

[YaGo]

Re : Suppresion feuille excel d'un autre classeur

Bonjour Victor, CamarchePas et Job75,

Merci à tous pour vos réponses et vos conseils.
Maintenant mon programme marche comme sur des roulettes!

Bonne journée!