[Résolu] Calcul de penalité en fonction d'un temps

[FooFighters82]

Bonjour a tous !

J'aurais besoin de votre aide pour la creation d'une formule.
j'ai beau retourner le probleme dans tous les sens, je suis bloqué (mes competences excel sont limitées 😉)

Je vous expose le probleme :
il faudrait que puisse calculer le coût des penalités appliquées pour le depassement de 15h d'arret par machine.
exemple : si la machine a été arretée pendant 17h (au lieu des 15h max autorisées) il faut appliquer une certaine somme par heure supplementaires entamées.

Je joint un fichier qui je l'espere sera plus clair pour vous

Merci pour votre aide 🙂

 

[Papou-net]

Re : Calcul de penalité en fonction d'un temps

Bonsoir FooFighter82,

Voici ton fichier avec les formules qui vont bien.

Exemple pour B2 :

=SI(HEURE(A2)>15;(HEURE(A2)-15)*75;"")

Cordialement.

Edit : attention, ça ne marche pas pour des retards >= à 24h00.

 

[paspat]

Re : Calcul de penalité en fonction d'un temps

une solution....

 

[R@chid]

Re : Calcul de penalité en fonction d'un temps

Bonsoir @ tous,
Bonsoir FooFighters et Bienvenu sur XLD,
une variante sans SI() et qui fonctionne avec des heures > 24:00,
en B2 :

=(A2>N("15:00"))*((A2-"15:00")*24*75)

@ tirer vers le bas
Amicalement

 

[FooFighters82]

Re : Calcul de penalité en fonction d'un temps

Merci a vous pour la rapidité vos reponses 😀

Rachid_0661 ta formule est tout a fait ce qu'il me fallait

Un grand merci a vous !!

😎

 

[hoerwind]

Re : [Résolu] Calcul de penalité en fonction d'un temps

Bonjour et bienvenue sur le forum, salut les autres,

Uniquement pour le plaisir de faire un peu plus court : =MAX(0;A2-15/24)*24*75
cellule au format 0.00;;

 

[mapomme]

Re : [Résolu] Calcul de penalité en fonction d'un temps

Bonjour à tous,

Il me semble que tout heure entamée doit entrainer la totalité des 75€ de pénalité...
Peut-être =ARRONDI.AU.MULTIPLE(MAX(0;A12-15/24)*24*75;75)
Raté! ne fonctionne pas avec des durées >=24h

 

[JBARBE]

Re : Calcul de penalité en fonction d'un temps

Bonjour,

& Bonjour Rachid !

Ta formule fonctionne également comme cela !

=((A2-"15:00")*24*75)

Encore bravo !

 

[hoerwind]

Re : [Résolu] Calcul de penalité en fonction d'un temps

Salut mapomme,

Tu as probablement raison, bien que notre ami FooFighter82 ait approuvé les résultats de Rachid, alors que sous la pièce jointe il est bien précisé : toute heure supplémentaire entamée applique une pénalité de 75€

Néanmoins il me semble que ta formule présente un petit problème en ligne 10, elle renvoie 1350 (et non 1425).
Pour ne pas changer mes habitudes d'économie, je te proposerais celle-ci :
=MAX(0;PLAFOND(A2*24;1)-15)*75

Édition : salut JBARBE (pas vu !)
Le problème avec la formule que tu proposes est qu'elle applique des pénalités négatives pour des arrêts <15:00

 

[mapomme]

Re : Calcul de penalité en fonction d'un temps

Bonjour,

Une formule devant le faire (yc duréee >=24h)

=75*MAX(0;SOMME(ENT(A2)*24;ARRONDI.SUP(24*MOD(A2;1);0);-15))

 

[mapomme]

Re : [Résolu] Calcul de penalité en fonction d'un temps

Bonjour à tous, hoerwind,

Bravo hoerwind pour le souci d'économie! La mienne est plus longue! 😱
Plafond : encore une que je n'arrive pas à intégrer!

 

[hoerwind]

Re : [Résolu] Calcul de penalité en fonction d'un temps

Re,

Exact, mais un tantinet plus longue (lol).

Édition :
On se croise vraiment beaucoup sur ce fil !

 

[R@chid]

Re : [Résolu] Calcul de penalité en fonction d'un temps

Bonjour @ tous,
Pour ma première formule, j'ai fais le format personnalisé le premier ce qui ne m'a pas permettre de voir les heures négatives,
j'ai pensé que A2>N("15:00") va renvoyer 0 au cas de A2<=N("15:00"), j'avais pas l'habitude d'ecrire "15:00" je ne sais pas pourquoi je l'ai fait hier je préfère 15/24 je toujours a l'aise avec...
donc ma formule peut s’écrire :

=(A2>15/24)*((A2-15/24)*75*24)

Avec format personnalisee pour ne pas afficher les 0 ==> 0,00;;
pour JBARBE ==> la partie que tu as enlevé de ma formule est très importante
Amicalement

 

[FooFighters82]

Re : [Résolu] Calcul de penalité en fonction d'un temps

Salut mapomme,

Tu as probablement raison, bien que notre ami FooFighter82 ait approuvé les résultats de Rachid, alors que sous la pièce jointe il est bien précisé : toute heure supplémentaire entamée applique une pénalité de 75€


Bonjour Hoerwind est merci car il est vrai que ta formule fonctionne apr tranche de 75€ ce qui est encore mieux
Merci beaucoup !