XL 2010 (resolu) Créer une private sub

chvalet · 24 Mars 2018

Bonjour

Dans le fichier joint, je souhaiterais dans la feuille listing que
Tant que la colonne A n'est pas vide
et que lorsque je remplis la colonne G d'un nombre (entre 0 et 4),
qu' automatiquement la colonne H se remplisse grâce à la formule suivante =SI(Gx="";"?";SI(Gx=0;"20sec";""))

quelqu'un aurait il une idée pour construire cette private sub dans la feuille listing?

merci
Chvalet

Staple1600 · 24 Mars 2018

Bonjour le fil, le forum

Une solution possible

VB:

Private Sub Worksheet_Change(ByVal T As Range)
If T.Column = 7 Then
T.Offset(, 1) = Application.Rept("20sec", T < 1)
End If
End Sub

NB: Avec ce code, on n'utilise pas les formules existantes dans ton fichier.
Donc supprimer les formules en colonne H avant de tester le code VBA.

EDITION: Une version qui circonscrit la plage de cellules sur laquelle s'applique la sub

VB:

Private Sub Worksheet_Change(ByVal T As Range)
If Not Intersect(T, Range("G3:G42")) Is Nothing Then
T.Offset(, 1) = Application.Rept("20sec", T < 1)
End If
End Sub

fanfan38 · 24 Mars 2018

Bonjour chvalet et le forum
une solution

Code:

Private Sub Worksheet_Change(ByVal Target As Range)
' Macro permettant le calcul de la pénalité mixité
If Target.Column <> 7 Then Exit Sub
If Target.Row < 3 Then Exit Sub
' Cstr pour faire la difference entre 0 et rien
Select Case CStr(Cells(Target.Row, 7).Value)
  Case Is = "0"
    Cells(Target.Row, 8).Value = "20sec"
  Case Is = "1"
  Case Is = "2"
  Case Is = "3"
  Case Is = "4"
  Case Else
    Cells(Target.Row, 8).Value = "?"
End Select
End Sub

A+ François

Staple1600 · 24 Mars 2018

Bonjour fanfan38

fanfan38 à dit:
Bonjour chvalet et le forum

Tu ne m'as pas vu passé?
Pas encore bien réveillé

(cf le message#2)

fanfan38 · 24 Mars 2018

Bonjour Staple1600
Non je ne t'ai pas vu passé et pourtant je suis debout depuis 5h..
Ça doit être l'age...lol...
A+ Francois et bonne journée...

chvalet · 24 Mars 2018

Bonjour à tous

et merci pour vos réponses.
Voici mes tests

Staple1600 reponse 1

Quand je mets 0 = 20s => ok
si je mets "" => 20s au lieu de ? => pas bon
si je mets 1/2/3/4 => "" ok

Staple1600 reponse 2
Quand je mets 0 = 20s => ok
si je mets "" => 20s au lieu de ? => pas bon
si je mets 1/2/3/4 => "" ok

François reponse 1
si je mets un "" = ? => ok
si je mets 0 = 20s = => ok
si je mets 1 2 3 ou 4 ca ne fonctionne pas

encore merci
Chvalet

fanfan38 · 24 Mars 2018

Qu'est ce qui ne fonctionne pas?
A+ François

Staple1600 · 24 Mars 2018

Re

chvalet
La formule dans ton fichier exemple était
=SI(G3="";"?";SI(G3<1;"20sec";""))

Donc j'ai respecté la condition <1

Quand au ? pour moi, il n'apporte pas grand chose donc, je n'en suis pas occupé
(En effet qu'une cellule contienne ? ou soit vide, l'information renvoyée signifie la même chose : rien)

chvalet · 24 Mars 2018

Rebonjour François

Quand je mets 1 2 3 ou 4 j'ai 20s au lieu de vide ''

Merci
Chvalet

Staple1600 · 24 Mars 2018

Re

@chvalet
Tu as zappé mon dernier message
(le message#8)

Merci de confirmer ou infirmer ce que j'y disais.

chvalet · 24 Mars 2018

Bonjour Jm

Justement si la cellule contient ? ça veut dire que l'on a oublié de remplir la colonne G, c'est une alerte qui veut dire attention il manque quelque chose

merci
Chvalet

Staple1600 · 24 Mars 2018

Re

Et comme ceci, c'est mieux?

VB:

Private Sub Worksheet_Change(ByVal T As Range)
If Not Intersect(T, Range("G3:G42")) Is Nothing Then
T.Offset(, 1) = Application.Rept("?", T = "") & Application.Rept("20sec", T <> "" And T < 1)
End If
End Sub

chvalet · 24 Mars 2018

Bonjour JM

Oui impeccable
merci

Chvalet

chvalet · 24 Mars 2018

re Bonjour

par rapport à la sub de François, je viens de comprendre le fonctionnement
et je me suis permis de la modifier , il y a certainement plus rapide et plus "propre" que ce que j'ai fait et plus long que celle de JM

Code:

Private Sub Worksheet_Change(ByVal Target As Range)
' Macro permettant le calcul de la pénalité mixité
   If Target.Column <> 7 Then Exit Sub
     If Target.Row < 3 Then Exit Sub
        ' Cstr pour faire la difference entre 0 et rien
       Select Case CStr(Cells(Target.Row, 7).Value)
          Case Is = "0"
            Cells(Target.Row, 8).Value = "20sec"
          Case Is = "1"
            Cells(Target.Row, 8).Value = ""
          Case Is = "2"
             Cells(Target.Row, 8).Value = ""
          Case Is = "3"
            Cells(Target.Row, 8).Value = ""
          Case Is = "4"
           Cells(Target.Row, 8).Value = ""
       Case Else
         Cells(Target.Row, 8).Value = "?"
       End Select
End Sub

encore merci à tous pour votre aide

Chvalet

Staple1600 · 24 Mars 2018

Re

@chvalet
Puisque tu as compris le code de Francois
Voici une version plus courte de son code que tu devrais aussi comprendre.

VB:

Private Sub Worksheet_Change(ByVal Target As Range)
' Macro permettant le calcul de la pénalité mixité
   If Target.Column <> 7 Then Exit Sub
     If Target.Row < 3 Then Exit Sub
    Select Case Cells(Target.Row, 7)
        Case Is = "": Cells(Target.Row, 8) = "?"
        Case 0: Cells(Target.Row, 8) = "20sec"
        Case 1 To 4: Cells(Target.Row, 8) = ""
    End Select
End Sub

XL 2010 (resolu) Créer une private sub

chvalet

XLDnaute Junior

Pièces jointes

Staple1600

XLDnaute Barbatruc

fanfan38

XLDnaute Barbatruc

Staple1600

XLDnaute Barbatruc

fanfan38

XLDnaute Barbatruc

chvalet

XLDnaute Junior

fanfan38

XLDnaute Barbatruc

Staple1600

XLDnaute Barbatruc

chvalet

XLDnaute Junior

Staple1600

XLDnaute Barbatruc

chvalet

XLDnaute Junior

Staple1600

XLDnaute Barbatruc

chvalet

XLDnaute Junior

chvalet

XLDnaute Junior

Staple1600

XLDnaute Barbatruc

Discussions similaires