Somme conditionnelle

jeanpierre

Nous a quitté

Repose en paix

• 2 Août 2008

• #2

Re : Somme conditionnelle

Bonsoir isa44,

Pourquoi par macro, un SOMMEPROD doit suffire...

Difficlie de t'en dire plus sans exemple concret.

Bonne soirée.

Jean-Pierre

 

Vote positif 0 Vote négatif

cibleo

XLDnaute Impliqué

• 2 Août 2008

• #3

Re : Somme conditionnelle

Bonjour isa44, jeanpierre

Isa44 ou pourquoi faire simple quand on peut faire compliqué 🙄

Comme dis jeanpierre, un sommeprod suffit amplement :

=SOMMEPROD((E11:E20="A")*(E11:E20="B")*K11:K20)

En bonus, une petite leçon de Monique dans le lien ci-dessous :

https://www.excel-downloads.com/threads/somme-si-avec-2-criteres.80243/

Amicalement Cibleo

 

Dernière édition: 2 Août 2008

Vote positif 0 Vote négatif

I

isa44

XLDnaute Occasionnel

• 2 Août 2008

• #4

Re : Somme conditionnelle

Merci les amis, ben oui c'est simple quand la solution est trouvée, mais avant quand l'on s'entête.......

 

Vote positif 0 Vote négatif

chris

XLDnaute Barbatruc

• 2 Août 2008

• #5

Re : Somme conditionnelle

Bonjour à tous
Bise à Jean Pierre

On peut faire encore plus simple (pour ceux qui ne sont pas à l'aise avec SOMMEPROD) sinon plus court

=SOMME.SI(E11:E20;"A";K11:K20)+SOMME.SI(E11:E20;"B";K11:K20)

 

Vote positif 0 Vote négatif

exene

XLDnaute Accro

• 3 Août 2008

• #6

Re : Somme conditionnelle

Bonjour le Forum,

Bonjour le Fil,

Ce sujet m'intéresse, alors j'ai pris vos deux solutions. En l'absence de tableau, j'en ai crée un , la formule avec SOMMEPROD retourne le résultat 0 alors que la formule SOMME.SI retourne un résultat différent.
Avez vous une explication ?. Ci-joint tableau.

Cordialement.

 

Pièces jointes

• conditions.xls

  13.5 KB · Affichages: 73
• conditions.xls

  13.5 KB · Affichages: 74
• conditions.xls

  13.5 KB · Affichages: 67

Vote positif 0 Vote négatif

A

abcd

XLDnaute Barbatruc

• 3 Août 2008

• #7

Re : Somme conditionnelle

Bonjour,

H11 : =SOMME(SI((E11:E20="A")+(E11:E20="B");K11:K20)) → matricielle (Ctrl+Maj+Entrée)
H12 : =SOMMEPROD(((E11:E20="A")+(E11:E20="B"))*K11:K20)

La fonction SOMMEPROD est également matricielle, mais peut être validée par une simple Entrée.

En matricielles :
OU → +
ET → *
SAUF → -

Les conditions (E11:E20="A") et (E11:E20="B") renvoient chacune VRAI ou FAUX, soit 1 ou 0.
En les multipliant on obtient toujours 0, en les additionnant on obtient 1 (VRAI) si une des deux conditions est remplie et 0 s'il n'y en a aucune.
Dans le cas présent c'est bien l'une ou l'autre condition et non l'une et l'autre condition.

abcd

 

Vote positif 0 Vote négatif

wilfried_42

XLDnaute Barbatruc

• 3 Août 2008

• #8

Re : Somme conditionnelle

Bonjour à tous

voici ton sommeprod :

Code:

=SOMMEPROD((((E11:E20="A")+(E11:E20="B"))>0)*K11:K20)

et ta formule matricielle

Code:

=SOMME(((E11:E20="A")+(E11:E20="B"))*K11:K20)

le probleme que tu rencontres, c'est que tu travailles sur la meme colonne, avec 2 valeurs differentes de test, donc en francais, tu cherches la somme de la colonne K, si la colonne E = A ou =B

un * = ET or une cellule ne pouvant etre à la fois = à A et B, le resultat est 0
+ = OU ce qui correspond à ta demande

selon l'exemple donné, regardons les resultats selon les valeurs possibles

avec * (ET), (E11:E20="A") * (E11:E20="B")
cellule E = A : 1 * 0 = 0
cellule E = B : 0 * 1 = 0
cellule E = C : 0 * 0 = 0
le resultat des tests etant = à 0 à chaque ligne, le resultat final = 0

avec + (OU), (E11:E20="A") + (E11:E20="B")
Cellule E = A : 1 + 0 = 1
Cellule E = B : 0 + 1 = 1
Cellule E = C : 0 + 0 = 0
le resultat des tests etant = à 1 Quand tu as soit A, soit B, le resultat finale correspond bien à tes criteres

oups : bonjoue abcd, excuse pour la collision

 

Vote positif 0 Vote négatif

exene

XLDnaute Accro

• 3 Août 2008

• #9

Re : Somme conditionnelle

Bonjour abcd et Wilfried,

Merci pour votre disponibilité et la clarté des explications.

Bon dimanche.

 

Vote positif 0 Vote négatif

chris

XLDnaute Barbatruc

• 3 Août 2008

• #10

Re : Somme conditionnelle

Bonjour

On peut aussi écrire sommeprod ainsi

=SOMMEPROD((E11:E20="A")+(E11:E20="B");K11:K20)

le fait de mettre la matrice à "sommer" après un point virgule donne plus de souplesse car on a alors le même comportement qu'une fonction somme
(pas d'erreur en cas de valeur non numérique par exemple)

 

Vote positif 0 Vote négatif