[RESOLU] : Liste deroulante

[MADAGASCAR]

Bonsoir Excel Downloads
Bonsoir tout le monde
SVP une autre fois je sollicite votre aide pour finir ce fichier .. mon but est lorsque je choisis dans la liste deroulante dans la cellule "F9" dans l'onglet "DATABASE" un code d'usine ..s'affichent automatiquement dans la colonne G ( commançant par "G9" ) les codes du pieces de cet usine choisit mais sans doublons du numero de ces pieces ..
Mille fois merci d'avance pour l'aide
Cordialement
MADA

 

[FROLLINDE]

Re : Liste deroulante

Bonsoir Mada...

Et pourquoi pas un simple TCD...

Bonne soirée

 

[MADAGASCAR]

Re : Liste deroulante

Bonsoir Mada...

Et pourquoi pas un simple TCD...

Bonne soirée

Salut FROLLINDE
Merci beaucoup pour votre impeccable travail et votre magnifique fichier
C'est vraiment ce que je veux avoir .. seulement svp si vous pouvez m'aider pour le faire sans filtre c'est à dire comme mon premier fichier avec liste deroulante ..
Merci beaucoup d'avance pour l'aide
Cordialement
MADA

 

[FROLLINDE]

Re : Liste deroulante

Mada,

Avec une solution qui exploite un TCD sur un autres onglet et l'utilisation des fonction Equiv + index...

C'est sans doute plus proche de ce que tu souhaitais.

 

[MADAGASCAR]

Re : Liste deroulante

Salut FROLLINDE
Merci pour tous
Oui vraiment c'est une solution plus proche de ce que je souhaitais
Je tiens toujours si c'est possible biensure de le faire sans TCD ..
Merci 1000 fois pour votre temps passé pour m'aider
Cordialement
MADA

 

[job75]

Re : Liste deroulante

Bonjour MADAGASCAR, FROLLINDE, le forum,

Une solution avec l'objet Dictionary et un tri :

Private Sub Worksheet_Change(ByVal Target As Range)
Dim cel As Range, x, t, d As Object, i&, a
Set cel = [F9] 'à adapter
If Intersect(Target, cel) Is Nothing Then Exit Sub
x = cel
t = [A1].CurrentRegion
Set d = CreateObject("Scripting.Dictionary")
For i = 1 To UBound(t)
  If t(i, 1) = x Then d(t(i, 2)) = ""
Next
If d.Count Then
  a = d.keys
  tri a, 0, UBound(a)
  cel(1, 2).Resize(d.Count) = Application.Transpose(a)
End If
cel(d.Count + 1, 2).Resize(Rows.Count - d.Count - cel.Row + 1).Delete xlUp
End Sub

Sub tri(a, gauc, droi)       ' Quick sort
Dim ref, g, d, temp
ref = a((gauc + droi) \ 2)
g = gauc: d = droi
Do
    Do While a(g) < ref: g = g + 1: Loop
    Do While ref < a(d): d = d - 1: Loop
    If g <= d Then
      temp = a(g): a(g) = a(d): a(d) = temp
      g = g + 1: d = d - 1
    End If
Loop While g <= d
If g < droi Then Call tri(a, g, droi)
If gauc < d Then Call tri(a, gauc, d)
End Sub

Bonne journée.

 

[MADAGASCAR]

Re : Liste deroulante

Bonjour JOB75
Merci maitre
BRAVO ..vraiment plus que parfait
C'est exactement ce que je veux voir et avoir
C'est parfaitement résolu
Cordialement
MADA