somme colonnes

Bonjour,

Tu pourrais utiliser SommeProd, avec la fonction MOD(COLONNE();4) qui te donne le reste de la division par 4 du n° de la colonne
Si tes données sont disposées de manière régulière, 1 trimestre par colonne, 4 colonnes par an et sans colonne vide une fois de temps en temps
Tes données de A3 à P14
Derniers trimestres :
=SOMMEPROD((MOD(COLONNE($A$3:$P$14);4)=0)*$A$3:$P$14)
ou bien (plus pratique parce que les 3 formules seront construites de la même manière) :
=SOMMEPROD((MOD(COLONNE($A$3:$P$14)+3;4)>2)*$A$3:$P$14)
Trimestres 3 et 4 :
=SOMMEPROD((MOD(COLONNE($A$3:$P$14)+3;4)>1)*$A$3:$P$14)
Trimestres 2, 3 et 4 :
=SOMMEPROD((MOD(COLONNE($A$3:$P$14)+3;4)>0)*$A$3:$P$14)

Ces formules fonctionnent si tes données démarrent en colonne A
Sinon, tu adaptes :
MOD(COLONNE()+3;4) si elles démarrent en colonne A ou E
MOD(COLONNE()+2;4) si elles démarrent en colonne B ou F
MOD(COLONNE()+1;4) si elles démarrent en colonne C ou G
MOD(COLONNE();4) si elles démarrent en colonne D ou H

Si tu as 1 colonne vide entre chaque année, MOD(COLONNE()+ x ; 5)

Merci beaucoup c'est exactement ce que je voulais.
Bon week end à tous