Ceci est une page optimisée pour les mobiles. Cliquez sur ce texte pour afficher la vraie page.

XL 2016 [Résolu] Copie de plage de cellules d'un fichier à un autre / Utilisation de Range et Cells

M

miloo

XLDnaute Junior
Bonjour à tous.

Je souhaiterais copier une plage de cellules d'un fichier vers un autre. Les 2 fichiers sont identiques dans leur structure.
J'ai appliqué le code de "BENNASR" dans ce post https://www.developpez.net/forums/d...xcel/macro-copier-coller-cellules-d-classeur/
Je l'ai adapté à mes fichiers, le voici:
VB: 
Sub CopiePlanning()

Dim wkbSource As Workbook, wkbCible As Workbook
Dim chemin As String, fichier As String
Dim PlageCopie As Range

Set wkbSource = ThisWorkbook
chemin = ThisWorkbook.Path
fichier = "Planning CDS 2021-4.0mCible.xlsm"
Workbooks.Open chemin & "\" & fichier
Set wkbCible = ActiveWorkbook

wkbCible.Sheets("Janvier").Range("C6:C95").Value = wkbSource.Sheets("Janvier").Range("C6:C95").Value

Cela fonctionne de cette manière, mais je dois maintenant complexifier le code et remplacer C6:C95 par des variables.

J'ai donc fait ce code intermédiaire avant de passer aux variables: (remplacement de Range("C6:C95") par Range(Cells(...),Cells(...)) pour me permettre de définir des variables à la place de 6 ,3 et 95, 3 par la suite)

Code: 
Sub CopiePlanning()

Dim wkbSource As Workbook, wkbCible As Workbook
Dim chemin As String, fichier As String
Dim PlageCopie As Range

Set wkbSource = ThisWorkbook
chemin = ThisWorkbook.Path
fichier = "Planning CDS 2021-4.0mCible.xlsm"
Workbooks.Open chemin & "\" & fichier
Set wkbCible = ActiveWorkbook

wkbCible.Sheets("Janvier").Range(Cells(6, 3), Cells(95, 3)).Value = wkbSource.Sheets("Janvier").Range(Cells(6, 3), Cells(95, 3)).Value

Mais Excel me retourne une erreur '1004' lors de l'exécution.
Y a-t-il une erreur évidente que je n'arrive pas à saisir? Sur l'utilisation de Range et Cells (que j'ai pourtant déjà utilisés dans ce genre de cas il me semble, mais peut-être pas avec des .Value...)

NB. je dois ensuite encore complexifier le code avec une boucle sur la colonne (actuellement '3'), puis une boucle sur les onglet.
Je pense savoir comment faire, mais j'aurai peut-être des questions à suivre si ce premier problème est résolu.

Merci d'avance à ceux qui voudront bien se pencher sur le sujet!

Miloo
 
Solution
Bonjour Miloo, Staple1600 , le forum

L'utilisation de range(cells(...) aboutit effectivement à quelques inconvenients.
Il faut lister précisémment les sources, idéalement en les définissant comme dans l'exemple ci-joint sur une plage "B6:C9" à copier.

Exemple

Set rng1 = wkbSource.Sheets("Janvier").Range(wkbSource.Sheets("Janvier").Cells(6, 2), wkbSource.Sheets("Janvier").Cells(9, 3))
Set rng2 = wkbCible.Sheets("Janvier").Range(wkbCible.Sheets("Janvier").Cells(6, 2), wkbCible.Sheets("Janvier").Cells(9, 3))

rng2.Value = rng1.Value
Trier par date Trier par votes

Staple1600

XLDnaute Barbatruc
Bonjour le fil, Miloo

=>Miloo
Et en testant ceci, l'erreur est toujours présente
VB: 
Sub CopiePlanning()
Dim wkS As Workbook, wkC As Workbook, chemin$, fichier$
Set wkS = ThisWorkbook
chemin = ThisWorkbook.Path
fichier = "Planning CDS 2021-4.0mCible.xlsm"
Workbooks.Open chemin & "\" & fichier
Set wkC = ActiveWorkbook
wkC.Sheets("Janvier").Range("$C$6:$C$95").Value = wkS.Sheets("Janvier").Range("$C$6:$C$95").Value
End Sub

EDITION: Bonjour zebanx
 
Dernière édition:
Vote positif 0 Vote négatif

zebanx

XLDnaute Accro
Bonjour Miloo, Staple1600 , le forum

L'utilisation de range(cells(...) aboutit effectivement à quelques inconvenients.
Il faut lister précisémment les sources, idéalement en les définissant comme dans l'exemple ci-joint sur une plage "B6:C9" à copier.

Exemple

Set rng1 = wkbSource.Sheets("Janvier").Range(wkbSource.Sheets("Janvier").Cells(6, 2), wkbSource.Sheets("Janvier").Cells(9, 3))
Set rng2 = wkbCible.Sheets("Janvier").Range(wkbCible.Sheets("Janvier").Cells(6, 2), wkbCible.Sheets("Janvier").Cells(9, 3))

rng2.Value = rng1.Value
 
Vote positif 0 Vote négatif
Solution
M

miloo

XLDnaute Junior
Bonjour Staple1600, bonjour zebanx.
Merci pour vos réponses.
Je n'ai pas actuellement accès à mon PC pour tester vos propositipons, demain au plus tôt, je vous en ferai un retour.
Maintenant que je vois la solution de zebanx, ma (petite) mémoire croit me rappeler que j'ai déjà été confronté à ce problème il y a longtemps et que je l'avais solutionné de cette manière.
Pourtant, dans le reste de mon code sur mon fichier Source (car ile fichier source possède aussi tout un tas de macros), cela marche sans faire référence au chemin complet.
Est-ce dû au fait que ces macros n'interviennent que dans ce fichier, mais que dès que l'on fait intervenir plusieurs fichiers, il faut répéter le chemin dans Cells, même s'il est déjà précisé avant le Range?
Merci en tout cas et je vous fait le retour dès que possible, pour, espérons-le mettre ce fil en Résolu!
 
Vote positif 0 Vote négatif
M

miloo

XLDnaute Junior
Bonjour Staple1600, bonjour zebanx.
J'ai utilisé la méthode de zebanx, et c'est impeccable, ça marche! Merci beaucoup à vous.
Zebanx, sais-tu répondre à ma question: comment se fait-il que que dans les dans les Sub de mes autres modules, les Cells fonctionnent sans faire référence au chemin complet? C'est uniquement quand il y a des références à plusieurs fichiers? Quel est alors le "périmètre"? La Sub? le module?
Merci
 
Vote positif 0 Vote négatif

zebanx

XLDnaute Accro
Bonjour Miloo, staple1600, le forum

Ci-joint une explication en anglais que j'avais chargé (mais qui hélas n'existe plus).
Reste l'explication et la pratique..
@+

