[RESOLU] Probléme pour identifier 1ére cellule non vide

loulou14

XLDnaute Nouveau
Bonjour à tous

Dans un tableau je herche à identifier (couleur jaune), la première cellule non vide, pour chaque ligne non vide, sur un range de la colonne B à la dernière colonne non vide vers la droite

J'utilise un code qui me renvoie des incohérences.
Peut être que je n'emploie pas la bonne méthode

En PJ un fichier exemple, les incohérences sont entourées en rouge

Code utilisé

Code:
Sub Macro4()
'
' Macro4 Macro

Dim i As Long, DerniereLigne As Long
DerniereLigne = Sheets("Feuil1").Range("B65536").End(xlUp).Row
    For i = 2 To DerniereLigne
    Sheets("Feuil1").Range("B" & i).End(xlToRight).Interior.ColorIndex = 6
    Next i
End Sub

Merci d'avance pour votre aide
 

Pièces jointes

  • Classeur1.xlsm
    19.6 KB · Affichages: 43

ROGER2327

XLDnaute Barbatruc
Bonjour à tous.

Deux autres :

VB:
Sub aaa1()
Dim i&, c&, p As Range
  With Range("B1")
    Set p = .Resize(.Offset(Rows.Count - .Row).End(xlUp).Row, .Offset(, Columns.Count - .Column).End(xlToLeft).Column)
    p.Interior.ColorIndex = xlNone
    For i = 1 To p.Rows.Count - 1
      If .Offset(i, 1).Value = "" Then
        c = .Offset(i, 1).End(xlToRight).Column - .Column
        If c <= p.Columns.Count Then .Offset(i, c).Interior.Color = vbYellow
      Else
        .Offset(i, 1).Interior.Color = vbYellow
      End If
    Next
  End With
End Sub


Sub aaa2()
Dim i&, j&, p()
  With Range("B1")
    With .Resize(.Offset(Rows.Count - .Row).End(xlUp).Row, .Offset(, Columns.Count - .Column).End(xlToLeft).Column)
      .Interior.ColorIndex = xlNone
      p = .Value
    End With
    For i = 2 To UBound(p, 1): For j = 2 To UBound(p, 2)
      If (p(i, j)) <> "" Then .Offset(i - 1, j - 1).Interior.Color = vbYellow: Exit For
    Next j, i
  End With
End Sub

ℝOGER2327
#8512


Lundi 16 Pédale 144 (Saints Templiers, adeptes - fête Suprême Quarte)
20 Ventôse An CCXXV, 1,1135h - cordeau
2017-W10-5T02:40:21Z
 

Discussions similaires

Statistiques des forums

Discussions
299 850
Messages
1 979 570
Membres
206 779
dernier inscrit
Bahlou