récupération de lettre de lecteur réseau

Yeahou · 6 Septembre 2004

Bonjour le forum

voici un petit problème sur lequel j'accroche :
j'ai un lecteur réseau connecté à un lettre de drive variable, je connais le chemin d'un dossier placé dessus sous la forme \\essai\essai2\essai3 et je désire récupérer la lettre de lecteur utilisée.
J'ai essayé
Sub essai()
Dim fs, fs2, f, d, s
Set fs = CreateObject("Scripting.FileSystemObject")
Set f = fs.GetFolder("\\essai\essai2\essai3")
MsgBox "Lecteur : " & f.drive
Set fs2 = CreateObject("Scripting.FileSystemObject")
Set d = fs2.GetDrive(fs2.GetDriveName(f.drive))
s = "Lettre de lecteur : " & d.driveletter
MsgBox s
End Sub
avec f.drive, je récupére bien le lecteur mais je n'arrive pas à récupérer la lettre de lecteur avec driveletter, ce qui est anormal, mon lecteur étant bien associé à une lettre et étant mappé comme tel, je peux d'ailleurs récupérer les autres infos.

D'avance merci à ceux qui pourront éclairer ma lanterne

Eric C · 7 Septembre 2004

Bonjour le forum
Bonjour Yeahou

Peut être que ?

Sub LecteursDispos()
'Chip Pearson, mpep, traduction/adaptation fs
Dim FSO As Object
Dim Drv As Object
Dim Msg$

Set FSO = CreateObject("Scripting.FileSystemObject")
Msg = "Votre système a " & FSO.Drives.Count & " lecteurs :" & vbLf & vbLf
For Each Drv In FSO.Drives
With Drv
Select Case .DriveType
Case 0 ' unknown
Msg = Msg & "Lecteur: " & .DriveLetter & " est de type inconnu." & vbLf
Case 1 ' removable, e.g., zip
Msg = Msg & "Lecteur: " & .DriveLetter & " est un disque amovible." & vbLf
Case 2 ' fixed, hard drive
Msg = Msg & "Lecteur: " & .DriveLetter & " est un disque dur." & vbLf
Case 3 ' remote
Msg = Msg & "Lecteur: " & .DriveLetter & " est un disque réseau." & vbLf
Case 4 ' CDROM
Msg = Msg & "Lecteur: " & .DriveLetter & " est un CDROM." & vbLf
Case 5 ' ram disk
Msg = Msg & "Lecteur: " & .DriveLetter & " est un disque virtuel." & vbLf
End Select
End With
Next Drv
MsgBox Msg, , "Lecteurs du système"
End Sub

@ + Eric C

Yeahou · 8 Septembre 2004

Bonjour Eric, le forum

Merci pour ta réponse, en retravaillant un peu, j'ai pu l'utiliser.

Cordialement, A+

Sub trouver_lecteur()
Dim FSO As Object
Dim Drv As Object
Set FSO = CreateObject("Scripting.FileSystemObject")
For Each Drv In FSO.Drives
With Drv
Select Case .DriveType
Case 3
If .sharename = "\\essai\essai2\essai3" Then
MsgBox .driveletter
End If
Case Else
End Select
End With
Next Drv
End Sub

récupération de lettre de lecteur réseau

Yeahou

Guest

Eric C

Guest

Yeahou

Guest

Discussions similaires