---


One final point which often catches people out when passing range objects as arguments to the Range property is that if you need to specify a worksheet object (which is good practice), you need to specify it for all of the Range/Cells properties you use.

So this is wrong:
Sheets("Sheet1").Range(Cells(1, "A"), Cells(10, "B"))

because the two Cells properties do not have a worksheet specified.

Although this may work some of the time, it will be dependent on where the code is (in a worksheet code module, unlike other modules, any use of Range or Cells without a worksheet object reference refers to the sheet containing the code and not the active sheet) and which worksheet is active at the time so sometimes it will fail – this kind of bug can be very hard to track down.

The correct syntax for the above is:
Sheets("Sheet1").Range(Sheets("Sheet1").Cells(1, "A"), Sheets("Sheet1").Cells(10, "B"))

or you can use a With … End With block to save a little typing:
With Sheets("Sheet1")
.Range(.Cells(1, "A"), .Cells(10, "B"))
End With
 
Vote positif 0 Vote négatif
Identifiez-vous ou inscrivez-vous pour participer.

Discussions similaires

  • Résolu(e)
Microsoft 365 Vba : Transférer des données d'un tableau dans un autre fichier
Réponses
7
Affichages
363
Chaton77
C
  • Question
XL 2021 Problème de remplissage d'une colonne conditionné à d'autres valeurs
Réponses
2
Affichages
329
CathyLD
C
G
  • Question
Microsoft 365 Avoir des classeurs maitres et les procédures dans un autre classeur.
2
Réponses
18
Affichages
1 K
GClaire
G
L
  • Résolu(e)
Microsoft 365 Pb de valeur de variable entre Sub
Réponses
5
Affichages
385
loreak
L
G
  • Question
Microsoft 365 Incompatibilité de type - Array
Réponses
2
Affichages
421
guiyom
G
G
  • Question
Microsoft 365 Saut de ligne dans une cellule
Réponses
3
Affichages
437
GClaire
G
Q
  • Résolu(e)
Microsoft 365 Exécutions directes différentes vs "pas à pas"
Réponses
2
Affichages
417
Quentin2106
Q
  • Résolu(e)
XL 2016 Problèmes de Range, tentative de boucle entre 2 fichiers
Réponses
4
Affichages
688
R3n0W
P
  • Résolu(e)
XL 2016 4 étapes en 1 seule Excel vba
Réponses
4
Affichages
665
Pygos691
P
EXCEL :: Exporter un onglet/plage de cellules dans un fichier PDF
Réponses
0
Affichages
329
oguruma
Menu
Connexion
S'inscrire
Les cookies sont requis pour utiliser ce site. Vous devez les accepter pour continuer à utiliser le site. En savoir plus…