Renommer aléatoirement des mp3

[JJ1]

Bonjour,

J'ai un dossier de x fichiers mp3 dans un dossier de fichiers toto sous C:/

Je souhaiterais un code VBA qui efface les noms existants des x fichiers.mp3 présents dans le dossier toto et les renomme aléatoirement 10.mp3, 100.mp3,21.mp3...etc jusqu'au dernier fichier existant, sans y avoir de "trous" (s'il y a 100 mp3, tous les nombres de 1 à 100 ont du être utilisés aléatoirement).

Ceci pour faciliter encore davantage la lecture aléatoire.

Merci de votre aide.

Bon am

 

[MJ13]

Re : Renommer aléatoirement des mp3

Bonjour JJ1

J'ai trouvé cela dans mes archives:

1er code: Pour lister les mp3 dans le dossier en B1

Second code : Pour renommer les fichier de 1 à N en les sélectionnant.

Il manque juste le code pour inclure une colonne avec un numéro aléatoire et faire le tri. Sinon, cela prend quelques secondes en manuel.

Sub Liste_Fichiers()
'Liste des Fichiers d'un dossier avec le nom du dossier en B1
    'On Error Resume Next
    Range(Cells(2, 1), Cells(65536, 2)).Clear
     Dim i  As Integer, z As String
     ChDrive Left(Cells(1, 2), 1)
     ChDir Cells(1, 2).Value
     Set fs = CreateObject("Scripting.FileSystemObject")
    i = 1
    z = Dir("*.*", 1)
    
    While z <> ""
          If z <> ThisWorkbook.Name Then ActiveSheet.Cells(i + 1, 1).Value = z:     Complet = Cells(1, 2).Value & "\" & z: Set f = fs.GetFile(Complet): ActiveSheet.Cells(i + 1, 2).Value = f.DateCreated: ActiveSheet.Cells(i + 1, 3).Value = f.DateLastModified: ActiveSheet.Cells(i + 1, 4).Value = f.DateLastAccessed
          i = i + 1
          z = Dir
    Wend
End Sub

Sub RenommeMP3()
'Sélectionner les nouveaux noms des fichiers à renommer
N = 1
For Each cell In Selection
cell.Select
Source = Cells(1, 2) & "\" & ActiveCell: Destination = Cells(1, 2) & "\" & Format(N, "00") & ".MP3" 'Adapter à l'extension
N = N + 1
Name Source As Destination
Next
End Sub

 

[JJ1]

Re : Renommer aléatoirement des mp3

Bonjour
Merci pour ton code, j'ai voulu simplement lister les fichiers, j'ai mis toto en B1 et j'ai un bug jaune ici:
ChDrive Left(Cells(1, 2), 1)

Sinon, je souhaiterais simplement "vider" le fichier toto des infos superflues tags des fichiers (taille, date,album .....) et simplement effacer le nom existant et les renommer aléatoirement en x.mp3 (pour alléger un Ipod)

merci

 

[JJ1]

Re : Renommer aléatoirement des mp3

Re,
J'y suis arrivé avec un petit logiciel gratuit "Tagremover" , un exe très rapide.

Merci
Bonne soirée

 

[job75]

Re : Renommer aléatoirement des mp3

Bonjour JJ1, salut Michel,

Sinon on peut aussi exécuter :

Sub RenommeFichiers()
'---Attention : fermer tous les fichiers mp3---
Dim Dossier$, chemin$, C As Object, NombreFichiers&, d As Object, F As Object, i&, a
Dossier = "C:\toto" 'à adapter
chemin = Dossier & "\"
Set C = CreateObject("Scripting.FileSystemObject").GetFolder(Dossier).Files
NombreFichiers = C.Count
'---nombres entiers aléatoires sans doublons---
Set d = CreateObject("Scripting.Dictionary")
Randomize
While d.Count < NombreFichiers
  d(1 + Int(Rnd * NombreFichiers)) = ""
Wend
'---noms provisoires---
For Each F In C
  Name chemin & F.Name As chemin & "zzz" & i & ".mp3"
  i = i + 1
Next
'---noms définitifs---
a = d.keys
i = 0
For Each F In C
  Name chemin & F.Name As chemin & a(i) & ".mp3"
  i = i + 1
Next
Set C = Nothing
End Sub

On a supposé que dans le dossier "toto" il n'y a que des fichiers .mp3.

Edit : j'avais mis On Error Resume Next mais il vaut mieux l'enlever...

A+

 

[JJ1]

Re : Renommer aléatoirement des mp3

Bonjour Michel ,Job
Merci Job de ton code (j'ai lu ton MP).
En réponse, ma solution ne fait pas tout (alea notamment).
J'ai utilisé:
1--Tagremover, exe rapide et efficace (il ne reste que le nom du MP3 et sa taille, aucun autre tag).
2-- sous Windows, j'ai utilisé renomme (F2)
Apparemment les MP3 fonctionnent toujours.

ps: la suppression de Tags ne diminue pas la taille du dossier.
merci à vous
Bonne journée

 

[MJ13]

Re : Renommer aléatoirement des mp3

Bonjour JJ1, Job

Merci beaucoup Job 🙂 pour ton super code que je vais essayer de rajouter à mon appli My_Mp3_V5 😱.

Good Job 🙂.

JJ1: C'est sur que sur un MP3, c'est plus la musique qui prend de la place que les tags 🙂.