renvoyer les deux plus petites valeurs d un tableau

Boostez vos compétences Excel avec notre communauté !

Rejoignez Excel Downloads, le rendez-vous des passionnés où l'entraide fait la force. Apprenez, échangez, progressez – et tout ça gratuitement ! 👉 Inscrivez-vous maintenant !

ivan972

XLDnaute Occasionnel
Bonjour a tous, bonjour a chacun

Je sollicite le forum afin de résoudre la difficulté suivante.

je souhaite dans un tableau obtenir les deux plus petits chronos a partir d un tableau de performances (ci joint en fichier)

A partir du tableau1 (A1:C15), je souhaite inscrire en cellules G3 et H3 les deux plus petit chronos en fonction du nom du cheval (F2) ET de l hippodrome(F3).

Les chronos ne sont pas rangés dans l ordre volontairement .

Le format des chronos doit rester sous forme 00'00''00.

Vous remerciant

Ivan
 

Pièces jointes

Re : renvoyer les deux plus petites valeurs d un tableau

Bonsoir @ tous,
pas sûr d'avoir compris la demande, en G3 :
Code:
=SIERREUR(INDEX($C$2:$C$15;EQUIV(PETITE.VALEUR(SI($B$2:$B$15=$F$3;CNUM(SUBSTITUE(SUBSTITUE($C$2:$C$15;"""";",");"'";)));COLONNES($G:G));SI($B$2:$B$15=$F$3;CNUM(SUBSTITUE(SUBSTITUE($C$2:$C$15;"""";",");"'";)));0));"")
@ valider par Ctrl+Shift+Enter
@ tirer vers la droite


@ + +
 
Re : renvoyer les deux plus petites valeurs d un tableau

Bonjour R@chid, re david84

Merci d avoir pris le temps de répondre a ma demande.

Cependant l hypothèse est de renvoyer dans les cellules colorées les deux plus petits chronos en fonction du cheval et de l hippodrome. Dans l exemple proposé Archange n a pas de chrono a chantilly donc pas de réponse possible.

Le résultat obtenus n est pas celui demandé.

Vous remerciant

ivan
 
Re : renvoyer les deux plus petites valeurs d un tableau

Bonsoir ivan972, David, R@chid,

Pas besoin de nombres, on peut comparer les textes des chronos.

Formule matricielle en G3 du fichier joint :

Code:
=SIERREUR(INDEX(Tableau1[CHRONOS];EQUIV(COLONNES($G3:G3);SI((Tableau1[CHEVAL]=$F2)*(Tableau1[HIPPODROME]=$F3);NB.SI(Tableau1[CHRONOS];"<="&Tableau1[CHRONOS]));0));"")
A valider par Ctrl+Maj+Entrée et tirer sur H3.

A+
 

Pièces jointes

Re : renvoyer les deux plus petites valeurs d un tableau

Re,

Bah, j'avais mal testé, il faut compliquer la formule :

Code:
=SIERREUR(INDEX(Tableau1[CHRONOS];EQUIV(PETITE.VALEUR(SI((Tableau1[CHEVAL]=$F2)*(Tableau1[HIPPODROME]=$F3);NB.SI(Tableau1[CHRONOS];"<="&Tableau1[CHRONOS]));COLONNES($G3:G3));SI((Tableau1[CHEVAL]=$F2)*(Tableau1[HIPPODROME]=$F3);NB.SI(Tableau1[CHRONOS];"<="&Tableau1[CHRONOS]));0));"")
Fichier (2).

Malgré les évènements, bonne soirée.
 

Pièces jointes

Re : renvoyer les deux plus petites valeurs d un tableau

Bonsoir, Rachid, Gérard,
en tenant compte de l'hippodrome et du cheval :
Code:
=SIERREUR(PETITE.VALEUR(SI(($A2:$A15=$F2)*($B2:$B15=$F3);(GAUCHE($C2:$C15;CHERCHE("'";$C2:$C15)-1)*60+SUBSTITUE(STXT($C2:$C15;CHERCHE("'";$C2:$C15)+1;99);"""";",")*1)/86400);COLONNE(A:A));"")
A+
 
Re : renvoyer les deux plus petites valeurs d un tableau

Re,

Bien sûr avec le nom défini matrice on simplifie la formule en G3 :

Code:
=SIERREUR(INDEX(Tableau1[CHRONOS];EQUIV(PETITE.VALEUR(matrice;COLONNES($G3:G3));matrice;0));"")
Toujours avec validation matricielle.

Fichier (3).

Bonne fin de soirée.
 

Pièces jointes

Re : renvoyer les deux plus petites valeurs d un tableau

Bonjour ivan972, David, R@chid,

En passant par des nombres (entiers) c'est en effet plus simple :

Code:
=SIERREUR(TEXTE(PETITE.VALEUR(SI((Tableau1[CHEVAL]=$F2)*(Tableau1[HIPPODROME]=$F3);--SUBSTITUE(SUBSTITUE(Tableau1[CHRONOS];"'";);"""";));COLONNES($G3:G3));"0'00\""00");"")
Ici pour les minutes on peut écrire 1' 2' 3'...10' 11' etc...

Fichier (4).

Bonne journée.
 

Pièces jointes

Re : renvoyer les deux plus petites valeurs d un tableau

Bonjour,

oui Gérard c'est mieux comme cela (à partir du moment bien sûr où toutes les données sont saisies comme cela).
On peut aussi passer par TEMPSVAL.
Ceci dit, et à moins que ce soient des données importées, le demandeur doit comprendre qu'il est bien plus efficace de saisir ses données pour qu'elles soient interprétées par Excel comme des temps plutôt que du texte, quitte à appliquer par la suite un format personnalisé.

A+
 
- Navigue sans publicité
- Accède à Cléa, notre assistante IA experte Excel... et pas que...
- Profite de fonctionnalités exclusives
Ton soutien permet à Excel Downloads de rester 100% gratuit et de continuer à rassembler les passionnés d'Excel.
Je deviens Supporter XLD

Discussions similaires

Retour