Repertoire de sauvegarde avec WorkbookBeforeSAve

[bond]

Bonjour à tous,
Lorsque l'utilisateur choisi la commande 'Enregistrer sous', je voudrai amener le répertoire de sauvegarde P:\CLIENT 2011\ (différent de celui où a été ouvert le fichier) dans la boite de dialogue 'Enregistrer sous', j'ai posé le code :

Private Sub Workbook_BeforeSave(ByVal SaveAsUI As Boolean, Cancel As Boolean)
Application.EnableEvents = False
Application.GetSaveAsFilename InitialFileName:="P:\CLIENT 2011\"
Application.EnableEvents = True
End Sub

Résultat, le répertoire est correctement changé dans le boite mais (et c'est là que les pb commencent) :
- La sauvegarde ne se produit pas,
- la boite de dialogue est affichée une 2nd fois sur le répertoire d'originbe du fichier.
J'ai essayé de placer un Cancel = True, sans succès.

Merci d'avance pour vos pistes...

 

[tototiti2008]

Re : Repertoire de sauvegarde avec WorkbookBeforeSAve

Bonjour bond,

Peut-être

Private Sub Workbook_BeforeSave(ByVal SaveAsUI As Boolean, Cancel As Boolean)
Dim AdrFic
    Application.EnableEvents = False
    Cancel = True
    AdrFic = Application.GetSaveAsFilename(InitialFileName:="C:\temp\", FileFilter:="Classeur Excel (*.xls), *.xls")
    If AdrFic <> False Then
        ThisWorkbook.SaveAs AdrFic
    End If
    Application.EnableEvents = True
End Sub

 

[Hippolite]

Re : Repertoire de sauvegarde avec WorkbookBeforeSAve

Bonjour,
Quelque chose comme

Sub Enreg_BoiteDialog()
Dim oNom As String, oChemin As String

'Définition du nom et de l'emplacement
oNom = "NomDuFichier"
oChemin = "P:\CLIENT 2011\"

'Enregistre sous
Application.Dialogs(xlDialogSaveAs).Show oChemin & oNom
End Sub

 

[bond]

Re : Repertoire de sauvegarde avec WorkbookBeforeSAve

Tototiti, Hippolite, merci de vous êtes penchés sur mon sujet. 😎
J'ai évaluer vos suggestions, et je vais finalement retenir celui de Tototiti qui correspond plus à ce que je veux obtenir.

Encore merci à tous les 2,
@+ dans le coin.